CSIT-861: SW cryptodev perf tests
[csit.git] / resources / libraries / robot / shared / default.robot
1 # Copyright (c) 2016 Cisco and/or its affiliates.
2 # Licensed under the Apache License, Version 2.0 (the "License");
3 # you may not use this file except in compliance with the License.
4 # You may obtain a copy of the License at:
5 #
6 #     http://www.apache.org/licenses/LICENSE-2.0
7 #
8 # Unless required by applicable law or agreed to in writing, software
9 # distributed under the License is distributed on an "AS IS" BASIS,
10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11 # See the License for the specific language governing permissions and
12 # limitations under the License.
13
14 *** Settings ***
15 | Resource | resources/libraries/robot/vm/qemu.robot
16 | Resource | resources/libraries/robot/vm/double_qemu_setup.robot
17 | Variables | resources/libraries/python/topology.py
18 | Variables | resources/libraries/python/VatHistory.py
19 | Library | resources.libraries.python.topology.Topology
20 | Library | resources.libraries.python.VatHistory
21 | Library | resources.libraries.python.CpuUtils
22 | Library | resources.libraries.python.DUTSetup
23 | Library | resources.libraries.python.SchedUtils
24 | Library | resources.libraries.python.TGSetup
25 | Library | resources.libraries.python.L2Util
26 | Library | resources.libraries.python.Tap
27 | Library | resources.libraries.python.VppCounters
28 | Library | resources.libraries.python.VPPUtil
29 | Library | resources.libraries.python.Trace
30 | Library | Collections
31
32 *** Keywords ***
33 | Configure all DUTs before test
34 | | [Documentation] | Setup all DUTs in topology before test execution.
35 | | ...
36 | | Setup All DUTs | ${nodes}
37
38 | Configure all TGs for traffic script
39 | | [Documentation] | Prepare all TGs before traffic scripts execution.
40 | | ...
41 | | All TGs Set Interface Default Driver | ${nodes}
42
43 | Show Vpp Errors On All DUTs
44 | | [Documentation] | Show VPP errors verbose on all DUTs.
45 | | ...
46 | | ${duts}= | Get Matches | ${nodes} | DUT*
47 | | :FOR | ${dut} | IN | @{duts}
48 | | | Vpp Show Errors | ${nodes['${dut}']}
49
50 | Show VPP trace dump on all DUTs
51 | | [Documentation] | Save API trace and dump output on all DUTs.
52 | | ...
53 | | ${duts}= | Get Matches | ${nodes} | DUT*
54 | | :FOR | ${dut} | IN | @{duts}
55 | | | Vpp api trace save | ${nodes['${dut}']}
56 | | | Vpp api trace dump | ${nodes['${dut}']}
57
58 | Show Bridge Domain Data On All DUTs
59 | | [Documentation] | Show Bridge Domain data on all DUTs.
60 | | ...
61 | | ${duts}= | Get Matches | ${nodes} | DUT*
62 | | :FOR | ${dut} | IN | @{duts}
63 | | | Vpp Get Bridge Domain Data | ${nodes['${dut}']}
64
65 | Setup Scheduler Policy for Vpp On All DUTs
66 | | [Documentation] | Set realtime scheduling policy (SCHED_RR) with priority 1
67 | | ... | on all VPP worker threads on all DUTs.
68 | | ...
69 | | ${duts}= | Get Matches | ${nodes} | DUT*
70 | | :FOR | ${dut} | IN | @{duts}
71 | | | Set VPP Scheduling rr | ${nodes['${dut}']}
72
73 | Configure crypto device on all DUTs
74 | | [Documentation] | Verify if Crypto QAT device virtual functions are
75 | | ... | initialized on all DUTs. If parameter force_init is set to True, then
76 | | ... | try to initialize/disable.
77 | | ...
78 | | ... | *Arguments:*
79 | | ... | - force_init - Force to initialize. Type: boolean
80 | | ... | - numvfs - Number of VFs to initialize, 0 - disable the VFs
81 | | ... | (Optional). Type: integer, default value: ${32}
82 | | ...
83 | | ... | *Example:*
84 | | ...
85 | | ... | \| Configure crypto device on all DUTs \| ${True} \|
86 | | ...
87 | | [Arguments] | ${force_init}=${False} | ${numvfs}=${32}
88 | | ...
89 | | ${duts}= | Get Matches | ${nodes} | DUT*
90 | | :FOR | ${dut} | IN | @{duts}
91 | | | Crypto Device Verify | ${nodes['${dut}']} | force_init=${force_init}
92 | | | ... | numvfs=${numvfs}
93
94 | Configure kernel module on all DUTs
95 | | [Documentation] | Verify if specific kernel module is loaded on all DUTs.
96 | | ... | If parameter force_load is set to True, then try to initialize.
97 | | ...
98 | | ... | *Arguments:*
99 | | ... | - module - Module to verify. Type: string
100 | | ... | - force_load - Try to load module. Type: boolean
101 | | ...
102 | | ... | *Example:*
103 | | ...
104 | | ... | \| Configure kernel module on all DUTs \| ${True} \|
105 | | ...
106 | | [Arguments] | ${module} | ${force_load}=${False}
107 | | ...
108 | | ${duts}= | Get Matches | ${nodes} | DUT*
109 | | :FOR | ${dut} | IN | @{duts}
110 | | | Kernel Module Verify | ${nodes['${dut}']} | ${module}
111 | | | ... | force_load=${force_load}
112
113 | Create base startup configuration of VPP on all DUTs
114 | | [Documentation] | Create base startup configuration of VPP to all DUTs.
115 | | ...
116 | | ${duts}= | Get Matches | ${nodes} | DUT*
117 | | :FOR | ${dut} | IN | @{duts}
118 | | | Import Library | resources.libraries.python.VppConfigGenerator
119 | | | ... | WITH NAME | ${dut}
120 | | | Run keyword | ${dut}.Set Node |  ${nodes['${dut}']}
121 | | | Run keyword | ${dut}.Add Unix Log
122 | | | Run keyword | ${dut}.Add Unix CLI Listen
123 | | | Run keyword | ${dut}.Add Unix Nodaemon
124 | | | Run keyword | ${dut}.Add DPDK Socketmem | "1024,1024"
125 | | | Run keyword | ${dut}.Add Heapsize | "3G"
126 | | | Run keyword | ${dut}.Add IP6 Hash Buckets | "2000000"
127 | | | Run keyword | ${dut}.Add IP6 Heap Size | "3G"
128
129 | Add '${m}' worker threads and '${n}' rxqueues in 3-node single-link circular topology
130 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
131 | | ... | configuration on all DUTs in 3-node single-link topology.
132 | | ...
133 | | ${m_int}= | Convert To Integer | ${m}
134 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
135 | | ... | ${dut1_if1} | ${dut1_if2}
136 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
137 | | ... | ${dut2_if1} | ${dut2_if2}
138 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
139 | | ... | skip_cnt=${1} | cpu_cnt=${1}
140 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
141 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
142 | | ${dut2_cpu_main}= | Cpu list per node str | ${dut2} | ${dut2_numa}
143 | | ... | skip_cnt=${1} | cpu_cnt=${1}
144 | | ${dut2_cpu_w}= | Cpu list per node str | ${dut2} | ${dut2_numa}
145 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
146 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
147 | | Run keyword | DUT2.Add CPU Main Core | ${dut2_cpu_main}
148 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
149 | | Run keyword | DUT2.Add CPU Corelist Workers | ${dut2_cpu_w}
150 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
151 | | Run keyword | DUT2.Add DPDK Dev Default RXQ | ${n}
152
153 | Add '${m}' worker threads and '${n}' rxqueues in 2-node single-link circular topology
154 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
155 | | ... | configuration on all DUTs in 2-node single-link topology.
156 | | ...
157 | | ${m_int}= | Convert To Integer | ${m}
158 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
159 | | ... | ${dut1_if1} | ${dut1_if2}
160 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
161 | | ... | skip_cnt=${1} | cpu_cnt=${1}
162 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
163 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
164 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
165 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
166 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
167
168 | Add '${m}' worker threads using SMT and '${n}' rxqueues in 3-node single-link circular topology
169 | | [Documentation] | Setup M worker threads using SMT and N rxqueues in vpp\
170 | | ... | startup configuration on all DUTs in 3-node single-link topology.
171 | | ...
172 | | ${m_int}= | Convert To Integer | ${m}
173 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
174 | | ... | ${dut1_if1} | ${dut1_if2}
175 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
176 | | ... | ${dut2_if1} | ${dut2_if2}
177 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
178 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
179 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
180 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
181 | | ${dut2_cpu_main}= | Cpu list per node str | ${dut2} | ${dut2_numa}
182 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
183 | | ${dut2_cpu_w}= | Cpu list per node str | ${dut2} | ${dut2_numa}
184 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
185 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
186 | | Run keyword | DUT2.Add CPU Main Core | ${dut2_cpu_main}
187 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
188 | | Run keyword | DUT2.Add CPU Corelist Workers | ${dut2_cpu_w}
189 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
190 | | Run keyword | DUT2.Add DPDK Dev Default RXQ | ${n}
191
192 | Add '${m}' worker threads using SMT and '${n}' rxqueues in 2-node single-link circular topology
193 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
194 | | ... | configuration on all DUTs in 2-node single-link topology.
195 | | ...
196 | | ${m_int}= | Convert To Integer | ${m}
197 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
198 | | ... | ${dut1_if1} | ${dut1_if2}
199 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
200 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
201 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
202 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
203 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
204 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
205 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
206
207 | Add no multi seg to all DUTs
208 | | [Documentation] | Add No Multi Seg to VPP startup configuration to all DUTs.
209 | | ...
210 | | ${duts}= | Get Matches | ${nodes} | DUT*
211 | | :FOR | ${dut} | IN | @{duts}
212 | | | Run keyword | ${dut}.Add DPDK No Multi Seg
213
214 | Add DPDK dev default RXD to all DUTs
215 | | [Documentation] | Add DPDK num-rx-desc to VPP startup configuration to all
216 | | ... | DUTs.
217 | | ...
218 | | ... | *Arguments:*
219 | | ... | - rxd - Number of RX descriptors. Type: string
220 | | ...
221 | | ... | *Example:*
222 | | ...
223 | | ... | \| Add DPDK dev default RXD to all DUTs \| ${rxd} \|
224 | | ...
225 | | [Arguments] | ${rxd}
226 | | ...
227 | | ${duts}= | Get Matches | ${nodes} | DUT*
228 | | :FOR | ${dut} | IN | @{duts}
229 | | | Run keyword | ${dut}.Add DPDK Dev Default RXD | ${rxd}
230
231 | Add DPDK dev default TXD to all DUTs
232 | | [Documentation] | Add DPDK num-tx-desc to VPP startup configuration to all
233 | | ... | DUTs.
234 | | ...
235 | | ... | *Arguments:*
236 | | ... | - txd - Number of TX descriptors. Type: string
237 | | ...
238 | | ... | *Example:*
239 | | ...
240 | | ... | \| Add DPDK dev default TXD to all DUTs \| ${txd} \|
241 | | ...
242 | | [Arguments] | ${txd}
243 | | ...
244 | | ${duts}= | Get Matches | ${nodes} | DUT*
245 | | :FOR | ${dut} | IN | @{duts}
246 | | | Run keyword | ${dut}.Add DPDK Dev Default TXD | ${txd}
247
248 | Add DPDK Uio Driver on all DUTs
249 | | [Documentation] | Add DPDK uio driver to VPP startup configuration on all
250 | | ... | DUTs.
251 | | ...
252 | | ... | *Arguments:*
253 | | ... | - uio_driver - Required uio driver. Type: string
254 | | ...
255 | | ... | *Example:*
256 | | ...
257 | | ... | \| Add DPDK Uio Driver on all DUTs \| igb_uio \|
258 | | ...
259 | | [Arguments] | ${uio_driver}
260 | | ...
261 | | ${duts}= | Get Matches | ${nodes} | DUT*
262 | | :FOR | ${dut} | IN | @{duts}
263 | | | Run keyword | ${dut}.Add DPDK Uio Driver | ${uio_driver}
264
265 | Add NAT to all DUTs
266 | | [Documentation] | Add NAT configuration to all DUTs.
267 | | ...
268 | | ${duts}= | Get Matches | ${nodes} | DUT*
269 | | :FOR | ${dut} | IN | @{duts}
270 | | | Run keyword | ${dut}.Add NAT
271
272 | Add cryptodev to all DUTs
273 | | [Documentation] | Add Cryptodev to VPP startup configuration to all DUTs.
274 | | ...
275 | | ... | *Arguments:*
276 | | ... | - count - Number of QAT devices. Type: integer
277 | | ...
278 | | ... | *Example:*
279 | | ...
280 | | ... | \| Add cryptodev to all DUTs \| ${4} \|
281 | | ...
282 | | [Arguments] | ${count}
283 | | ${duts}= | Get Matches | ${nodes} | DUT*
284 | | :FOR | ${dut} | IN | @{duts}
285 | | | Run keyword | ${dut}.Add DPDK Cryptodev | ${count}
286
287 | Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
288 | | [Documentation] | Add required number of SW crypto devices of given type
289 | | ... | to VPP startup configuration on all DUTs in 3-node single-link
290 | | ... | circular topology.
291 | | ...
292 | | ... | *Arguments:*
293 | | ... | - sw_pmd_type - PMD type of SW crypto device. Type: string
294 | | ... | - count - Number of SW crypto devices. Type: string
295 | | ...
296 | | ... | *Example:*
297 | | ...
298 | | ... | \| Add DPDK SW cryptodev on DUTs in 3-node single-link circular\
299 | | ... | topology \| aesni-mb \| ${2} \|
300 | | ...
301 | | [Arguments] | ${sw_pmd_type} | ${count}
302 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT1']} | ${dut1_if2}
303 | | Run keyword | DUT1.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
304 | | ... | ${count}
305 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT2']} | ${dut2_if1}
306 | | Run keyword | DUT2.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
307 | | ... | ${count}
308
309 | Apply startup configuration on all VPP DUTs
310 | | [Documentation] | Write startup configuration and restart VPP on all DUTs.
311 | | ...
312 | | ... | *Arguments:*
313 | | ... | - restart_vpp - Whether to restart VPP (Optional). Type: boolean
314 | | ...
315 | | ... | *Example:*
316 | | ...
317 | | ... | \| Apply startup configuration on all VPP DUTs \| ${False} \|
318 | | ...
319 | | [Arguments] | ${restart_vpp}=${True}
320 | | ...
321 | | ${duts}= | Get Matches | ${nodes} | DUT*
322 | | :FOR | ${dut} | IN | @{duts}
323 | | | Run keyword | ${dut}.Apply Config | restart_vpp=${restart_vpp}
324 | | Update All Interface Data On All Nodes | ${nodes} | skip_tg=${True}
325
326 | Save VPP PIDs
327 | | [Documentation] | Get PIDs of VPP processes from all DUTs in topology and\
328 | | ... | set it as a test variable. The PIDs are stored as dictionary items\
329 | | ... | where the key is the host and the value is the PID.
330 | | ...
331 | | ${setup_vpp_pids}= | Get VPP PIDs | ${nodes}
332 | | ${keys}= | Get Dictionary Keys | ${setup_vpp_pids}
333 | | :FOR | ${key} | IN | @{keys}
334 | | | ${pid}= | Get From Dictionary | ${setup_vpp_pids} | ${key}
335 | | | Run Keyword If | $pid is None | FAIL | No VPP PID found on node ${key}
336 | | | Run Keyword If | ',' in '${pid}'
337 | | | ... | FAIL | More then one VPP PID found on node ${key}: ${pid}
338 | | Set Test Variable | ${setup_vpp_pids}
339
340 | Verify VPP PID in Teardown
341 | | [Documentation] | Check if the VPP PIDs on all DUTs are the same at the end\
342 | | ... | of test as they were at the begining. If they are not, only a message\
343 | | ... | is printed on console and to log. The test will not fail.
344 | | ...
345 | | ${teardown_vpp_pids}= | Get VPP PIDs | ${nodes}
346 | | ${err_msg}= | Catenate | ${SUITE NAME} - ${TEST NAME}
347 | | ... | \nThe VPP PIDs are not equal!\nTest Setup VPP PIDs:
348 | | ... | ${setup_vpp_pids}\nTest Teardown VPP PIDs: ${teardown_vpp_pids}
349 | | ${rc} | ${msg}= | Run keyword and ignore error
350 | | ... | Dictionaries Should Be Equal
351 | | ... | ${setup_vpp_pids} | ${teardown_vpp_pids}
352 | | Run Keyword And Return If | '${rc}'=='FAIL' | Log | ${err_msg}
353 | | ... | console=yes | level=WARN
354
355 | Set up functional test
356 | | [Documentation] | Common test setup for functional tests.
357 | | ...
358 | | Configure all DUTs before test
359 | | Save VPP PIDs
360 | | Configure all TGs for traffic script
361 | | Update All Interface Data On All Nodes | ${nodes}
362 | | Reset VAT History On All DUTs | ${nodes}
363
364 | Tear down functional test
365 | | [Documentation] | Common test teardown for functional tests.
366 | | ...
367 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
368 | | Show Packet Trace on All DUTs | ${nodes}
369 | | Show VAT History On All DUTs | ${nodes}
370 | | Vpp Show Errors On All DUTs | ${nodes}
371 | | Verify VPP PID in Teardown
372
373 | Tear down LISP functional test
374 | | [Documentation] | Common test teardown for functional tests with LISP.
375 | | ...
376 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
377 | | Show Packet Trace on All DUTs | ${nodes}
378 | | Show VAT History On All DUTs | ${nodes}
379 | | Show Vpp Settings | ${nodes['DUT1']}
380 | | Show Vpp Settings | ${nodes['DUT2']}
381 | | Vpp Show Errors On All DUTs | ${nodes}
382 | | Verify VPP PID in Teardown
383
384 | Tear down LISP functional test with QEMU
385 | | [Documentation] | Common test teardown for functional tests with LISP and\
386 | | ... | QEMU.
387 | | ...
388 | | ... | *Arguments:*
389 | | ... | - vm_node - VM to stop. Type: string
390 | | ...
391 | | ... | *Example:*
392 | | ...
393 | | ... | \| Tear down LISP functional test with QEMU \| ${vm_node} \|
394 | | ...
395 | | [Arguments] | ${vm_node}
396 | | ...
397 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
398 | | Show Packet Trace on All DUTs | ${nodes}
399 | | Show VAT History On All DUTs | ${nodes}
400 | | Show Vpp Settings | ${nodes['DUT1']}
401 | | Show Vpp Settings | ${nodes['DUT2']}
402 | | Vpp Show Errors On All DUTs | ${nodes}
403 | | Stop and clear QEMU | ${nodes['DUT1']} | ${vm_node}
404 | | Verify VPP PID in Teardown
405
406 | Set up TAP functional test
407 | | [Documentation] | Common test setup for functional tests with TAP.
408 | | ...
409 | | Set up functional test
410 | | Clean Up Namespaces | ${nodes['DUT1']}
411
412 | Tear down TAP functional test
413 | | [Documentation] | Common test teardown for functional tests with TAP.
414 | | ...
415 | | Tear down functional test
416 | | Clean Up Namespaces | ${nodes['DUT1']}
417
418 | Tear down TAP functional test with Linux bridge
419 | | [Documentation] | Common test teardown for functional tests with TAP and
420 | | ... | a Linux bridge.
421 | | ...
422 | | ... | *Arguments:*
423 | | ... | - bid_TAP - Bridge name. Type: string
424 | | ...
425 | | ... | *Example:*
426 | | ...
427 | | ... | \| Tear down TAP functional test with Linux bridge \| ${bid_TAP} \|
428 | | ...
429 | | [Arguments] | ${bid_TAP}
430 | | ...
431 | | Tear down functional test
432 | | Linux Del Bridge | ${nodes['DUT1']} | ${bid_TAP}
433 | | Clean Up Namespaces | ${nodes['DUT1']}
434
435 | Tear down FDS functional test
436 | | [Documentation] | Common test teardown for FDS functional tests.
437 | | ...
438 | | ... | *Arguments:*
439 | | ... | - dut1_node - Node Nr.1 where to clean qemu. Type: dictionary
440 | | ... | - qemu_node1 - VM Nr.1 node info dictionary. Type: string
441 | | ... | - dut2_node - Node Nr.2 where to clean qemu. Type: dictionary
442 | | ... | - qemu_node2 - VM Nr.2 node info dictionary. Type: string
443 | | ...
444 | | ... | *Example:*
445 | | ...
446 | | ... | \| Tear down FDS functional test \| ${dut1_node} \| ${qemu_node1}\
447 | | ... | \| ${dut2_node} \| ${qemu_node2} \|
448 | | ...
449 | | [Arguments] | ${dut1_node} | ${qemu_node1} | ${dut2_node}
450 | | ... | ${qemu_node2}
451 | | ...
452 | | Tear down functional test
453 | | Tear down QEMU | ${dut1_node} | ${qemu_node1} | qemu_node1
454 | | Tear down QEMU | ${dut2_node} | ${qemu_node2} | qemu_node2
455
456 | Stop VPP Service on DUT
457 | | [Documentation] | Stop the VPP service on the specified node.
458 | | ...
459 | | ... | *Arguments:*
460 | | ... | - node - information about a DUT node. Type: dictionary
461 | | ...
462 | | ... | *Example:*
463 | | ...
464 | | ... | \| Stop VPP Service on DUT \| ${nodes['DUT1']} \|
465 | | ...
466 | | [Arguments] | ${node}
467 | | Stop VPP Service | ${node}
468
469 | Start VPP Service on DUT
470 | | [Documentation] | Start the VPP service on the specified node.
471 | | ...
472 | | ... | *Arguments:*
473 | | ... | - node - information about a DUT node. Type: dictionary
474 | | ...
475 | | ... | *Example:*
476 | | ...
477 | | ... | \| Start VPP Service on DUT \| ${nodes['DUT1']} \|
478 | | ...
479 | | [Arguments] | ${node}
480 | | Start VPP Service | ${node}

©2016 FD.io a Linux Foundation Collaborative Project. All Rights Reserved.
Linux Foundation is a registered trademark of The Linux Foundation. Linux is a registered trademark of Linus Torvalds.
Please see our privacy policy and terms of use.