resources/libraries/robot/shared/default.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/vm/qemu.robot
  16 | Resource | resources/libraries/robot/vm/double_qemu_setup.robot
  17 | Variables | resources/libraries/python/topology.py
  18 | Variables | resources/libraries/python/VatHistory.py
  19 | Library | resources.libraries.python.topology.Topology
  20 | Library | resources.libraries.python.VatHistory
  21 | Library | resources.libraries.python.CpuUtils
  22 | Library | resources.libraries.python.DUTSetup
  23 | Library | resources.libraries.python.SchedUtils
  24 | Library | resources.libraries.python.TGSetup
  25 | Library | resources.libraries.python.L2Util
  26 | Library | resources.libraries.python.Tap
  27 | Library | resources.libraries.python.VppCounters
  28 | Library | resources.libraries.python.VPPUtil
  29 | Library | resources.libraries.python.Trace
  30 | Library | Collections
  31
  32 *** Keywords ***
  33 | Configure all DUTs before test
  34 | | [Documentation] | Setup all DUTs in topology before test execution.
  35 | | ...
  36 | | Setup All DUTs | ${nodes}
  37
  38 | Configure all TGs for traffic script
  39 | | [Documentation] | Prepare all TGs before traffic scripts execution.
  40 | | ...
  41 | | All TGs Set Interface Default Driver | ${nodes}
  42
  43 | Show Vpp Errors On All DUTs
  44 | | [Documentation] | Show VPP errors verbose on all DUTs.
  45 | | ...
  46 | | ${duts}= | Get Matches | ${nodes} | DUT*
  47 | | :FOR | ${dut} | IN | @{duts}
  48 | | | Vpp Show Errors | ${nodes['${dut}']}
  49
  50 | Show VPP trace dump on all DUTs
  51 | | [Documentation] | Save API trace and dump output on all DUTs.
  52 | | ...
  53 | | ${duts}= | Get Matches | ${nodes} | DUT*
  54 | | :FOR | ${dut} | IN | @{duts}
  55 | | | Vpp api trace save | ${nodes['${dut}']}
  56 | | | Vpp api trace dump | ${nodes['${dut}']}
  57
  58 | Show Bridge Domain Data On All DUTs
  59 | | [Documentation] | Show Bridge Domain data on all DUTs.
  60 | | ...
  61 | | ${duts}= | Get Matches | ${nodes} | DUT*
  62 | | :FOR | ${dut} | IN | @{duts}
  63 | | | Vpp Get Bridge Domain Data | ${nodes['${dut}']}
  64
  65 | Setup Scheduler Policy for Vpp On All DUTs
  66 | | [Documentation] | Set realtime scheduling policy (SCHED_RR) with priority 1
  67 | | ... | on all VPP worker threads on all DUTs.
  68 | | ...
  69 | | ${duts}= | Get Matches | ${nodes} | DUT*
  70 | | :FOR | ${dut} | IN | @{duts}
  71 | | | Set VPP Scheduling rr | ${nodes['${dut}']}
  72
  73 | Configure crypto device on all DUTs
  74 | | [Documentation] | Verify if Crypto QAT device virtual functions are
  75 | | ... | initialized on all DUTs. If parameter force_init is set to True, then
  76 | | ... | try to initialize/disable.
  77 | | ...
  78 | | ... | *Arguments:*
  79 | | ... | - force_init - Force to initialize. Type: boolean
  80 | | ... | - numvfs - Number of VFs to initialize, 0 - disable the VFs
  81 | | ... | (Optional). Type: integer, default value: ${32}
  82 | | ...
  83 | | ... | *Example:*
  84 | | ...
  85 | | ... | \| Configure crypto device on all DUTs \| ${True} \|
  86 | | ...
  87 | | [Arguments] | ${force_init}=${False} | ${numvfs}=${32}
  88 | | ...
  89 | | ${duts}= | Get Matches | ${nodes} | DUT*
  90 | | :FOR | ${dut} | IN | @{duts}
  91 | | | Crypto Device Verify | ${nodes['${dut}']} | force_init=${force_init}
  92 | | | ... | numvfs=${numvfs}
  93
  94 | Configure kernel module on all DUTs
  95 | | [Documentation] | Verify if specific kernel module is loaded on all DUTs.
  96 | | ... | If parameter force_load is set to True, then try to initialize.
  97 | | ...
  98 | | ... | *Arguments:*
  99 | | ... | - module - Module to verify. Type: string
 100 | | ... | - force_load - Try to load module. Type: boolean
 101 | | ...
 102 | | ... | *Example:*
 103 | | ...
 104 | | ... | \| Configure kernel module on all DUTs \| ${True} \|
 105 | | ...
 106 | | [Arguments] | ${module} | ${force_load}=${False}
 107 | | ...
 108 | | ${duts}= | Get Matches | ${nodes} | DUT*
 109 | | :FOR | ${dut} | IN | @{duts}
 110 | | | Kernel Module Verify | ${nodes['${dut}']} | ${module}
 111 | | | ... | force_load=${force_load}
 112
 113 | Create base startup configuration of VPP on all DUTs
 114 | | [Documentation] | Create base startup configuration of VPP to all DUTs.
 115 | | ...
 116 | | ${duts}= | Get Matches | ${nodes} | DUT*
 117 | | :FOR | ${dut} | IN | @{duts}
 118 | | | Import Library | resources.libraries.python.VppConfigGenerator
 119 | | | ... | WITH NAME | ${dut}
 120 | | | Run keyword | ${dut}.Set Node |  ${nodes['${dut}']}
 121 | | | Run keyword | ${dut}.Add Unix Log
 122 | | | Run keyword | ${dut}.Add Unix CLI Listen
 123 | | | Run keyword | ${dut}.Add Unix Nodaemon
 124 | | | Run keyword | ${dut}.Add DPDK Socketmem | "1024,1024"
 125 | | | Run keyword | ${dut}.Add DPDK No Tx Checksum Offload
 126 | | | Run keyword | ${dut}.Add DPDK Log Level | debug
 127 | | | Run keyword | ${dut}.Add Heapsize | "4G"
 128 | | | Run keyword | ${dut}.Add Plugin | disable | default
 129 | | | Run keyword | ${dut}.Add Plugin | enable | @{plugins_to_enable}
 130 | | | Run keyword | ${dut}.Add IP6 Hash Buckets | "2000000"
 131 | | | Run keyword | ${dut}.Add IP6 Heap Size | "4G"
 132 | | | Run keyword | ${dut}.Add IP Heap Size | "4G"
 133
 134 # The following keyword results in lines longer than 80 characters.
 135 # FIXME: Rename the keyword, possibly moving arguments out of the keyword name.
 136 | Add '${m}' worker threads and '${n}' rxqueues in 3-node single-link circular topology
 137 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
 138 | | ... | configuration on all DUTs in 3-node single-link topology.
 139 | | ...
 140 | | ${m_int}= | Convert To Integer | ${m}
 141 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 142 | | ... | ${dut1_if1} | ${dut1_if2}
 143 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
 144 | | ... | ${dut2_if1} | ${dut2_if2}
 145 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 146 | | ... | skip_cnt=${1} | cpu_cnt=${1}
 147 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 148 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
 149 | | ${dut2_cpu_main}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 150 | | ... | skip_cnt=${1} | cpu_cnt=${1}
 151 | | ${dut2_cpu_w}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 152 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
 153 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 154 | | Run keyword | DUT2.Add CPU Main Core | ${dut2_cpu_main}
 155 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 156 | | Run keyword | DUT2.Add CPU Corelist Workers | ${dut2_cpu_w}
 157 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 158 | | Run keyword | DUT2.Add DPDK Dev Default RXQ | ${n}
 159
 160 | Add '${m}' worker threads and '${n}' rxqueues in 2-node single-link circular topology
 161 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
 162 | | ... | configuration on all DUTs in 2-node single-link topology.
 163 | | ...
 164 | | ${m_int}= | Convert To Integer | ${m}
 165 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 166 | | ... | ${dut1_if1} | ${dut1_if2}
 167 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 168 | | ... | skip_cnt=${1} | cpu_cnt=${1}
 169 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 170 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
 171 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 172 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 173 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 174
 175 | Add '${m}' worker threads using SMT and '${n}' rxqueues in 3-node single-link circular topology
 176 | | [Documentation] | Setup M worker threads using SMT and N rxqueues in vpp\
 177 | | ... | startup configuration on all DUTs in 3-node single-link topology.
 178 | | ...
 179 | | ${m_int}= | Convert To Integer | ${m}
 180 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 181 | | ... | ${dut1_if1} | ${dut1_if2}
 182 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
 183 | | ... | ${dut2_if1} | ${dut2_if2}
 184 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 185 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
 186 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 187 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
 188 | | ${dut2_cpu_main}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 189 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
 190 | | ${dut2_cpu_w}= | Cpu list per node str | ${dut2} | ${dut2_numa}
 191 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
 192 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 193 | | Run keyword | DUT2.Add CPU Main Core | ${dut2_cpu_main}
 194 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 195 | | Run keyword | DUT2.Add CPU Corelist Workers | ${dut2_cpu_w}
 196 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 197 | | Run keyword | DUT2.Add DPDK Dev Default RXQ | ${n}
 198
 199 | Add '${m}' worker threads using SMT and '${n}' rxqueues in 2-node single-link circular topology
 200 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
 201 | | ... | configuration on all DUTs in 2-node single-link topology.
 202 | | ...
 203 | | ${m_int}= | Convert To Integer | ${m}
 204 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 205 | | ... | ${dut1_if1} | ${dut1_if2}
 206 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 207 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
 208 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
 209 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
 210 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
 211 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
 212 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
 213
 214 | Add no multi seg to all DUTs
 215 | | [Documentation] | Add No Multi Seg to VPP startup configuration to all DUTs.
 216 | | ...
 217 | | ${duts}= | Get Matches | ${nodes} | DUT*
 218 | | :FOR | ${dut} | IN | @{duts}
 219 | | | Run keyword | ${dut}.Add DPDK No Multi Seg
 220
 221 | Add DPDK dev default RXD to all DUTs
 222 | | [Documentation] | Add DPDK num-rx-desc to VPP startup configuration to all
 223 | | ... | DUTs.
 224 | | ...
 225 | | ... | *Arguments:*
 226 | | ... | - rxd - Number of RX descriptors. Type: string
 227 | | ...
 228 | | ... | *Example:*
 229 | | ...
 230 | | ... | \| Add DPDK dev default RXD to all DUTs \| ${rxd} \|
 231 | | ...
 232 | | [Arguments] | ${rxd}
 233 | | ...
 234 | | ${duts}= | Get Matches | ${nodes} | DUT*
 235 | | :FOR | ${dut} | IN | @{duts}
 236 | | | Run keyword | ${dut}.Add DPDK Dev Default RXD | ${rxd}
 237
 238 | Add DPDK dev default TXD to all DUTs
 239 | | [Documentation] | Add DPDK num-tx-desc to VPP startup configuration to all
 240 | | ... | DUTs.
 241 | | ...
 242 | | ... | *Arguments:*
 243 | | ... | - txd - Number of TX descriptors. Type: string
 244 | | ...
 245 | | ... | *Example:*
 246 | | ...
 247 | | ... | \| Add DPDK dev default TXD to all DUTs \| ${txd} \|
 248 | | ...
 249 | | [Arguments] | ${txd}
 250 | | ...
 251 | | ${duts}= | Get Matches | ${nodes} | DUT*
 252 | | :FOR | ${dut} | IN | @{duts}
 253 | | | Run keyword | ${dut}.Add DPDK Dev Default TXD | ${txd}
 254
 255 | Add DPDK Uio Driver on all DUTs
 256 | | [Documentation] | Add DPDK uio driver to VPP startup configuration on all
 257 | | ... | DUTs.
 258 | | ...
 259 | | ... | *Arguments:*
 260 | | ... | - uio_driver - Required uio driver. Type: string
 261 | | ...
 262 | | ... | *Example:*
 263 | | ...
 264 | | ... | \| Add DPDK Uio Driver on all DUTs \| igb_uio \|
 265 | | ...
 266 | | [Arguments] | ${uio_driver}
 267 | | ...
 268 | | ${duts}= | Get Matches | ${nodes} | DUT*
 269 | | :FOR | ${dut} | IN | @{duts}
 270 | | | Run keyword | ${dut}.Add DPDK Uio Driver | ${uio_driver}
 271
 272 | Add NAT to all DUTs
 273 | | [Documentation] | Add NAT configuration to all DUTs.
 274 | | ...
 275 | | ${duts}= | Get Matches | ${nodes} | DUT*
 276 | | :FOR | ${dut} | IN | @{duts}
 277 | | | Run keyword | ${dut}.Add NAT
 278
 279 | Add cryptodev to all DUTs
 280 | | [Documentation] | Add Cryptodev to VPP startup configuration to all DUTs.
 281 | | ...
 282 | | ... | *Arguments:*
 283 | | ... | - count - Number of QAT devices. Type: integer
 284 | | ...
 285 | | ... | *Example:*
 286 | | ...
 287 | | ... | \| Add cryptodev to all DUTs \| ${4} \|
 288 | | ...
 289 | | [Arguments] | ${count}
 290 | | ${duts}= | Get Matches | ${nodes} | DUT*
 291 | | :FOR | ${dut} | IN | @{duts}
 292 | | | Run keyword | ${dut}.Add DPDK Cryptodev | ${count}
 293
 294 | Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
 295 | | [Documentation] | Add required number of SW crypto devices of given type
 296 | | ... | to VPP startup configuration on all DUTs in 3-node single-link
 297 | | ... | circular topology.
 298 | | ...
 299 | | ... | *Arguments:*
 300 | | ... | - sw_pmd_type - PMD type of SW crypto device. Type: string
 301 | | ... | - count - Number of SW crypto devices. Type: string
 302 | | ...
 303 | | ... | *Example:*
 304 | | ...
 305 | | ... | \| Add DPDK SW cryptodev on DUTs in 3-node single-link circular\
 306 | | ... | topology \| aesni-mb \| ${2} \|
 307 | | ...
 308 | | [Arguments] | ${sw_pmd_type} | ${count}
 309 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT1']} | ${dut1_if2}
 310 | | Run keyword | DUT1.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
 311 | | ... | ${count}
 312 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT2']} | ${dut2_if1}
 313 | | Run keyword | DUT2.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
 314 | | ... | ${count}
 315
 316 | Apply startup configuration on all VPP DUTs
 317 | | [Documentation] | Write startup configuration and restart VPP on all DUTs.
 318 | | ...
 319 | | ... | *Arguments:*
 320 | | ... | - restart_vpp - Whether to restart VPP (Optional). Type: boolean
 321 | | ...
 322 | | ... | *Example:*
 323 | | ...
 324 | | ... | \| Apply startup configuration on all VPP DUTs \| ${False} \|
 325 | | ...
 326 | | [Arguments] | ${restart_vpp}=${True}
 327 | | ...
 328 | | ${duts}= | Get Matches | ${nodes} | DUT*
 329 | | :FOR | ${dut} | IN | @{duts}
 330 | | | Run keyword | ${dut}.Apply Config | restart_vpp=${restart_vpp}
 331 | | Update All Interface Data On All Nodes | ${nodes} | skip_tg=${True}
 332
 333 | Save VPP PIDs
 334 | | [Documentation] | Get PIDs of VPP processes from all DUTs in topology and\
 335 | | ... | set it as a test variable. The PIDs are stored as dictionary items\
 336 | | ... | where the key is the host and the value is the PID.
 337 | | ...
 338 | | ${setup_vpp_pids}= | Get VPP PIDs | ${nodes}
 339 | | ${keys}= | Get Dictionary Keys | ${setup_vpp_pids}
 340 | | :FOR | ${key} | IN | @{keys}
 341 | | | ${pid}= | Get From Dictionary | ${setup_vpp_pids} | ${key}
 342 | | | Run Keyword If | $pid is None | FAIL | No VPP PID found on node ${key}
 343 | | | Run Keyword If | ',' in '${pid}'
 344 | | | ... | FAIL | More then one VPP PID found on node ${key}: ${pid}
 345 | | Set Test Variable | ${setup_vpp_pids}
 346
 347 | Verify VPP PID in Teardown
 348 | | [Documentation] | Check if the VPP PIDs on all DUTs are the same at the end\
 349 | | ... | of test as they were at the begining. If they are not, only a message\
 350 | | ... | is printed on console and to log. The test will not fail.
 351 | | ...
 352 | | ${teardown_vpp_pids}= | Get VPP PIDs | ${nodes}
 353 | | ${err_msg}= | Catenate | ${SUITE NAME} - ${TEST NAME}
 354 | | ... | \nThe VPP PIDs are not equal!\nTest Setup VPP PIDs:
 355 | | ... | ${setup_vpp_pids}\nTest Teardown VPP PIDs: ${teardown_vpp_pids}
 356 | | ${rc} | ${msg}= | Run keyword and ignore error
 357 | | ... | Dictionaries Should Be Equal
 358 | | ... | ${setup_vpp_pids} | ${teardown_vpp_pids}
 359 | | Run Keyword And Return If | '${rc}'=='FAIL' | Log | ${err_msg}
 360 | | ... | console=yes | level=WARN
 361
 362 | Set up functional test
 363 | | [Documentation] | Common test setup for functional tests.
 364 | | ...
 365 | | Configure all DUTs before test
 366 | | Save VPP PIDs
 367 | | Configure all TGs for traffic script
 368 | | Update All Interface Data On All Nodes | ${nodes}
 369 | | Reset VAT History On All DUTs | ${nodes}
 370
 371 | Tear down functional test
 372 | | [Documentation] | Common test teardown for functional tests.
 373 | | ...
 374 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 375 | | Show Packet Trace on All DUTs | ${nodes}
 376 | | Show VAT History On All DUTs | ${nodes}
 377 | | Vpp Show Errors On All DUTs | ${nodes}
 378 | | Verify VPP PID in Teardown
 379
 380 | Tear down LISP functional test
 381 | | [Documentation] | Common test teardown for functional tests with LISP.
 382 | | ...
 383 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 384 | | Show Packet Trace on All DUTs | ${nodes}
 385 | | Show VAT History On All DUTs | ${nodes}
 386 | | Show Vpp Settings | ${nodes['DUT1']}
 387 | | Show Vpp Settings | ${nodes['DUT2']}
 388 | | Vpp Show Errors On All DUTs | ${nodes}
 389 | | Verify VPP PID in Teardown
 390
 391 | Tear down LISP functional test with QEMU
 392 | | [Documentation] | Common test teardown for functional tests with LISP and\
 393 | | ... | QEMU.
 394 | | ...
 395 | | ... | *Arguments:*
 396 | | ... | - vm_node - VM to stop. Type: string
 397 | | ...
 398 | | ... | *Example:*
 399 | | ...
 400 | | ... | \| Tear down LISP functional test with QEMU \| ${vm_node} \|
 401 | | ...
 402 | | [Arguments] | ${vm_node}
 403 | | ...
 404 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 405 | | Show Packet Trace on All DUTs | ${nodes}
 406 | | Show VAT History On All DUTs | ${nodes}
 407 | | Show Vpp Settings | ${nodes['DUT1']}
 408 | | Show Vpp Settings | ${nodes['DUT2']}
 409 | | Vpp Show Errors On All DUTs | ${nodes}
 410 | | Stop and clear QEMU | ${nodes['DUT1']} | ${vm_node}
 411 | | Verify VPP PID in Teardown
 412
 413 | Set up TAP functional test
 414 | | [Documentation] | Common test setup for functional tests with TAP.
 415 | | ...
 416 | | Set up functional test
 417 | | Clean Up Namespaces | ${nodes['DUT1']}
 418
 419 | Tear down TAP functional test
 420 | | [Documentation] | Common test teardown for functional tests with TAP.
 421 | | ...
 422 | | Tear down functional test
 423 | | Clean Up Namespaces | ${nodes['DUT1']}
 424
 425 | Tear down TAP functional test with Linux bridge
 426 | | [Documentation] | Common test teardown for functional tests with TAP and
 427 | | ... | a Linux bridge.
 428 | | ...
 429 | | ... | *Arguments:*
 430 | | ... | - bid_TAP - Bridge name. Type: string
 431 | | ...
 432 | | ... | *Example:*
 433 | | ...
 434 | | ... | \| Tear down TAP functional test with Linux bridge \| ${bid_TAP} \|
 435 | | ...
 436 | | [Arguments] | ${bid_TAP}
 437 | | ...
 438 | | Tear down functional test
 439 | | Linux Del Bridge | ${nodes['DUT1']} | ${bid_TAP}
 440 | | Clean Up Namespaces | ${nodes['DUT1']}
 441
 442 | Tear down FDS functional test
 443 | | [Documentation] | Common test teardown for FDS functional tests.
 444 | | ...
 445 | | ... | *Arguments:*
 446 | | ... | - dut1_node - Node Nr.1 where to clean qemu. Type: dictionary
 447 | | ... | - qemu_node1 - VM Nr.1 node info dictionary. Type: string
 448 | | ... | - dut2_node - Node Nr.2 where to clean qemu. Type: dictionary
 449 | | ... | - qemu_node2 - VM Nr.2 node info dictionary. Type: string
 450 | | ...
 451 | | ... | *Example:*
 452 | | ...
 453 | | ... | \| Tear down FDS functional test \| ${dut1_node} \| ${qemu_node1}\
 454 | | ... | \| ${dut2_node} \| ${qemu_node2} \|
 455 | | ...
 456 | | [Arguments] | ${dut1_node} | ${qemu_node1} | ${dut2_node}
 457 | | ... | ${qemu_node2}
 458 | | ...
 459 | | Tear down functional test
 460 | | Tear down QEMU | ${dut1_node} | ${qemu_node1} | qemu_node1
 461 | | Tear down QEMU | ${dut2_node} | ${qemu_node2} | qemu_node2
 462
 463 | Stop VPP Service on DUT
 464 | | [Documentation] | Stop the VPP service on the specified node.
 465 | | ...
 466 | | ... | *Arguments:*
 467 | | ... | - node - information about a DUT node. Type: dictionary
 468 | | ...
 469 | | ... | *Example:*
 470 | | ...
 471 | | ... | \| Stop VPP Service on DUT \| ${nodes['DUT1']} \|
 472 | | ...
 473 | | [Arguments] | ${node}
 474 | | Stop VPP Service | ${node}
 475
 476 | Start VPP Service on DUT
 477 | | [Documentation] | Start the VPP service on the specified node.
 478 | | ...
 479 | | ... | *Arguments:*
 480 | | ... | - node - information about a DUT node. Type: dictionary
 481 | | ...
 482 | | ... | *Example:*
 483 | | ...
 484 | | ... | \| Start VPP Service on DUT \| ${nodes['DUT1']} \|
 485 | | ...
 486 | | [Arguments] | ${node}
 487 | | Start VPP Service | ${node}