resources/libraries/robot/shared/default.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/vm/qemu.robot
  16 | Resource | resources/libraries/robot/vm/double_qemu_setup.robot
  17 | Variables | resources/libraries/python/topology.py
  18 | Variables | resources/libraries/python/VatHistory.py
  19 | Library | resources.libraries.python.topology.Topology
  20 | Library | resources.libraries.python.VatHistory
  21 | Library | resources.libraries.python.CpuUtils
  22 | Library | resources.libraries.python.DUTSetup
  23 | Library | resources.libraries.python.SchedUtils
  24 | Library | resources.libraries.python.TGSetup
  25 | Library | resources.libraries.python.L2Util
  26 | Library | resources.libraries.python.Tap
  27 | Library | resources.libraries.python.VppCounters
  28 | Library | resources.libraries.python.VPPUtil
  29 | Library | resources.libraries.python.Trace
  30 | Library | Collections
  31
  32 *** Keywords ***
  33 | Configure all DUTs before test
  34 | | [Documentation] | Setup all DUTs in topology before test execution.
  35 | | ...
  36 | | Setup All DUTs | ${nodes}
  37
  38 | Configure all TGs for traffic script
  39 | | [Documentation] | Prepare all TGs before traffic scripts execution.
  40 | | ...
  41 | | All TGs Set Interface Default Driver | ${nodes}
  42
  43 | Show Vpp Errors On All DUTs
  44 | | [Documentation] | Show VPP errors verbose on all DUTs.
  45 | | ...
  46 | | ${duts}= | Get Matches | ${nodes} | DUT*
  47 | | :FOR | ${dut} | IN | @{duts}
  48 | | | Vpp Show Errors | ${nodes['${dut}']}
  49
  50 | Show VPP trace dump on all DUTs
  51 | | [Documentation] | Save API trace and dump output on all DUTs.
  52 | | ...
  53 | | ${duts}= | Get Matches | ${nodes} | DUT*
  54 | | :FOR | ${dut} | IN | @{duts}
  55 | | | Vpp api trace save | ${nodes['${dut}']}
  56 | | | Vpp api trace dump | ${nodes['${dut}']}
  57
  58 | Show Bridge Domain Data On All DUTs
  59 | | [Documentation] | Show Bridge Domain data on all DUTs.
  60 | | ...
  61 | | ${duts}= | Get Matches | ${nodes} | DUT*
  62 | | :FOR | ${dut} | IN | @{duts}
  63 | | | Vpp Get Bridge Domain Data | ${nodes['${dut}']}
  64
  65 | Setup Scheduler Policy for Vpp On All DUTs
  66 | | [Documentation] | Set realtime scheduling policy (SCHED_RR) with priority 1
  67 | | ... | on all VPP worker threads on all DUTs.
  68 | | ...
  69 | | ${duts}= | Get Matches | ${nodes} | DUT*
  70 | | :FOR | ${dut} | IN | @{duts}
  71 | | | Set VPP Scheduling rr | ${nodes['${dut}']}
  72
  73 | Configure crypto device on all DUTs
  74 | | [Documentation] | Verify if Crypto QAT device virtual functions are
  75 | | ... | initialized on all DUTs. If parameter force_init is set to True, then
  76 | | ... | try to initialize/disable.
  77 | | ...
  78 | | ... | *Arguments:*
  79 | | ... | - force_init - Force to initialize. Type: boolean
  80 | | ... | - numvfs - Number of VFs to initialize, 0 - disable the VFs
  81 | | ... | (Optional). Type: integer, default value: ${32}
  82 | | ...
  83 | | ... | *Example:*
  84 | | ...
  85 | | ... | \| Configure crypto device on all DUTs \| ${True} \|
  86 | | ...
  87 | | [Arguments] | ${force_init}=${False} | ${numvfs}=${32}
  88 | | ...
  89 | | ${duts}= | Get Matches | ${nodes} | DUT*
  90 | | :FOR | ${dut} | IN | @{duts}
  91 | | | Crypto Device Verify | ${nodes['${dut}']} | force_init=${force_init}
  92 | | | ... | numvfs=${numvfs}
  93
  94 | Configure kernel module on all DUTs
  95 | | [Documentation] | Verify if specific kernel module is loaded on all DUTs.
  96 | | ... | If parameter force_load is set to True, then try to initialize.
  97 | | ...
  98 | | ... | *Arguments:*
  99 | | ... | - module - Module to verify. Type: string
 100 | | ... | - force_load - Try to load module. Type: boolean
 101 | | ...
 102 | | ... | *Example:*
 103 | | ...
 104 | | ... | \| Configure kernel module on all DUTs \| ${True} \|
 105 | | ...
 106 | | [Arguments] | ${module} | ${force_load}=${False}
 107 | | ...
 108 | | ${duts}= | Get Matches | ${nodes} | DUT*
 109 | | :FOR | ${dut} | IN | @{duts}
 110 | | | Kernel Module Verify | ${nodes['${dut}']} | ${module}
 111 | | | ... | force_load=${force_load}
 112
 113 | Create base startup configuration of VPP on all DUTs
 114 | | [Documentation] | Create base startup configuration of VPP to all DUTs.
 115 | | ...
 116 | | ${duts}= | Get Matches | ${nodes} | DUT*
 117 | | :FOR | ${dut} | IN | @{duts}
 118 | | | Import Library | resources.libraries.python.VppConfigGenerator
 119 | | | ... | WITH NAME | ${dut}
 120 | | | Run keyword | ${dut}.Set Node |  ${nodes['${dut}']}
 121 | | | Run keyword | ${dut}.Add Unix Log
 122 | | | Run keyword | ${dut}.Add Unix CLI Listen
 123 | | | Run keyword | ${dut}.Add Unix Nodaemon
 124 | | | Run keyword | ${dut}.Add Unix Coredump
 125 | | | Run keyword | ${dut}.Add DPDK Socketmem | 1024,1024
 126 | | | Run keyword | ${dut}.Add DPDK No Tx Checksum Offload
 127 | | | Run keyword | ${dut}.Add DPDK Log Level | debug
 128 | | | Run keyword | ${dut}.Add DPDK Uio Driver
 129 | | | Run keyword | ${dut}.Add Heapsize | 4G
 130 | | | Run keyword | ${dut}.Add Statseg size | 4G
 131 | | | Run keyword | ${dut}.Add Plugin | disable | default
 132 | | | Run keyword | ${dut}.Add Plugin | enable | @{plugins_to_enable}
 133 | | | Run keyword | ${dut}.Add IP6 Hash Buckets | 2000000
 134 | | | Run keyword | ${dut}.Add IP6 Heap Size | 4G
 135 | | | Run keyword | ${dut}.Add IP Heap Size | 4G
 136
 137 | Add worker threads and rxqueues to all DUTs
 138 | | [Documentation] | Setup worker threads and rxqueues in vpp startup
 139 | | ... | configuration on all DUTs. Based on the SMT configuration of DUT if
 140 | | ... | enabled keyword will automatically map also the sibling logical cores.
 141 | | ... | Keyword will automatically set the appropriate test TAGs in format
 142 | | ... | mTnC, where m=logical_core_count and n=physical_core_count.
 143 | | ...
 144 | | ... | *Arguments:*
 145 | | ... | - phy_cores - Number of physical cores to use. Type: integer
 146 | | ... | - rx_queues - Number of RX queues. Type: integer
 147 | | ...
 148 | | ... | *Example:*
 149 | | ...
 150 | | ... | \| Add worker threads and rxqueues to all DUTs \| ${1} \| ${1} \|
 151 | | ...
 152 | | [Arguments] | ${phy_cores} | ${rx_queues}=${None}
 153 | | ...
 154 | | ${cpu_count_int} | Convert to Integer | ${phy_cores}
 155 | | ${thr_count_int} | Convert to Integer | ${phy_cores}
 156 | | ${num_mbufs_int} | Convert to Integer | 16384
 157 | | ${duts}= | Get Matches | ${nodes} | DUT*
 158 | | :FOR | ${dut} | IN | @{duts}
 159 | | | ${if1_status} | ${value}= | Run Keyword And Ignore Error
 160 | | | ... | Variable Should Exist | ${${dut}_if1}
 161 | | | @{if_list}= | Run Keyword If | '${if1_status}' == 'PASS'
 162 | | | ... | Create List | ${${dut}_if1}
 163 | | | ... | ELSE | Create List | ${${dut}_if1_1} | ${${dut}_if1_2}
 164 | | | ${if2_status} | ${value}= | Run Keyword And Ignore Error
 165 | | | ... | Variable Should Exist | ${${dut}_if2}
 166 | | | Run Keyword If | '${if2_status}' == 'PASS'
 167 | | | ... | Append To List | ${if_list} | ${${dut}_if2}
 168 | | | ... | ELSE
 169 | | | ... | Append To List | ${if_list} | ${${dut}_if2_1} | ${${dut}_if2_2}
 170 | | | ${numa}= | Get interfaces numa node | ${nodes['${dut}']} | @{if_list}
 171 | | | ${smt_used}= | Is SMT enabled | ${nodes['${dut}']['cpuinfo']}
 172 | | | ${cpu_main}= | Cpu list per node str | ${nodes['${dut}']} | ${numa}
 173 | | | ... | skip_cnt=${1} | cpu_cnt=${1}
 174 | | | ${cpu_wt}= | Cpu list per node str | ${nodes['${dut}']} | ${numa}
 175 | | | ... | skip_cnt=${2} | cpu_cnt=${cpu_count_int} | smt_used=${smt_used}
 176 | | | ${thr_count_int}= | Run keyword if | ${smt_used}
 177 | | | ... | Evaluate | int(${cpu_count_int}*2)
 178 | | | ... | ELSE | Set variable | ${thr_count_int}
 179 | | | ${rxq_count_int}= | Run keyword if | ${rx_queues}
 180 | | | ... | Set variable | ${rx_queues}
 181 | | | ... | ELSE | Evaluate | int(${thr_count_int}/2)
 182 | | | ${rxq_count_int}= | Run keyword if | ${rxq_count_int} == 0
 183 | | | ... | Set variable | ${1}
 184 | | | ... | ELSE | Set variable | ${rxq_count_int}
 185 | | | ${num_mbufs_int}= | Evaluate | int(${num_mbufs_int}*${rxq_count_int})
 186 | | | Run keyword | ${dut}.Add CPU Main Core | ${cpu_main}
 187 | | | Run keyword | ${dut}.Add CPU Corelist Workers | ${cpu_wt}
 188 | | | Run keyword | ${dut}.Add DPDK Dev Default RXQ | ${rxq_count_int}
 189 | | | Run keyword | ${dut}.Add DPDK Num Mbufs | ${num_mbufs_int}
 190 | | | Run keyword if | ${thr_count_int} > 1
 191 | | | ... | Set Tags | MTHREAD | ELSE | Set Tags | STHREAD
 192 | | | Set Tags | ${thr_count_int}T${cpu_count_int}C
 193 | | Set Test Variable | ${smt_used}
 194 | | Set Test Variable | ${thr_count_int}
 195 | | Set Test Variable | ${cpu_count_int}
 196 | | Set Test Variable | ${rxq_count_int}
 197
 198 | Create Kubernetes VSWITCH startup config on all DUTs
 199 | | [Documentation] | Create base startup configuration of VSWITCH in Kubernetes
 200 | | ... | deploy to all DUTs.
 201 | | ...
 202 | | ... | *Arguments:*
 203 | | ... | - ${jumbo} - Jumbo packet. Type: boolean
 204 | | ... | - ${phy_cores} - Physical cores. Type: integer
 205 | | ... | - ${rxq} - RX queues. Type: integer
 206 | | ...
 207 | | ... | *Example:*
 208 | | ...
 209 | | ... | \| Create Kubernetes VSWITCH startup config on all DUTs \| ${True} \
 210 | | ... | \| ${1} \| ${1}
 211 | | ...
 212 | | [Arguments] | ${phy_cores} | ${rx_queues}=${None} | ${jumbo}=${False}
 213 | | ...
 214 | | ${cpu_count_int} | Convert to Integer | ${phy_cores}
 215 | | ${thr_count_int} | Convert to Integer | ${phy_cores}
 216 | | ${num_mbufs_int} | Convert to Integer | 16384
 217 | | ${duts}= | Get Matches | ${nodes} | DUT*
 218 | | :FOR | ${dut} | IN | @{duts}
 219 | | | ${numa}= | Get interfaces numa node | ${nodes['${dut}']}
 220 | | | ... | ${${dut}_if1} | ${${dut}_if2}
 221 | | | ${smt_used}= | Is SMT enabled | ${nodes['${dut}']['cpuinfo']}
 222 | | | ${if1_pci}= | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if1}
 223 | | | ${if2_pci}= | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if2}
 224 | | | ${thr_count_int}= | Run keyword if | ${smt_used}
 225 | | | ... | Evaluate | int(${cpu_count_int}*2)
 226 | | | ... | ELSE | Set variable | ${thr_count_int}
 227 | | | ${rxq_count_int}= | Run keyword if | ${rx_queues}
 228 | | | ... | Set variable | ${rx_queues}
 229 | | | ... | ELSE | Evaluate | int(${thr_count_int}/2)
 230 | | | ${rxq_count_int}= | Run keyword if | ${rxq_count_int} == 0
 231 | | | ... | Set variable | ${1}
 232 | | | ... | ELSE | Set variable | ${rxq_count_int}
 233 | | | ${num_mbufs_int}= | Evaluate | int(${num_mbufs_int}*${rxq_count_int})
 234 | | | ${config}= | Run keyword | Create Kubernetes VSWITCH startup config
 235 | | | ... | node=${nodes['${dut}']} | phy_cores=${phy_cores}
 236 | | | ... | cpu_node=${numa} | jumbo=${jumbo} | rxq_count_int=${rxq_count_int}
 237 | | | ... | num_mbufs_int=${num_mbufs_int}
 238 | | | ... | filename=/tmp/vswitch.conf | if1=${if1_pci} | if2=${if2_pci}
 239 | | | Run keyword if | ${thr_count_int} > 1
 240 | | | ... | Set Tags | MTHREAD | ELSE | Set Tags | STHREAD
 241 | | | Set Tags | ${thr_count_int}T${cpu_count_int}C
 242 | | Set Test Variable | ${smt_used}
 243 | | Set Test Variable | ${thr_count_int}
 244 | | Set Test Variable | ${cpu_count_int}
 245 | | Set Test Variable | ${rxq_count_int}
 246
 247 | Create Kubernetes VNF'${i}' startup config on all DUTs
 248 | | [Documentation] | Create base startup configuration of VNF in Kubernetes
 249 | | ... | deploy to all DUTs.
 250 | | ...
 251 | | ${i_int}= | Convert To Integer | ${i}
 252 | | ${cpu_skip}= | Evaluate | ${vswitch_cpus}+${system_cpus}
 253 | | ${dut1_numa}= | Get interfaces numa node | ${dut1}
 254 | | ... | ${dut1_if1} | ${dut1_if2}
 255 | | ${dut2_numa}= | Get interfaces numa node | ${dut2}
 256 | | ... | ${dut2_if1} | ${dut2_if2}
 257 | | ${config}= | Run keyword | Create Kubernetes VNF startup config
 258 | | ... | node=${dut1} | phy_cores=${vnf_cpus} | cpu_node=${dut1_numa}
 259 | | ... | cpu_skip=${cpu_skip} | filename=/tmp/vnf${i}.conf
 260 | | ... | i=${i_int}
 261 | | ${config}= | Run keyword | Create Kubernetes VNF startup config
 262 | | ... | node=${dut2} | phy_cores=${vnf_cpus} | cpu_node=${dut2_numa}
 263 | | ... | cpu_skip=${cpu_skip} | filename=/tmp/vnf${i}.conf
 264 | | ... | i=${i_int}
 265
 266 | Add no multi seg to all DUTs
 267 | | [Documentation] | Add No Multi Seg to VPP startup configuration to all DUTs.
 268 | | ...
 269 | | ${duts}= | Get Matches | ${nodes} | DUT*
 270 | | :FOR | ${dut} | IN | @{duts}
 271 | | | Run keyword | ${dut}.Add DPDK No Multi Seg
 272
 273 | Add DPDK dev default RXD to all DUTs
 274 | | [Documentation] | Add DPDK num-rx-desc to VPP startup configuration to all
 275 | | ... | DUTs.
 276 | | ...
 277 | | ... | *Arguments:*
 278 | | ... | - rxd - Number of RX descriptors. Type: string
 279 | | ...
 280 | | ... | *Example:*
 281 | | ...
 282 | | ... | \| Add DPDK dev default RXD to all DUTs \| ${rxd} \|
 283 | | ...
 284 | | [Arguments] | ${rxd}
 285 | | ...
 286 | | ${duts}= | Get Matches | ${nodes} | DUT*
 287 | | :FOR | ${dut} | IN | @{duts}
 288 | | | Run keyword | ${dut}.Add DPDK Dev Default RXD | ${rxd}
 289
 290 | Add DPDK dev default TXD to all DUTs
 291 | | [Documentation] | Add DPDK num-tx-desc to VPP startup configuration to all
 292 | | ... | DUTs.
 293 | | ...
 294 | | ... | *Arguments:*
 295 | | ... | - txd - Number of TX descriptors. Type: string
 296 | | ...
 297 | | ... | *Example:*
 298 | | ...
 299 | | ... | \| Add DPDK dev default TXD to all DUTs \| ${txd} \|
 300 | | ...
 301 | | [Arguments] | ${txd}
 302 | | ...
 303 | | ${duts}= | Get Matches | ${nodes} | DUT*
 304 | | :FOR | ${dut} | IN | @{duts}
 305 | | | Run keyword | ${dut}.Add DPDK Dev Default TXD | ${txd}
 306
 307 | Add DPDK Uio Driver on all DUTs
 308 | | [Documentation] | Add DPDK uio driver to VPP startup configuration on all
 309 | | ... | DUTs.
 310 | | ...
 311 | | ... | *Arguments:*
 312 | | ... | - uio_driver - Required uio driver. Type: string
 313 | | ...
 314 | | ... | *Example:*
 315 | | ...
 316 | | ... | \| Add DPDK Uio Driver on all DUTs \| igb_uio \|
 317 | | ...
 318 | | [Arguments] | ${uio_driver}
 319 | | ...
 320 | | ${duts}= | Get Matches | ${nodes} | DUT*
 321 | | :FOR | ${dut} | IN | @{duts}
 322 | | | Run keyword | ${dut}.Add DPDK Uio Driver | ${uio_driver}
 323
 324 | Add NAT to all DUTs
 325 | | [Documentation] | Add NAT configuration to all DUTs.
 326 | | ...
 327 | | ${duts}= | Get Matches | ${nodes} | DUT*
 328 | | :FOR | ${dut} | IN | @{duts}
 329 | | | Run keyword | ${dut}.Add NAT
 330
 331 | Add cryptodev to all DUTs
 332 | | [Documentation] | Add Cryptodev to VPP startup configuration to all DUTs.
 333 | | ...
 334 | | ... | *Arguments:*
 335 | | ... | - count - Number of QAT devices. Type: integer
 336 | | ...
 337 | | ... | *Example:*
 338 | | ...
 339 | | ... | \| Add cryptodev to all DUTs \| ${4} \|
 340 | | ...
 341 | | [Arguments] | ${count}
 342 | | ${duts}= | Get Matches | ${nodes} | DUT*
 343 | | :FOR | ${dut} | IN | @{duts}
 344 | | | ${smt_used}= | Is SMT enabled | ${nodes['${dut}']['cpuinfo']}
 345 | | | ${thr_count_int}= | Run keyword if | ${smt_used}
 346 | | | ... | Evaluate | int(${count}*2)
 347 | | | ... | ELSE | Set variable | ${count}
 348 | | | Run keyword | ${dut}.Add DPDK Cryptodev | ${thr_count_int}
 349
 350 | Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
 351 | | [Documentation] | Add required number of SW crypto devices of given type
 352 | | ... | to VPP startup configuration on all DUTs in 3-node single-link
 353 | | ... | circular topology.
 354 | | ...
 355 | | ... | *Arguments:*
 356 | | ... | - sw_pmd_type - PMD type of SW crypto device. Type: string
 357 | | ... | - count - Number of SW crypto devices. Type: string
 358 | | ...
 359 | | ... | *Example:*
 360 | | ...
 361 | | ... | \| Add DPDK SW cryptodev on DUTs in 3-node single-link circular\
 362 | | ... | topology \| aesni-mb \| ${2} \|
 363 | | ...
 364 | | [Arguments] | ${sw_pmd_type} | ${count}
 365 | | ${smt_used}= | Is SMT enabled | ${nodes['DUT1']['cpuinfo']}
 366 | | ${thr_count_int}= | Run keyword if | ${smt_used}
 367 | | ... | Evaluate | int(${count}*2)
 368 | | ... | ELSE | Set variable | ${count}
 369 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT1']} | ${dut1_if2}
 370 | | Run keyword | DUT1.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
 371 | | ... | ${thr_count_int}
 372 | | ${smt_used}= | Is SMT enabled | ${nodes['DUT2']['cpuinfo']}
 373 | | ${thr_count_int}= | Run keyword if | ${smt_used}
 374 | | ... | Evaluate | int(${count}*2)
 375 | | ... | ELSE | Set variable | ${count}
 376 | | ${socket_id}= | Get Interface Numa Node | ${nodes['DUT2']} | ${dut2_if1}
 377 | | Run keyword | DUT2.Add DPDK SW Cryptodev | ${sw_pmd_type} | ${socket_id}
 378 | | ... | ${thr_count_int}
 379
 380 | Apply startup configuration on all VPP DUTs
 381 | | [Documentation] | Write startup configuration and restart VPP on all DUTs.
 382 | | ...
 383 | | ... | *Arguments:*
 384 | | ... | - restart_vpp - Whether to restart VPP (Optional). Type: boolean
 385 | | ...
 386 | | ... | *Example:*
 387 | | ...
 388 | | ... | \| Apply startup configuration on all VPP DUTs \| ${False} \|
 389 | | ...
 390 | | [Arguments] | ${restart_vpp}=${True}
 391 | | ...
 392 | | ${duts}= | Get Matches | ${nodes} | DUT*
 393 | | :FOR | ${dut} | IN | @{duts}
 394 | | | Run keyword | ${dut}.Apply Config | restart_vpp=${restart_vpp}
 395 | | Update All Interface Data On All Nodes | ${nodes} | skip_tg=${True}
 396
 397 | Save VPP PIDs
 398 | | [Documentation] | Get PIDs of VPP processes from all DUTs in topology and\
 399 | | ... | set it as a test variable. The PIDs are stored as dictionary items\
 400 | | ... | where the key is the host and the value is the PID.
 401 | | ...
 402 | | ${setup_vpp_pids}= | Get VPP PIDs | ${nodes}
 403 | | ${keys}= | Get Dictionary Keys | ${setup_vpp_pids}
 404 | | :FOR | ${key} | IN | @{keys}
 405 | | | ${pid}= | Get From Dictionary | ${setup_vpp_pids} | ${key}
 406 | | | Run Keyword If | $pid is None | FAIL | No VPP PID found on node ${key}
 407 | | | Run Keyword If | ',' in '${pid}'
 408 | | | ... | FAIL | More then one VPP PID found on node ${key}: ${pid}
 409 | | Set Test Variable | ${setup_vpp_pids}
 410
 411 | Verify VPP PID in Teardown
 412 | | [Documentation] | Check if the VPP PIDs on all DUTs are the same at the end\
 413 | | ... | of test as they were at the begining. If they are not, only a message\
 414 | | ... | is printed on console and to log. The test will not fail.
 415 | | ...
 416 | | ${teardown_vpp_pids}= | Get VPP PIDs | ${nodes}
 417 | | ${err_msg}= | Catenate | ${SUITE NAME} - ${TEST NAME}
 418 | | ... | \nThe VPP PIDs are not equal!\nTest Setup VPP PIDs:
 419 | | ... | ${setup_vpp_pids}\nTest Teardown VPP PIDs: ${teardown_vpp_pids}
 420 | | ${rc} | ${msg}= | Run keyword and ignore error
 421 | | ... | Dictionaries Should Be Equal
 422 | | ... | ${setup_vpp_pids} | ${teardown_vpp_pids}
 423 | | Run Keyword And Return If | '${rc}'=='FAIL' | Log | ${err_msg}
 424 | | ... | console=yes | level=WARN
 425
 426 | Set up functional test
 427 | | [Documentation] | Common test setup for functional tests.
 428 | | ...
 429 | | Configure all DUTs before test
 430 | | Save VPP PIDs
 431 | | Configure all TGs for traffic script
 432 | | Update All Interface Data On All Nodes | ${nodes}
 433 | | Reset VAT History On All DUTs | ${nodes}
 434
 435 | Tear down functional test
 436 | | [Documentation] | Common test teardown for functional tests.
 437 | | ...
 438 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 439 | | Show Packet Trace on All DUTs | ${nodes}
 440 | | Show VAT History On All DUTs | ${nodes}
 441 | | Vpp Show Errors On All DUTs | ${nodes}
 442 | | Verify VPP PID in Teardown
 443
 444 | Tear down LISP functional test
 445 | | [Documentation] | Common test teardown for functional tests with LISP.
 446 | | ...
 447 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 448 | | Show Packet Trace on All DUTs | ${nodes}
 449 | | Show VAT History On All DUTs | ${nodes}
 450 | | Show Vpp Settings | ${nodes['DUT1']}
 451 | | Show Vpp Settings | ${nodes['DUT2']}
 452 | | Vpp Show Errors On All DUTs | ${nodes}
 453 | | Verify VPP PID in Teardown
 454
 455 | Tear down LISP functional test with QEMU
 456 | | [Documentation] | Common test teardown for functional tests with LISP and\
 457 | | ... | QEMU.
 458 | | ...
 459 | | ... | *Arguments:*
 460 | | ... | - vm_node - VM to stop. Type: string
 461 | | ...
 462 | | ... | *Example:*
 463 | | ...
 464 | | ... | \| Tear down LISP functional test with QEMU \| ${vm_node} \|
 465 | | ...
 466 | | [Arguments] | ${vm_node}
 467 | | ...
 468 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 469 | | Show Packet Trace on All DUTs | ${nodes}
 470 | | Show VAT History On All DUTs | ${nodes}
 471 | | Show Vpp Settings | ${nodes['DUT1']}
 472 | | Show Vpp Settings | ${nodes['DUT2']}
 473 | | Vpp Show Errors On All DUTs | ${nodes}
 474 | | Stop and clear QEMU | ${nodes['DUT1']} | ${vm_node}
 475 | | Verify VPP PID in Teardown
 476
 477 | Set up TAP functional test
 478 | | [Documentation] | Common test setup for functional tests with TAP.
 479 | | ...
 480 | | Set up functional test
 481 | | Clean Up Namespaces | ${nodes['DUT1']}
 482
 483 | Tear down TAP functional test
 484 | | [Documentation] | Common test teardown for functional tests with TAP.
 485 | | ...
 486 | | Tear down functional test
 487 | | Clean Up Namespaces | ${nodes['DUT1']}
 488
 489 | Tear down TAP functional test with Linux bridge
 490 | | [Documentation] | Common test teardown for functional tests with TAP and
 491 | | ... | a Linux bridge.
 492 | | ...
 493 | | ... | *Arguments:*
 494 | | ... | - bid_TAP - Bridge name. Type: string
 495 | | ...
 496 | | ... | *Example:*
 497 | | ...
 498 | | ... | \| Tear down TAP functional test with Linux bridge \| ${bid_TAP} \|
 499 | | ...
 500 | | [Arguments] | ${bid_TAP}
 501 | | ...
 502 | | Tear down functional test
 503 | | Linux Del Bridge | ${nodes['DUT1']} | ${bid_TAP}
 504 | | Clean Up Namespaces | ${nodes['DUT1']}
 505
 506 | Tear down FDS functional test
 507 | | [Documentation] | Common test teardown for FDS functional tests.
 508 | | ...
 509 | | ... | *Arguments:*
 510 | | ... | - dut1_node - Node Nr.1 where to clean qemu. Type: dictionary
 511 | | ... | - qemu_node1 - VM Nr.1 node info dictionary. Type: string
 512 | | ... | - dut2_node - Node Nr.2 where to clean qemu. Type: dictionary
 513 | | ... | - qemu_node2 - VM Nr.2 node info dictionary. Type: string
 514 | | ...
 515 | | ... | *Example:*
 516 | | ...
 517 | | ... | \| Tear down FDS functional test \| ${dut1_node} \| ${qemu_node1}\
 518 | | ... | \| ${dut2_node} \| ${qemu_node2} \|
 519 | | ...
 520 | | [Arguments] | ${dut1_node} | ${qemu_node1} | ${dut2_node}
 521 | | ... | ${qemu_node2}
 522 | | ...
 523 | | Tear down functional test
 524 | | Tear down QEMU | ${dut1_node} | ${qemu_node1} | qemu_node1
 525 | | Tear down QEMU | ${dut2_node} | ${qemu_node2} | qemu_node2
 526
 527 | Stop VPP Service on DUT
 528 | | [Documentation] | Stop the VPP service on the specified node.
 529 | | ...
 530 | | ... | *Arguments:*
 531 | | ... | - node - information about a DUT node. Type: dictionary
 532 | | ...
 533 | | ... | *Example:*
 534 | | ...
 535 | | ... | \| Stop VPP Service on DUT \| ${nodes['DUT1']} \|
 536 | | ...
 537 | | [Arguments] | ${node}
 538 | | Stop VPP Service | ${node}
 539
 540 | Start VPP Service on DUT
 541 | | [Documentation] | Start the VPP service on the specified node.
 542 | | ...
 543 | | ... | *Arguments:*
 544 | | ... | - node - information about a DUT node. Type: dictionary
 545 | | ...
 546 | | ... | *Example:*
 547 | | ...
 548 | | ... | \| Start VPP Service on DUT \| ${nodes['DUT1']} \|
 549 | | ...
 550 | | [Arguments] | ${node}
 551 | | Start VPP Service | ${node}