Make default driver configurable
[csit.git] / resources / libraries / robot / shared / default.robot
1 # Copyright (c) 2016 Cisco and/or its affiliates.
2 # Licensed under the Apache License, Version 2.0 (the "License");
3 # you may not use this file except in compliance with the License.
4 # You may obtain a copy of the License at:
5 #
6 #     http://www.apache.org/licenses/LICENSE-2.0
7 #
8 # Unless required by applicable law or agreed to in writing, software
9 # distributed under the License is distributed on an "AS IS" BASIS,
10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11 # See the License for the specific language governing permissions and
12 # limitations under the License.
13
14 *** Settings ***
15 | Resource | resources/libraries/robot/vm/qemu.robot
16 | Resource | resources/libraries/robot/vm/double_qemu_setup.robot
17 | Variables | resources/libraries/python/topology.py
18 | Variables | resources/libraries/python/VatHistory.py
19 | Library | resources.libraries.python.topology.Topology
20 | Library | resources.libraries.python.VatHistory
21 | Library | resources.libraries.python.CpuUtils
22 | Library | resources.libraries.python.DUTSetup
23 | Library | resources.libraries.python.SchedUtils
24 | Library | resources.libraries.python.TGSetup
25 | Library | resources.libraries.python.L2Util
26 | Library | resources.libraries.python.Tap
27 | Library | resources.libraries.python.VppCounters
28 | Library | resources.libraries.python.VPPUtil
29 | Library | resources.libraries.python.Trace
30 | Library | Collections
31
32 *** Keywords ***
33 | Configure all DUTs before test
34 | | [Documentation] | Setup all DUTs in topology before test execution.
35 | | ...
36 | | Setup All DUTs | ${nodes}
37
38 | Configure all TGs for traffic script
39 | | [Documentation] | Prepare all TGs before traffic scripts execution.
40 | | ...
41 | | All TGs Set Interface Default Driver | ${nodes}
42
43 | Show Vpp Errors On All DUTs
44 | | [Documentation] | Show VPP errors verbose on all DUTs.
45 | | ...
46 | | ${duts}= | Get Matches | ${nodes} | DUT*
47 | | :FOR | ${dut} | IN | @{duts}
48 | | | Vpp Show Errors | ${nodes['${dut}']}
49
50 | Show VPP trace dump on all DUTs
51 | | [Documentation] | Save API trace and dump output on all DUTs.
52 | | ...
53 | | ${duts}= | Get Matches | ${nodes} | DUT*
54 | | :FOR | ${dut} | IN | @{duts}
55 | | | Vpp api trace save | ${nodes['${dut}']}
56 | | | Vpp api trace dump | ${nodes['${dut}']}
57
58 | Show Bridge Domain Data On All DUTs
59 | | [Documentation] | Show Bridge Domain data on all DUTs.
60 | | ...
61 | | ${duts}= | Get Matches | ${nodes} | DUT*
62 | | :FOR | ${dut} | IN | @{duts}
63 | | | Vpp Get Bridge Domain Data | ${nodes['${dut}']}
64
65 | Setup Scheduler Policy for Vpp On All DUTs
66 | | [Documentation] | Set realtime scheduling policy (SCHED_RR) with priority 1
67 | | ... | on all VPP worker threads on all DUTs.
68 | | ...
69 | | ${duts}= | Get Matches | ${nodes} | DUT*
70 | | :FOR | ${dut} | IN | @{duts}
71 | | | Set VPP Scheduling rr | ${nodes['${dut}']}
72
73 | Configure crypto device on all DUTs
74 | | [Documentation] | Verify if Crypto QAT device virtual functions are
75 | | ... | initialized on all DUTs. If parameter force_init is set to True, then
76 | | ... | try to initialize/disable.
77 | | ...
78 | | ... | *Arguments:*
79 | | ... | - force_init - Force to initialize. Type: boolean
80 | | ... | - numvfs - Number of VFs to initialize, 0 - disable the VFs
81 | | ... | (Optional). Type: integer, default value: ${32}
82 | | ...
83 | | ... | *Example:*
84 | | ...
85 | | ... | \| Configure crypto device on all DUTs \| ${True} \|
86 | | ...
87 | | [Arguments] | ${force_init}=${False} | ${numvfs}=${32}
88 | | ...
89 | | ${duts}= | Get Matches | ${nodes} | DUT*
90 | | :FOR | ${dut} | IN | @{duts}
91 | | | Crypto Device Verify | ${nodes['${dut}']} | force_init=${force_init}
92 | | | ... | numvfs=${numvfs}
93
94 | Configure kernel module on all DUTs
95 | | [Documentation] | Verify if specific kernel module is loaded on all DUTs.
96 | | ... | If parameter force_load is set to True, then try to initialize.
97 | | ...
98 | | ... | *Arguments:*
99 | | ... | - module - Module to verify. Type: string
100 | | ... | - force_load - Try to load module. Type: boolean
101 | | ...
102 | | ... | *Example:*
103 | | ...
104 | | ... | \| Configure kernel module on all DUTs \| ${True} \|
105 | | ...
106 | | [Arguments] | ${module} | ${force_load}=${False}
107 | | ...
108 | | ${duts}= | Get Matches | ${nodes} | DUT*
109 | | :FOR | ${dut} | IN | @{duts}
110 | | | Kernel Module Verify | ${nodes['${dut}']} | ${module}
111 | | | ... | force_load=${force_load}
112
113 | Create base startup configuration of VPP on all DUTs
114 | | [Documentation] | Create base startup configuration of VPP to all DUTs.
115 | | ...
116 | | ${duts}= | Get Matches | ${nodes} | DUT*
117 | | :FOR | ${dut} | IN | @{duts}
118 | | | Import Library | resources.libraries.python.VppConfigGenerator
119 | | | ... | WITH NAME | ${dut}
120 | | | Run keyword | ${dut}.Set Node |  ${nodes['${dut}']}
121 | | | Run keyword | ${dut}.Add Unix Log
122 | | | Run keyword | ${dut}.Add Unix CLI Listen
123 | | | Run keyword | ${dut}.Add Unix Nodaemon
124 | | | Run keyword | ${dut}.Add DPDK Socketmem | 1024,1024
125 | | | Run keyword | ${dut}.Add DPDK No Tx Checksum Offload
126 | | | Run keyword | ${dut}.Add DPDK Log Level | debug
127 | | | Run keyword | ${dut}.Add DPDK Uio Driver | ${uio_driver}
128 | | | Run keyword | ${dut}.Add Heapsize | 4G
129 | | | Run keyword | ${dut}.Add Plugin | disable | default
130 | | | Run keyword | ${dut}.Add Plugin | enable | @{plugins_to_enable}
131 | | | Run keyword | ${dut}.Add IP6 Hash Buckets | 2000000
132 | | | Run keyword | ${dut}.Add IP6 Heap Size | 4G
133 | | | Run keyword | ${dut}.Add IP Heap Size | 4G
134
135 # The following keyword results in lines longer than 80 characters.
136 # FIXME: Rename the keyword, possibly moving arguments out of the keyword name.
137 | Add '${m}' worker threads and '${n}' rxqueues in 3-node single-link circular topology
138 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
139 | | ... | configuration on all DUTs in 3-node single-link topology.
140 | | ...
141 | | ${m_int}= | Convert To Integer | ${m}
142 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
143 | | ... | ${dut1_if1} | ${dut1_if2}
144 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
145 | | ... | ${dut2_if1} | ${dut2_if2}
146 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
147 | | ... | skip_cnt=${1} | cpu_cnt=${1}
148 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
149 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
150 | | ${dut2_cpu_main}= | Cpu list per node str | ${dut2} | ${dut2_numa}
151 | | ... | skip_cnt=${1} | cpu_cnt=${1}
152 | | ${dut2_cpu_w}= | Cpu list per node str | ${dut2} | ${dut2_numa}
153 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
154 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
155 | | Run keyword | DUT2.Add CPU Main Core | ${dut2_cpu_main}
156 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
157 | | Run keyword | DUT2.Add CPU Corelist Workers | ${dut2_cpu_w}
158 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
159 | | Run keyword | DUT2.Add DPDK Dev Default RXQ | ${n}
160
161 | Add '${m}' worker threads and '${n}' rxqueues in 2-node single-link circular topology
162 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
163 | | ... | configuration on all DUTs in 2-node single-link topology.
164 | | ...
165 | | ${m_int}= | Convert To Integer | ${m}
166 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
167 | | ... | ${dut1_if1} | ${dut1_if2}
168 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
169 | | ... | skip_cnt=${1} | cpu_cnt=${1}
170 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
171 | | ... | skip_cnt=${2} | cpu_cnt=${m_int}
172 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
173 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
174 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
175
176 | Add '${m}' worker threads using SMT and '${n}' rxqueues in 3-node single-link circular topology
177 | | [Documentation] | Setup M worker threads using SMT and N rxqueues in vpp\
178 | | ... | startup configuration on all DUTs in 3-node single-link topology.
179 | | ...
180 | | ${m_int}= | Convert To Integer | ${m}
181 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
182 | | ... | ${dut1_if1} | ${dut1_if2}
183 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
184 | | ... | ${dut2_if1} | ${dut2_if2}
185 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
186 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
187 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
188 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
189 | | ${dut2_cpu_main}= | Cpu list per node str | ${dut2} | ${dut2_numa}
190 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
191 | | ${dut2_cpu_w}= | Cpu list per node str | ${dut2} | ${dut2_numa}
192 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
193 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
194 | | Run keyword | DUT2.Add CPU Main Core | ${dut2_cpu_main}
195 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
196 | | Run keyword | DUT2.Add CPU Corelist Workers | ${dut2_cpu_w}
197 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
198 | | Run keyword | DUT2.Add DPDK Dev Default RXQ | ${n}
199
200 | Add '${m}' worker threads using SMT and '${n}' rxqueues in 2-node single-link circular topology
201 | | [Documentation] | Setup M worker threads and N rxqueues in vpp startup\
202 | | ... | configuration on all DUTs in 2-node single-link topology.
203 | | ...
204 | | ${m_int}= | Convert To Integer | ${m}
205 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
206 | | ... | ${dut1_if1} | ${dut1_if2}
207 | | ${dut1_cpu_main}= | Cpu list per node str | ${dut1} | ${dut1_numa}
208 | | ... | skip_cnt=${1} | cpu_cnt=${1} | smt_used=${True}
209 | | ${dut1_cpu_w}= | Cpu list per node str | ${dut1} | ${dut1_numa}
210 | | ... | skip_cnt=${2} | cpu_cnt=${m_int} | smt_used=${True}
211 | | Run keyword | DUT1.Add CPU Main Core | ${dut1_cpu_main}
212 | | Run keyword | DUT1.Add CPU Corelist Workers | ${dut1_cpu_w}
213 | | Run keyword | DUT1.Add DPDK Dev Default RXQ | ${n}
214
215 | Add no multi seg to all DUTs
216 | | [Documentation] | Add No Multi Seg to VPP startup configuration to all DUTs.
217 | | ...
218 | | ${duts}= | Get Matches | ${nodes} | DUT*
219 | | :FOR | ${dut} | IN | @{duts}
220 | | | Run keyword | ${dut}.Add DPDK No Multi Seg
221
222 | Add DPDK dev default RXD to all DUTs
223 | | [Documentation] | Add DPDK num-rx-desc to VPP startup configuration to all
224 | | ... | DUTs.
225 | | ...
226 | | ... | *Arguments:*
227 | | ... | - rxd - Number of RX descriptors. Type: string
228 | | ...
229 | | ... | *Example:*
230 | | ...
231 | | ... | \| Add DPDK dev default RXD to all DUTs \| ${rxd} \|
232 | | ...
233 | | [Arguments] | ${rxd}
234 | | ...
235 | | ${duts}= | Get Matches | ${nodes} | DUT*
236 | | :FOR | ${dut} | IN | @{duts}
237 | | | Run keyword | ${dut}.Add DPDK Dev Default RXD | ${rxd}
238
239 | Add DPDK dev default TXD to all DUTs
240 | | [Documentation] | Add DPDK num-tx-desc to VPP startup configuration to all
241 | | ... | DUTs.
242 | | ...
243 | | ... | *Arguments:*
244 | | ... | - txd - Number of TX descriptors. Type: string
245 | | ...
246 | | ... | *Example:*
247 | | ...
248 | | ... | \| Add DPDK dev default TXD to all DUTs \| ${txd} \|
249 | | ...
250 | | [Arguments] | ${txd}
251 | | ...
252 | | ${duts}= | Get Matches | ${nodes} | DUT*
253 | | :FOR | ${dut} | IN | @{duts}
254 | | | Run keyword | ${dut}.Add DPDK Dev Default TXD | ${txd}
255
256 | Add DPDK Uio Driver on all DUTs
257 | | [Documentation] | Add DPDK uio driver to VPP startup configuration on all
258 | | ... | DUTs.
259 | | ...
260 | | ... | *Arguments:*
261 | | ... | - uio_driver - Required uio driver. Type: string
262 | | ...
263 | | ... | *Example:*
264 | | ...
265 | | ... | \| Add DPDK Uio Driver on all DUTs \| igb_uio \|
266 | | ...
267 | | [Arguments] | ${uio_driver}
268 | | ...
269 | | ${duts}= | Get Matches | ${nodes} | DUT*
270 | | :FOR | ${dut} | IN | @{duts}
271 | | | Run keyword | ${dut}.Add DPDK Uio Driver | ${uio_driver}
272
273 | Add NAT to all DUTs
274 | | [Documentation] | Add NAT configuration to all DUTs.
275 | | ...
276 | | ${duts}= | Get Matches | ${nodes} | DUT*
277 | | :FOR | ${dut} | IN | @{duts}
278 | | | Run keyword | ${dut}.Add NAT
279
280 | Add cryptodev to all DUTs
281 | | [Documentation] | Add Cryptodev to VPP startup configuration to all DUTs.
282 | | ...
283 | | ... | *Arguments:*
284 | | ... | - count - Number of QAT devices. Type: integer
285 | | ...
286 | | ... | *Example:*
287 | | ...
288 | | ... | \| Add cryptodev to all DUTs \| ${4} \|
289 | | ...
290 | | [Arguments] | ${count}
291 | | ${duts}= | Get Matches | ${nodes} | DUT*
292 | | :FOR | ${dut} | IN | @{duts}
293 | | | Run keyword | ${dut}.Add DPDK Cryptodev | ${count}
294
295 | Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
296 | | [Documentation] | Add required number of SW crypto devices of given type
297 | | ... | to VPP startup configuration on all DUTs in 3-node single-link
298 | | ... | circular topology.
299 | | ...
300 | | ... | *Arguments:*
301 | | ... | - sw_pmd_type - PMD type of SW crypto device. Type: string
302 | | ... | - count - Number of SW crypto devices. Type: string
303 | | ...
304 | | ... | *Example:*
305 | | ...
306 | | ... | \| Add DPDK SW cryptodev on DUTs in 3-node single-link circular\
307 | | ... | topology \| aesni-mb \| ${2} \|
308 | | ...
309 | | [Arguments] | ${sw_pmd_type} | ${count}
310 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT1']} | ${dut1_if2}
311 | | Run keyword | DUT1.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
312 | | ... | ${count}
313 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT2']} | ${dut2_if1}
314 | | Run keyword | DUT2.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
315 | | ... | ${count}
316
317 | Apply startup configuration on all VPP DUTs
318 | | [Documentation] | Write startup configuration and restart VPP on all DUTs.
319 | | ...
320 | | ... | *Arguments:*
321 | | ... | - restart_vpp - Whether to restart VPP (Optional). Type: boolean
322 | | ...
323 | | ... | *Example:*
324 | | ...
325 | | ... | \| Apply startup configuration on all VPP DUTs \| ${False} \|
326 | | ...
327 | | [Arguments] | ${restart_vpp}=${True}
328 | | ...
329 | | ${duts}= | Get Matches | ${nodes} | DUT*
330 | | :FOR | ${dut} | IN | @{duts}
331 | | | Run keyword | ${dut}.Apply Config | restart_vpp=${restart_vpp}
332 | | Update All Interface Data On All Nodes | ${nodes} | skip_tg=${True}
333
334 | Save VPP PIDs
335 | | [Documentation] | Get PIDs of VPP processes from all DUTs in topology and\
336 | | ... | set it as a test variable. The PIDs are stored as dictionary items\
337 | | ... | where the key is the host and the value is the PID.
338 | | ...
339 | | ${setup_vpp_pids}= | Get VPP PIDs | ${nodes}
340 | | ${keys}= | Get Dictionary Keys | ${setup_vpp_pids}
341 | | :FOR | ${key} | IN | @{keys}
342 | | | ${pid}= | Get From Dictionary | ${setup_vpp_pids} | ${key}
343 | | | Run Keyword If | $pid is None | FAIL | No VPP PID found on node ${key}
344 | | | Run Keyword If | ',' in '${pid}'
345 | | | ... | FAIL | More then one VPP PID found on node ${key}: ${pid}
346 | | Set Test Variable | ${setup_vpp_pids}
347
348 | Verify VPP PID in Teardown
349 | | [Documentation] | Check if the VPP PIDs on all DUTs are the same at the end\
350 | | ... | of test as they were at the begining. If they are not, only a message\
351 | | ... | is printed on console and to log. The test will not fail.
352 | | ...
353 | | ${teardown_vpp_pids}= | Get VPP PIDs | ${nodes}
354 | | ${err_msg}= | Catenate | ${SUITE NAME} - ${TEST NAME}
355 | | ... | \nThe VPP PIDs are not equal!\nTest Setup VPP PIDs:
356 | | ... | ${setup_vpp_pids}\nTest Teardown VPP PIDs: ${teardown_vpp_pids}
357 | | ${rc} | ${msg}= | Run keyword and ignore error
358 | | ... | Dictionaries Should Be Equal
359 | | ... | ${setup_vpp_pids} | ${teardown_vpp_pids}
360 | | Run Keyword And Return If | '${rc}'=='FAIL' | Log | ${err_msg}
361 | | ... | console=yes | level=WARN
362
363 | Set up functional test
364 | | [Documentation] | Common test setup for functional tests.
365 | | ...
366 | | Configure all DUTs before test
367 | | Save VPP PIDs
368 | | Configure all TGs for traffic script
369 | | Update All Interface Data On All Nodes | ${nodes}
370 | | Reset VAT History On All DUTs | ${nodes}
371
372 | Tear down functional test
373 | | [Documentation] | Common test teardown for functional tests.
374 | | ...
375 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
376 | | Show Packet Trace on All DUTs | ${nodes}
377 | | Show VAT History On All DUTs | ${nodes}
378 | | Vpp Show Errors On All DUTs | ${nodes}
379 | | Verify VPP PID in Teardown
380
381 | Tear down LISP functional test
382 | | [Documentation] | Common test teardown for functional tests with LISP.
383 | | ...
384 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
385 | | Show Packet Trace on All DUTs | ${nodes}
386 | | Show VAT History On All DUTs | ${nodes}
387 | | Show Vpp Settings | ${nodes['DUT1']}
388 | | Show Vpp Settings | ${nodes['DUT2']}
389 | | Vpp Show Errors On All DUTs | ${nodes}
390 | | Verify VPP PID in Teardown
391
392 | Tear down LISP functional test with QEMU
393 | | [Documentation] | Common test teardown for functional tests with LISP and\
394 | | ... | QEMU.
395 | | ...
396 | | ... | *Arguments:*
397 | | ... | - vm_node - VM to stop. Type: string
398 | | ...
399 | | ... | *Example:*
400 | | ...
401 | | ... | \| Tear down LISP functional test with QEMU \| ${vm_node} \|
402 | | ...
403 | | [Arguments] | ${vm_node}
404 | | ...
405 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
406 | | Show Packet Trace on All DUTs | ${nodes}
407 | | Show VAT History On All DUTs | ${nodes}
408 | | Show Vpp Settings | ${nodes['DUT1']}
409 | | Show Vpp Settings | ${nodes['DUT2']}
410 | | Vpp Show Errors On All DUTs | ${nodes}
411 | | Stop and clear QEMU | ${nodes['DUT1']} | ${vm_node}
412 | | Verify VPP PID in Teardown
413
414 | Set up TAP functional test
415 | | [Documentation] | Common test setup for functional tests with TAP.
416 | | ...
417 | | Set up functional test
418 | | Clean Up Namespaces | ${nodes['DUT1']}
419
420 | Tear down TAP functional test
421 | | [Documentation] | Common test teardown for functional tests with TAP.
422 | | ...
423 | | Tear down functional test
424 | | Clean Up Namespaces | ${nodes['DUT1']}
425
426 | Tear down TAP functional test with Linux bridge
427 | | [Documentation] | Common test teardown for functional tests with TAP and
428 | | ... | a Linux bridge.
429 | | ...
430 | | ... | *Arguments:*
431 | | ... | - bid_TAP - Bridge name. Type: string
432 | | ...
433 | | ... | *Example:*
434 | | ...
435 | | ... | \| Tear down TAP functional test with Linux bridge \| ${bid_TAP} \|
436 | | ...
437 | | [Arguments] | ${bid_TAP}
438 | | ...
439 | | Tear down functional test
440 | | Linux Del Bridge | ${nodes['DUT1']} | ${bid_TAP}
441 | | Clean Up Namespaces | ${nodes['DUT1']}
442
443 | Tear down FDS functional test
444 | | [Documentation] | Common test teardown for FDS functional tests.
445 | | ...
446 | | ... | *Arguments:*
447 | | ... | - dut1_node - Node Nr.1 where to clean qemu. Type: dictionary
448 | | ... | - qemu_node1 - VM Nr.1 node info dictionary. Type: string
449 | | ... | - dut2_node - Node Nr.2 where to clean qemu. Type: dictionary
450 | | ... | - qemu_node2 - VM Nr.2 node info dictionary. Type: string
451 | | ...
452 | | ... | *Example:*
453 | | ...
454 | | ... | \| Tear down FDS functional test \| ${dut1_node} \| ${qemu_node1}\
455 | | ... | \| ${dut2_node} \| ${qemu_node2} \|
456 | | ...
457 | | [Arguments] | ${dut1_node} | ${qemu_node1} | ${dut2_node}
458 | | ... | ${qemu_node2}
459 | | ...
460 | | Tear down functional test
461 | | Tear down QEMU | ${dut1_node} | ${qemu_node1} | qemu_node1
462 | | Tear down QEMU | ${dut2_node} | ${qemu_node2} | qemu_node2
463
464 | Stop VPP Service on DUT
465 | | [Documentation] | Stop the VPP service on the specified node.
466 | | ...
467 | | ... | *Arguments:*
468 | | ... | - node - information about a DUT node. Type: dictionary
469 | | ...
470 | | ... | *Example:*
471 | | ...
472 | | ... | \| Stop VPP Service on DUT \| ${nodes['DUT1']} \|
473 | | ...
474 | | [Arguments] | ${node}
475 | | Stop VPP Service | ${node}
476
477 | Start VPP Service on DUT
478 | | [Documentation] | Start the VPP service on the specified node.
479 | | ...
480 | | ... | *Arguments:*
481 | | ... | - node - information about a DUT node. Type: dictionary
482 | | ...
483 | | ... | *Example:*
484 | | ...
485 | | ... | \| Start VPP Service on DUT \| ${nodes['DUT1']} \|
486 | | ...
487 | | [Arguments] | ${node}
488 | | Start VPP Service | ${node}

©2016 FD.io a Linux Foundation Collaborative Project. All Rights Reserved.
Linux Foundation is a registered trademark of The Linux Foundation. Linux is a registered trademark of Linus Torvalds.
Please see our privacy policy and terms of use.