resources/libraries/robot/shared/default.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/vm/qemu.robot
  16 | Resource | resources/libraries/robot/vm/double_qemu_setup.robot
  17 | Variables | resources/libraries/python/topology.py
  18 | Variables | resources/libraries/python/VatHistory.py
  19 | Library | resources.libraries.python.topology.Topology
  20 | Library | resources.libraries.python.VatHistory
  21 | Library | resources.libraries.python.CpuUtils
  22 | Library | resources.libraries.python.DUTSetup
  23 | Library | resources.libraries.python.SchedUtils
  24 | Library | resources.libraries.python.TGSetup
  25 | Library | resources.libraries.python.L2Util
  26 | Library | resources.libraries.python.Tap
  27 | Library | resources.libraries.python.VppCounters
  28 | Library | resources.libraries.python.VPPUtil
  29 | Library | resources.libraries.python.Trace
  30 | Library | Collections
  31
  32 *** Keywords ***
  33 | Configure all DUTs before test
  34 | | [Documentation] | Setup all DUTs in topology before test execution.
  35 | | ...
  36 | | Setup All DUTs | ${nodes}
  37
  38 | Configure all TGs for traffic script
  39 | | [Documentation] | Prepare all TGs before traffic scripts execution.
  40 | | ...
  41 | | All TGs Set Interface Default Driver | ${nodes}
  42
  43 | Show Vpp Errors On All DUTs
  44 | | [Documentation] | Show VPP errors verbose on all DUTs.
  45 | | ...
  46 | | ${duts}= | Get Matches | ${nodes} | DUT*
  47 | | :FOR | ${dut} | IN | @{duts}
  48 | | | Vpp Show Errors | ${nodes['${dut}']}
  49
  50 | Show VPP trace dump on all DUTs
  51 | | [Documentation] | Save API trace and dump output on all DUTs.
  52 | | ...
  53 | | ${duts}= | Get Matches | ${nodes} | DUT*
  54 | | :FOR | ${dut} | IN | @{duts}
  55 | | | Vpp api trace save | ${nodes['${dut}']}
  56 | | | Vpp api trace dump | ${nodes['${dut}']}
  57
  58 | Show Bridge Domain Data On All DUTs
  59 | | [Documentation] | Show Bridge Domain data on all DUTs.
  60 | | ...
  61 | | ${duts}= | Get Matches | ${nodes} | DUT*
  62 | | :FOR | ${dut} | IN | @{duts}
  63 | | | Vpp Get Bridge Domain Data | ${nodes['${dut}']}
  64
  65 | Setup Scheduler Policy for Vpp On All DUTs
  66 | | [Documentation] | Set realtime scheduling policy (SCHED_RR) with priority 1
  67 | | ... | on all VPP worker threads on all DUTs.
  68 | | ...
  69 | | ${duts}= | Get Matches | ${nodes} | DUT*
  70 | | :FOR | ${dut} | IN | @{duts}
  71 | | | Set VPP Scheduling rr | ${nodes['${dut}']}
  72
  73 | Configure crypto device on all DUTs
  74 | | [Documentation] | Verify if Crypto QAT device virtual functions are
  75 | | ... | initialized on all DUTs. If parameter force_init is set to True, then
  76 | | ... | try to initialize/disable.
  77 | | ...
  78 | | ... | *Arguments:*
  79 | | ... | - force_init - Force to initialize. Type: boolean
  80 | | ... | - numvfs - Number of VFs to initialize, 0 - disable the VFs
  81 | | ... | (Optional). Type: integer, default value: ${32}
  82 | | ...
  83 | | ... | *Example:*
  84 | | ...
  85 | | ... | \| Configure crypto device on all DUTs \| ${True} \|
  86 | | ...
  87 | | [Arguments] | ${force_init}=${False} | ${numvfs}=${32}
  88 | | ...
  89 | | ${duts}= | Get Matches | ${nodes} | DUT*
  90 | | :FOR | ${dut} | IN | @{duts}
  91 | | | Crypto Device Verify | ${nodes['${dut}']} | force_init=${force_init}
  92 | | | ... | numvfs=${numvfs}
  93
  94 | Configure kernel module on all DUTs
  95 | | [Documentation] | Verify if specific kernel module is loaded on all DUTs.
  96 | | ... | If parameter force_load is set to True, then try to initialize.
  97 | | ...
  98 | | ... | *Arguments:*
  99 | | ... | - module - Module to verify. Type: string
 100 | | ... | - force_load - Try to load module. Type: boolean
 101 | | ...
 102 | | ... | *Example:*
 103 | | ...
 104 | | ... | \| Configure kernel module on all DUTs \| ${True} \|
 105 | | ...
 106 | | [Arguments] | ${module} | ${force_load}=${False}
 107 | | ...
 108 | | ${duts}= | Get Matches | ${nodes} | DUT*
 109 | | :FOR | ${dut} | IN | @{duts}
 110 | | | Kernel Module Verify | ${nodes['${dut}']} | ${module}
 111 | | | ... | force_load=${force_load}
 112
 113 | Create base startup configuration of VPP on all DUTs
 114 | | [Documentation] | Create base startup configuration of VPP to all DUTs.
 115 | | ...
 116 | | ${duts}= | Get Matches | ${nodes} | DUT*
 117 | | :FOR | ${dut} | IN | @{duts}
 118 | | | Import Library | resources.libraries.python.VppConfigGenerator
 119 | | | ... | WITH NAME | ${dut}
 120 | | | Run keyword | ${dut}.Set Node |  ${nodes['${dut}']}
 121 | | | Run keyword | ${dut}.Add Unix Log
 122 | | | Run keyword | ${dut}.Add Unix CLI Listen
 123 | | | Run keyword | ${dut}.Add Unix Nodaemon
 124 | | | Run keyword | ${dut}.Add API segment global size | 2000M
 125 | | | Run keyword | ${dut}.Add API segment API size | 1G
 126 | | | Run keyword | ${dut}.Add DPDK Socketmem | "1024,1024"
 127 | | | Run keyword | ${dut}.Add Heapsize | "4G"
 128 | | | Run keyword | ${dut}.Add IP6 Hash Buckets | "2000000"
 129 | | | Run keyword | ${dut}.Add IP6 Heap Size | "4G"
 130 | | | Run keyword | ${dut}.Add IP Heap Size | "4G"
 131
 132 | Add '${m}' worker threads and '${n}' rxqueues in 3-node single-link circular topology
 133 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
 134 | | ... | configuration on all DUTs in 3-node single-link topology.
 135 | | ...
 136 | | ${m_int}= | Convert To Integer | ${m}
 137 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 138 | | ... | ${dut1_if1} | ${dut1_if2}
 139 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
 140 | | ... | ${dut2_if1} | ${dut2_if2}
 141 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 142 | | ... | skip_cnt=${1} | cpu_cnt=${1}
 143 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 144 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
 145 | | ${dut2_cpu_main}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 146 | | ... | skip_cnt=${1} | cpu_cnt=${1}
 147 | | ${dut2_cpu_w}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 148 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
 149 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 150 | | Run keyword | DUT2.Add CPU Main Core | ${dut2_cpu_main}
 151 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 152 | | Run keyword | DUT2.Add CPU Corelist Workers | ${dut2_cpu_w}
 153 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 154 | | Run keyword | DUT2.Add DPDK Dev Default RXQ | ${n}
 155
 156 | Add '${m}' worker threads and '${n}' rxqueues in 2-node single-link circular topology
 157 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
 158 | | ... | configuration on all DUTs in 2-node single-link topology.
 159 | | ...
 160 | | ${m_int}= | Convert To Integer | ${m}
 161 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 162 | | ... | ${dut1_if1} | ${dut1_if2}
 163 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 164 | | ... | skip_cnt=${1} | cpu_cnt=${1}
 165 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 166 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
 167 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 168 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 169 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 170
 171 | Add '${m}' worker threads using SMT and '${n}' rxqueues in 3-node single-link circular topology
 172 | | [Documentation] | Setup M worker threads using SMT and N rxqueues in vpp\
 173 | | ... | startup configuration on all DUTs in 3-node single-link topology.
 174 | | ...
 175 | | ${m_int}= | Convert To Integer | ${m}
 176 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 177 | | ... | ${dut1_if1} | ${dut1_if2}
 178 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
 179 | | ... | ${dut2_if1} | ${dut2_if2}
 180 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 181 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
 182 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 183 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
 184 | | ${dut2_cpu_main}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 185 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
 186 | | ${dut2_cpu_w}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 187 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
 188 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 189 | | Run keyword | DUT2.Add CPU Main Core | ${dut2_cpu_main}
 190 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 191 | | Run keyword | DUT2.Add CPU Corelist Workers | ${dut2_cpu_w}
 192 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 193 | | Run keyword | DUT2.Add DPDK Dev Default RXQ | ${n}
 194
 195 | Add '${m}' worker threads using SMT and '${n}' rxqueues in 2-node single-link circular topology
 196 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
 197 | | ... | configuration on all DUTs in 2-node single-link topology.
 198 | | ...
 199 | | ${m_int}= | Convert To Integer | ${m}
 200 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 201 | | ... | ${dut1_if1} | ${dut1_if2}
 202 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 203 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
 204 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 205 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
 206 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 207 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 208 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 209
 210 | Add no multi seg to all DUTs
 211 | | [Documentation] | Add No Multi Seg to VPP startup configuration to all DUTs.
 212 | | ...
 213 | | ${duts}= | Get Matches | ${nodes} | DUT*
 214 | | :FOR | ${dut} | IN | @{duts}
 215 | | | Run keyword | ${dut}.Add DPDK No Multi Seg
 216
 217 | Add DPDK dev default RXD to all DUTs
 218 | | [Documentation] | Add DPDK num-rx-desc to VPP startup configuration to all
 219 | | ... | DUTs.
 220 | | ...
 221 | | ... | *Arguments:*
 222 | | ... | - rxd - Number of RX descriptors. Type: string
 223 | | ...
 224 | | ... | *Example:*
 225 | | ...
 226 | | ... | \| Add DPDK dev default RXD to all DUTs \| ${rxd} \|
 227 | | ...
 228 | | [Arguments] | ${rxd}
 229 | | ...
 230 | | ${duts}= | Get Matches | ${nodes} | DUT*
 231 | | :FOR | ${dut} | IN | @{duts}
 232 | | | Run keyword | ${dut}.Add DPDK Dev Default RXD | ${rxd}
 233
 234 | Add DPDK dev default TXD to all DUTs
 235 | | [Documentation] | Add DPDK num-tx-desc to VPP startup configuration to all
 236 | | ... | DUTs.
 237 | | ...
 238 | | ... | *Arguments:*
 239 | | ... | - txd - Number of TX descriptors. Type: string
 240 | | ...
 241 | | ... | *Example:*
 242 | | ...
 243 | | ... | \| Add DPDK dev default TXD to all DUTs \| ${txd} \|
 244 | | ...
 245 | | [Arguments] | ${txd}
 246 | | ...
 247 | | ${duts}= | Get Matches | ${nodes} | DUT*
 248 | | :FOR | ${dut} | IN | @{duts}
 249 | | | Run keyword | ${dut}.Add DPDK Dev Default TXD | ${txd}
 250
 251 | Add DPDK Uio Driver on all DUTs
 252 | | [Documentation] | Add DPDK uio driver to VPP startup configuration on all
 253 | | ... | DUTs.
 254 | | ...
 255 | | ... | *Arguments:*
 256 | | ... | - uio_driver - Required uio driver. Type: string
 257 | | ...
 258 | | ... | *Example:*
 259 | | ...
 260 | | ... | \| Add DPDK Uio Driver on all DUTs \| igb_uio \|
 261 | | ...
 262 | | [Arguments] | ${uio_driver}
 263 | | ...
 264 | | ${duts}= | Get Matches | ${nodes} | DUT*
 265 | | :FOR | ${dut} | IN | @{duts}
 266 | | | Run keyword | ${dut}.Add DPDK Uio Driver | ${uio_driver}
 267
 268 | Add NAT to all DUTs
 269 | | [Documentation] | Add NAT configuration to all DUTs.
 270 | | ...
 271 | | ${duts}= | Get Matches | ${nodes} | DUT*
 272 | | :FOR | ${dut} | IN | @{duts}
 273 | | | Run keyword | ${dut}.Add NAT
 274
 275 | Add cryptodev to all DUTs
 276 | | [Documentation] | Add Cryptodev to VPP startup configuration to all DUTs.
 277 | | ...
 278 | | ... | *Arguments:*
 279 | | ... | - count - Number of QAT devices. Type: integer
 280 | | ...
 281 | | ... | *Example:*
 282 | | ...
 283 | | ... | \| Add cryptodev to all DUTs \| ${4} \|
 284 | | ...
 285 | | [Arguments] | ${count}
 286 | | ${duts}= | Get Matches | ${nodes} | DUT*
 287 | | :FOR | ${dut} | IN | @{duts}
 288 | | | Run keyword | ${dut}.Add DPDK Cryptodev | ${count}
 289
 290 | Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
 291 | | [Documentation] | Add required number of SW crypto devices of given type
 292 | | ... | to VPP startup configuration on all DUTs in 3-node single-link
 293 | | ... | circular topology.
 294 | | ...
 295 | | ... | *Arguments:*
 296 | | ... | - sw_pmd_type - PMD type of SW crypto device. Type: string
 297 | | ... | - count - Number of SW crypto devices. Type: string
 298 | | ...
 299 | | ... | *Example:*
 300 | | ...
 301 | | ... | \| Add DPDK SW cryptodev on DUTs in 3-node single-link circular\
 302 | | ... | topology \| aesni-mb \| ${2} \|
 303 | | ...
 304 | | [Arguments] | ${sw_pmd_type} | ${count}
 305 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT1']} | ${dut1_if2}
 306 | | Run keyword | DUT1.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
 307 | | ... | ${count}
 308 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT2']} | ${dut2_if1}
 309 | | Run keyword | DUT2.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
 310 | | ... | ${count}
 311
 312 | Apply startup configuration on all VPP DUTs
 313 | | [Documentation] | Write startup configuration and restart VPP on all DUTs.
 314 | | ...
 315 | | ... | *Arguments:*
 316 | | ... | - restart_vpp - Whether to restart VPP (Optional). Type: boolean
 317 | | ...
 318 | | ... | *Example:*
 319 | | ...
 320 | | ... | \| Apply startup configuration on all VPP DUTs \| ${False} \|
 321 | | ...
 322 | | [Arguments] | ${restart_vpp}=${True}
 323 | | ...
 324 | | ${duts}= | Get Matches | ${nodes} | DUT*
 325 | | :FOR | ${dut} | IN | @{duts}
 326 | | | Run keyword | ${dut}.Apply Config | restart_vpp=${restart_vpp}
 327 | | Update All Interface Data On All Nodes | ${nodes} | skip_tg=${True}
 328
 329 | Save VPP PIDs
 330 | | [Documentation] | Get PIDs of VPP processes from all DUTs in topology and\
 331 | | ... | set it as a test variable. The PIDs are stored as dictionary items\
 332 | | ... | where the key is the host and the value is the PID.
 333 | | ...
 334 | | ${setup_vpp_pids}= | Get VPP PIDs | ${nodes}
 335 | | ${keys}= | Get Dictionary Keys | ${setup_vpp_pids}
 336 | | :FOR | ${key} | IN | @{keys}
 337 | | | ${pid}= | Get From Dictionary | ${setup_vpp_pids} | ${key}
 338 | | | Run Keyword If | $pid is None | FAIL | No VPP PID found on node ${key}
 339 | | | Run Keyword If | ',' in '${pid}'
 340 | | | ... | FAIL | More then one VPP PID found on node ${key}: ${pid}
 341 | | Set Test Variable | ${setup_vpp_pids}
 342
 343 | Verify VPP PID in Teardown
 344 | | [Documentation] | Check if the VPP PIDs on all DUTs are the same at the end\
 345 | | ... | of test as they were at the begining. If they are not, only a message\
 346 | | ... | is printed on console and to log. The test will not fail.
 347 | | ...
 348 | | ${teardown_vpp_pids}= | Get VPP PIDs | ${nodes}
 349 | | ${err_msg}= | Catenate | ${SUITE NAME} - ${TEST NAME}
 350 | | ... | \nThe VPP PIDs are not equal!\nTest Setup VPP PIDs:
 351 | | ... | ${setup_vpp_pids}\nTest Teardown VPP PIDs: ${teardown_vpp_pids}
 352 | | ${rc} | ${msg}= | Run keyword and ignore error
 353 | | ... | Dictionaries Should Be Equal
 354 | | ... | ${setup_vpp_pids} | ${teardown_vpp_pids}
 355 | | Run Keyword And Return If | '${rc}'=='FAIL' | Log | ${err_msg}
 356 | | ... | console=yes | level=WARN
 357
 358 | Set up functional test
 359 | | [Documentation] | Common test setup for functional tests.
 360 | | ...
 361 | | Configure all DUTs before test
 362 | | Save VPP PIDs
 363 | | Configure all TGs for traffic script
 364 | | Update All Interface Data On All Nodes | ${nodes}
 365 | | Reset VAT History On All DUTs | ${nodes}
 366
 367 | Tear down functional test
 368 | | [Documentation] | Common test teardown for functional tests.
 369 | | ...
 370 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 371 | | Show Packet Trace on All DUTs | ${nodes}
 372 | | Show VAT History On All DUTs | ${nodes}
 373 | | Vpp Show Errors On All DUTs | ${nodes}
 374 | | Verify VPP PID in Teardown
 375
 376 | Tear down LISP functional test
 377 | | [Documentation] | Common test teardown for functional tests with LISP.
 378 | | ...
 379 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 380 | | Show Packet Trace on All DUTs | ${nodes}
 381 | | Show VAT History On All DUTs | ${nodes}
 382 | | Show Vpp Settings | ${nodes['DUT1']}
 383 | | Show Vpp Settings | ${nodes['DUT2']}
 384 | | Vpp Show Errors On All DUTs | ${nodes}
 385 | | Verify VPP PID in Teardown
 386
 387 | Tear down LISP functional test with QEMU
 388 | | [Documentation] | Common test teardown for functional tests with LISP and\
 389 | | ... | QEMU.
 390 | | ...
 391 | | ... | *Arguments:*
 392 | | ... | - vm_node - VM to stop. Type: string
 393 | | ...
 394 | | ... | *Example:*
 395 | | ...
 396 | | ... | \| Tear down LISP functional test with QEMU \| ${vm_node} \|
 397 | | ...
 398 | | [Arguments] | ${vm_node}
 399 | | ...
 400 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 401 | | Show Packet Trace on All DUTs | ${nodes}
 402 | | Show VAT History On All DUTs | ${nodes}
 403 | | Show Vpp Settings | ${nodes['DUT1']}
 404 | | Show Vpp Settings | ${nodes['DUT2']}
 405 | | Vpp Show Errors On All DUTs | ${nodes}
 406 | | Stop and clear QEMU | ${nodes['DUT1']} | ${vm_node}
 407 | | Verify VPP PID in Teardown
 408
 409 | Set up TAP functional test
 410 | | [Documentation] | Common test setup for functional tests with TAP.
 411 | | ...
 412 | | Set up functional test
 413 | | Clean Up Namespaces | ${nodes['DUT1']}
 414
 415 | Tear down TAP functional test
 416 | | [Documentation] | Common test teardown for functional tests with TAP.
 417 | | ...
 418 | | Tear down functional test
 419 | | Clean Up Namespaces | ${nodes['DUT1']}
 420
 421 | Tear down TAP functional test with Linux bridge
 422 | | [Documentation] | Common test teardown for functional tests with TAP and
 423 | | ... | a Linux bridge.
 424 | | ...
 425 | | ... | *Arguments:*
 426 | | ... | - bid_TAP - Bridge name. Type: string
 427 | | ...
 428 | | ... | *Example:*
 429 | | ...
 430 | | ... | \| Tear down TAP functional test with Linux bridge \| ${bid_TAP} \|
 431 | | ...
 432 | | [Arguments] | ${bid_TAP}
 433 | | ...
 434 | | Tear down functional test
 435 | | Linux Del Bridge | ${nodes['DUT1']} | ${bid_TAP}
 436 | | Clean Up Namespaces | ${nodes['DUT1']}
 437
 438 | Tear down FDS functional test
 439 | | [Documentation] | Common test teardown for FDS functional tests.
 440 | | ...
 441 | | ... | *Arguments:*
 442 | | ... | - dut1_node - Node Nr.1 where to clean qemu. Type: dictionary
 443 | | ... | - qemu_node1 - VM Nr.1 node info dictionary. Type: string
 444 | | ... | - dut2_node - Node Nr.2 where to clean qemu. Type: dictionary
 445 | | ... | - qemu_node2 - VM Nr.2 node info dictionary. Type: string
 446 | | ...
 447 | | ... | *Example:*
 448 | | ...
 449 | | ... | \| Tear down FDS functional test \| ${dut1_node} \| ${qemu_node1}\
 450 | | ... | \| ${dut2_node} \| ${qemu_node2} \|
 451 | | ...
 452 | | [Arguments] | ${dut1_node} | ${qemu_node1} | ${dut2_node}
 453 | | ... | ${qemu_node2}
 454 | | ...
 455 | | Tear down functional test
 456 | | Tear down QEMU | ${dut1_node} | ${qemu_node1} | qemu_node1
 457 | | Tear down QEMU | ${dut2_node} | ${qemu_node2} | qemu_node2
 458
 459 | Stop VPP Service on DUT
 460 | | [Documentation] | Stop the VPP service on the specified node.
 461 | | ...
 462 | | ... | *Arguments:*
 463 | | ... | - node - information about a DUT node. Type: dictionary
 464 | | ...
 465 | | ... | *Example:*
 466 | | ...
 467 | | ... | \| Stop VPP Service on DUT \| ${nodes['DUT1']} \|
 468 | | ...
 469 | | [Arguments] | ${node}
 470 | | Stop VPP Service | ${node}
 471
 472 | Start VPP Service on DUT
 473 | | [Documentation] | Start the VPP service on the specified node.
 474 | | ...
 475 | | ... | *Arguments:*
 476 | | ... | - node - information about a DUT node. Type: dictionary
 477 | | ...
 478 | | ... | *Example:*
 479 | | ...
 480 | | ... | \| Start VPP Service on DUT \| ${nodes['DUT1']} \|
 481 | | ...
 482 | | [Arguments] | ${node}
 483 | | Start VPP Service | ${node}