resources/libraries/robot/shared/default.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Variables | resources/libraries/python/topology.py
  16 | Variables | resources/libraries/python/PapiHistory.py
  17 | Variables | resources/libraries/python/Constants.py
  18 |
  19 | Library | Collections
  20 | Library | OperatingSystem
  21 | Library | String
  22 |
  23 | Library | resources.libraries.python.Classify
  24 | Library | resources.libraries.python.CpuUtils
  25 | Library | resources.libraries.python.CoreDumpUtil
  26 | Library | resources.libraries.python.Cop
  27 | Library | resources.libraries.python.DUTSetup
  28 | Library | resources.libraries.python.L2Util
  29 | Library | resources.libraries.python.InterfaceUtil
  30 | Library | resources.libraries.python.IPUtil
  31 | Library | resources.libraries.python.IPv6Util
  32 | Library | resources.libraries.python.NodePath
  33 | Library | resources.libraries.python.Namespaces
  34 | Library | resources.libraries.python.PapiHistory
  35 | Library | resources.libraries.python.SchedUtils
  36 | Library | resources.libraries.python.Tap
  37 | Library | resources.libraries.python.TestConfig
  38 | Library | resources.libraries.python.TGSetup
  39 | Library | resources.libraries.python.topology.Topology
  40 | Library | resources.libraries.python.Trace
  41 | Library | resources.libraries.python.VppCounters
  42 | Library | resources.libraries.python.VPPUtil
  43 |
  44 | Resource | resources/libraries/robot/lb/load_balancer.robot
  45 | Resource | resources/libraries/robot/crypto/ipsec.robot
  46 | Resource | resources/libraries/robot/features/acl.robot
  47 | Resource | resources/libraries/robot/features/gbp.robot
  48 | Resource | resources/libraries/robot/features/policer.robot
  49 | Resource | resources/libraries/robot/ip/ip4.robot
  50 | Resource | resources/libraries/robot/ip/ip6.robot
  51 | Resource | resources/libraries/robot/ip/nat.robot
  52 | Resource | resources/libraries/robot/l2/l2_bridge_domain.robot
  53 | Resource | resources/libraries/robot/l2/l2_patch.robot
  54 | Resource | resources/libraries/robot/l2/l2_traffic.robot
  55 | Resource | resources/libraries/robot/l2/l2_xconnect.robot
  56 | Resource | resources/libraries/robot/l2/tagging.robot
  57 | Resource | resources/libraries/robot/overlay/srv6.robot
  58 | Resource | resources/libraries/robot/overlay/lisp.robot
  59 | Resource | resources/libraries/robot/overlay/lispgpe.robot
  60 | Resource | resources/libraries/robot/overlay/lisp_api.robot
  61 | Resource | resources/libraries/robot/performance/performance_configuration.robot
  62 | Resource | resources/libraries/robot/performance/performance_limits.robot
  63 | Resource | resources/libraries/robot/performance/performance_utils.robot
  64 | Resource | resources/libraries/robot/shared/interfaces.robot
  65 | Resource | resources/libraries/robot/shared/container.robot
  66 | Resource | resources/libraries/robot/shared/memif.robot
  67 | Resource | resources/libraries/robot/shared/suite_teardown.robot
  68 | Resource | resources/libraries/robot/shared/suite_setup.robot
  69 | Resource | resources/libraries/robot/shared/test_teardown.robot
  70 | Resource | resources/libraries/robot/shared/test_setup.robot
  71 | Resource | resources/libraries/robot/shared/testing_path.robot
  72 | Resource | resources/libraries/robot/shared/traffic.robot
  73 | Resource | resources/libraries/robot/shared/vm.robot
  74
  75 *** Keywords ***
  76 | Configure crypto device on all DUTs
  77 | | [Documentation] | Verify if Crypto QAT device virtual functions are
  78 | | ... | initialized on all DUTs. If parameter force_init is set to True, then
  79 | | ... | try to initialize/disable.
  80 | |
  81 | | ... | *Arguments:*
  82 | | ... | - crypto_type - Crypto device type - HW_DH895xcc or HW_C3xxx.
  83 | | ... | Type: string, default value: HW_DH895xcc
  84 | | ... | - numvfs - Number of VFs to initialize, 0 - disable the VFs
  85 | | ... | Type: integer, default value: ${32}
  86 | | ... | - force_init - Force to initialize. Type: boolean
  87 | |
  88 | | ... | *Example:*
  89 | |
  90 | | ... | \| Configure crypto device on all DUTs \| HW_DH895xcc \| ${32} \|
  91 | |
  92 | | [Arguments] | ${crypto_type} | ${numvfs} | ${force_init}=${False}
  93 | |
  94 | | FOR | ${dut} | IN | @{duts}
  95 | | | Crypto Device Verify | ${nodes['${dut}']} | ${crypto_type}
  96 | | | ... | ${numvfs} | force_init=${force_init}
  97 | | END
  98
  99 | Configure kernel module on all DUTs
 100 | | [Documentation] | Verify if specific kernel module is loaded on all DUTs.
 101 | | ... | If parameter force_load is set to True, then try to load.
 102 | |
 103 | | ... | *Arguments:*
 104 | | ... | - module - Module to verify. Type: string
 105 | | ... | - force_load - Try to load module. Type: boolean
 106 | |
 107 | | ... | *Example:*
 108 | |
 109 | | ... | \| Configure kernel module on all DUTs \| ${True} \|
 110 | |
 111 | | [Arguments] | ${module} | ${force_load}=${False}
 112 | |
 113 | | Verify Kernel Module on All DUTs | ${nodes} | ${module}
 114 | | ... | force_load=${force_load}
 115
 116 | Create base startup configuration of VPP on all DUTs
 117 | | [Documentation] | Create base startup configuration of VPP to all DUTs.
 118 | |
 119 | | FOR | ${dut} | IN | @{duts}
 120 | | | Import Library | resources.libraries.python.VppConfigGenerator
 121 | | | ... | WITH NAME | ${dut}
 122 | | | Run keyword | ${dut}.Set Node |  ${nodes['${dut}']}
 123 | | | Run keyword | ${dut}.Add Unix Log
 124 | | | Run keyword | ${dut}.Add Unix CLI Listen
 125 | | | Run keyword | ${dut}.Add Unix Nodaemon
 126 | | | Run keyword | ${dut}.Add Unix Coredump
 127 | | | Run keyword | ${dut}.Add Socksvr | ${SOCKSVR_PATH}
 128 | | | Run keyword | ${dut}.Add Heapsize | 4G
 129 | | | Run keyword | ${dut}.Add Statseg size | 4G
 130 | | | Run keyword | ${dut}.Add Statseg Per Node Counters | on
 131 | | | Run keyword | ${dut}.Add Plugin | disable | default
 132 | | | Run keyword | ${dut}.Add Plugin | enable | @{plugins_to_enable}
 133 | | | Run keyword | ${dut}.Add IP6 Hash Buckets | 2000000
 134 | | | Run keyword | ${dut}.Add IP6 Heap Size | 4G
 135 | | | Run keyword | ${dut}.Add IP Heap Size | 4G
 136 | | END
 137
 138 | Add worker threads to all DUTs
 139 | | [Documentation] | Setup worker threads in vpp startup configuration on all
 140 | | ... | DUTs. Based on the SMT configuration of DUT if enabled keyword will
 141 | | ... | automatically map also the sibling logical cores.
 142 | | ... | Keyword will automatically set the appropriate test TAGs in format
 143 | | ... | mTnC, where m=logical_core_count and n=physical_core_count.
 144 | | ... | RXQ are computed automatically by dividing thread count with number 2
 145 | | ... | (TODO: Add division by actual number of interfaces). User can manually
 146 | | ... | override RX, RXD, TXD parameters if needed.
 147 | |
 148 | | ... | *Arguments:*
 149 | | ... | - phy_cores - Number of physical cores to use. Type: integer
 150 | | ... | - rx_queues - Number of RX queues. Type: integer
 151 | | ... | - rxd - Number of RX descriptors. Type: integer
 152 | | ... | - txd - Number of TX descriptors. Type: integer
 153 | |
 154 | | ... | *Example:*
 155 | |
 156 | | ... | \| Add worker threads to all DUTs \| ${1} \| ${1} \|
 157 | |
 158 | | [Arguments] | ${phy_cores} | ${rx_queues}=${None} | ${rxd}=${None}
 159 | | ... | ${txd}=${None}
 160 | |
 161 | | ${cpu_count_int} | Convert to Integer | ${phy_cores}
 162 | | ${thr_count_int} | Convert to Integer | ${phy_cores}
 163 | | ${rxd_count_int}= | Set variable | ${rxd}
 164 | | ${txd_count_int}= | Set variable | ${txd}
 165 | | FOR | ${dut} | IN | @{duts}
 166 | | | ${if1_status} | ${value}= | Run Keyword And Ignore Error
 167 | | | ... | Variable Should Exist | ${${dut}_if1}
 168 | | | @{if_list}= | Run Keyword If | '${if1_status}' == 'PASS'
 169 | | | ... | Create List | ${${dut}_if1}
 170 | | | ... | ELSE | Create List | ${${dut}_if1_1} | ${${dut}_if1_2}
 171 | | | ${if2_status} | ${value}= | Run Keyword And Ignore Error
 172 | | | ... | Variable Should Exist | ${${dut}_if2}
 173 | | | Run Keyword If | '${if2_status}' == 'PASS'
 174 | | | ... | Append To List | ${if_list} | ${${dut}_if2}
 175 | | | ... | ELSE
 176 | | | ... | Append To List | ${if_list} | ${${dut}_if2_1} | ${${dut}_if2_2}
 177 | | | ${numa}= | Get interfaces numa node | ${nodes['${dut}']} | @{if_list}
 178 | | | ${smt_used}= | Is SMT enabled | ${nodes['${dut}']['cpuinfo']}
 179 | | | ${skip_cnt}= | Set variable | ${CPU_CNT_SYSTEM}
 180 | | | ${cpu_main}= | Cpu list per node str | ${nodes['${dut}']} | ${numa}
 181 | | | ... | skip_cnt=${skip_cnt} | cpu_cnt=${CPU_CNT_MAIN}
 182 | | | ${skip_cnt}= | Evaluate | ${CPU_CNT_SYSTEM} + ${CPU_CNT_MAIN}
 183 | | | ${cpu_wt}= | Run keyword if | ${cpu_count_int} > 0 |
 184 | | | ... | Cpu list per node str | ${nodes['${dut}']} | ${numa}
 185 | | | ... | skip_cnt=${skip_cnt} | cpu_cnt=${cpu_count_int}
 186 | | | ... | smt_used=${smt_used}
 187 | | | ${thr_count_int}= | Run keyword if | ${smt_used}
 188 | | | ... | Evaluate | int(${cpu_count_int}*2)
 189 | | | ... | ELSE | Set variable | ${thr_count_int}
 190 | | | ${rxq_count_int}= | Run keyword if | ${rx_queues}
 191 | | | ... | Set variable | ${rx_queues}
 192 | | | ... | ELSE | Evaluate | int(${thr_count_int}/2)
 193 | | | ${rxq_count_int}= | Run keyword if | ${rxq_count_int} == 0
 194 | | | ... | Set variable | ${1}
 195 | | | ... | ELSE | Set variable | ${rxq_count_int}
 196 | | | Run keyword if | ${cpu_count_int} > 0
 197 | | | ... | ${dut}.Add CPU Main Core | ${cpu_main}
 198 | | | Run keyword if | ${cpu_count_int} > 0
 199 | | | ... | ${dut}.Add CPU Corelist Workers | ${cpu_wt}
 200 | | | Run keyword if | ${smt_used}
 201 | | | ... | Run keyword | ${dut}.Add Buffers Per Numa | ${215040} | ELSE
 202 | | | ... | Run keyword | ${dut}.Add Buffers Per Numa | ${107520}
 203 | | | Run keyword if | ${thr_count_int} > 1
 204 | | | ... | Set Tags | MTHREAD | ELSE | Set Tags | STHREAD
 205 | | | Set Tags | ${thr_count_int}T${cpu_count_int}C
 206 | | END
 207 | | Set Test Variable | ${smt_used}
 208 | | Set Test Variable | ${thr_count_int}
 209 | | Set Test Variable | ${cpu_count_int}
 210 | | Set Test Variable | ${rxq_count_int}
 211 | | Set Test Variable | ${rxd_count_int}
 212 | | Set Test Variable | ${txd_count_int}
 213
 214 | Add DPDK pci devices to all DUTs
 215 | | [Documentation]
 216 | | ... | Add PCI devices to VPP configuration file.
 217 | |
 218 | | FOR | ${dut} | IN | @{duts}
 219 | | | ${if1_status} | ${value}= | Run Keyword And Ignore Error
 220 | | | ... | Variable Should Exist | ${${dut}_if1}
 221 | | | ${if1_pci}= | Run Keyword If | '${if1_status}' == 'PASS'
 222 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if1}
 223 | | | ${if1_1_pci}= | Run Keyword Unless | '${if1_status}' == 'PASS'
 224 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if1_1}
 225 | | | ${if1_2_pci}= | Run Keyword Unless | '${if1_status}' == 'PASS'
 226 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if1_2}
 227 | | | ${if2_status} | ${value}= | Run Keyword And Ignore Error
 228 | | | ... | Variable Should Exist | ${${dut}_if2}
 229 | | | ${if2_pci}= | Run Keyword If | '${if2_status}' == 'PASS'
 230 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if2}
 231 | | | ${if2_1_pci}= | Run Keyword Unless | '${if2_status}' == 'PASS'
 232 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if2_1}
 233 | | | ${if2_2_pci}= | Run Keyword Unless | '${if2_status}' == 'PASS'
 234 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if2_2}
 235 | | | @{pci_devs}= | Run Keyword If | '${if1_status}' == 'PASS'
 236 | | | ... | Create List | ${if1_pci}
 237 | | | ... | ELSE
 238 | | | ... | Create List | ${if1_1_pci} | ${if1_2_pci}
 239 | | | Run Keyword If | '${if2_status}' == 'PASS'
 240 | | | ... | Append To List | ${pci_devs} | ${if2_pci}
 241 | | | ... | ELSE
 242 | | | ... | Append To List | ${pci_devs} | ${if2_1_pci} | ${if2_2_pci}
 243 | | | Run keyword | ${dut}.Add DPDK Dev | @{pci_devs}
 244 | | | Run Keyword If | '${if1_status}' == 'PASS'
 245 | | | ... | Set Test Variable | ${${dut}_if1_pci} | ${if1_pci}
 246 | | | Run Keyword Unless | '${if1_status}' == 'PASS'
 247 | | | ... | Set Test Variable | ${${dut}_if1_1_pci} | ${if1_1_pci}
 248 | | | Run Keyword Unless | '${if1_status}' == 'PASS'
 249 | | | ... | Set Test Variable | ${${dut}_if1_2_pci} | ${if1_2_pci}
 250 | | | Run Keyword If | '${if2_status}' == 'PASS'
 251 | | | ... | Set Test Variable | ${${dut}_if2_pci} | ${if2_pci}
 252 | | | Run Keyword Unless | '${if2_status}' == 'PASS'
 253 | | | ... | Set Test Variable | ${${dut}_if2_1_pci} | ${if2_1_pci}
 254 | | | Run Keyword Unless | '${if2_status}' == 'PASS'
 255 | | | ... | Set Test Variable | ${${dut}_if2_2_pci} | ${if2_2_pci}
 256 | | END
 257
 258 | Add DPDK no PCI to all DUTs
 259 | | [Documentation] | Add DPDK no-pci to VPP startup configuration to all DUTs.
 260 | |
 261 | | FOR | ${dut} | IN | @{duts}
 262 | | | Run keyword | ${dut}.Add DPDK no PCI
 263 | | END
 264
 265 | Add VLAN strip offload switch off between DUTs in 3-node single link topology
 266 | | [Documentation]
 267 | | ... | Add VLAN Strip Offload switch off on PCI devices between DUTs to VPP
 268 | | ... | configuration file.
 269 | |
 270 | | Run keyword | DUT1.Add DPDK Dev Parameter | ${dut1_if2_pci}
 271 | | ... | vlan-strip-offload | off
 272 | | Run keyword | DUT2.Add DPDK Dev Parameter | ${dut2_if1_pci}
 273 | | ... | vlan-strip-offload | off
 274
 275 | Add VLAN strip offload switch off between DUTs in 3-node double link topology
 276 | | [Documentation]
 277 | | ... | Add VLAN Strip Offload switch off on PCI devices between DUTs to VPP
 278 | | ... | configuration file
 279 | |
 280 | | Run keyword | DUT1.Add DPDK Dev Parameter | ${dut1_if2_1_pci}
 281 | | ... | vlan-strip-offload | off
 282 | | Run keyword | DUT1.Add DPDK Dev Parameter | ${dut1_if2_2_pci}
 283 | | ... | vlan-strip-offload | off
 284 | | Run keyword | DUT2.Add DPDK Dev Parameter | ${dut2_if1_1_pci}
 285 | | ... | vlan-strip-offload | off
 286 | | Run keyword | DUT2.Add DPDK Dev Parameter | ${dut2_if1_2_pci}
 287 | | ... | vlan-strip-offload | off
 288
 289 | Add NAT to all DUTs
 290 | | [Documentation] | Add NAT configuration to all DUTs.
 291 | |
 292 | | FOR | ${dut} | IN | @{duts}
 293 | | | Run keyword | ${dut}.Add NAT
 294 | | END
 295
 296 | Write startup configuration on all VPP DUTs
 297 | | [Documentation] | Write VPP startup configuration without restarting VPP.
 298 | |
 299 | | FOR | ${dut} | IN | @{duts}
 300 | | | Run keyword | ${dut}.Write Config
 301 | | END
 302
 303 | Apply startup configuration on all VPP DUTs
 304 | | [Documentation] | Write VPP startup configuration and restart VPP on all
 305 | | ... | DUTs.
 306 | |
 307 | | ... | *Arguments:*
 308 | | ... | - with_trace - Enable packet trace after VPP restart Type: boolean
 309 | |
 310 | | ... | *Example:*
 311 | |
 312 | | ... | \| Apply startup configuration on all VPP DUTs \| False \|
 313 | |
 314 | | [Arguments] | ${with_trace}=${False}
 315 | |
 316 | | FOR | ${dut} | IN | @{duts}
 317 | | | Run keyword | ${dut}.Apply Config
 318 | | | Add New Socket | ${nodes['${dut}']} | PAPI | ${dut} | ${SOCKSVR_PATH}
 319 | | | Add New Socket | ${nodes['${dut}']} | STATS | ${dut} | ${SOCKSTAT_PATH}
 320 | | END
 321 | | Save VPP PIDs
 322 | | Enable Coredump Limit VPP on All DUTs | ${nodes}
 323 | | Update All Interface Data On All Nodes | ${nodes} | skip_tg=${True}
 324 | | Run keyword If | ${with_trace} | VPP Enable Traces On All Duts | ${nodes}
 325
 326 | Save VPP PIDs
 327 | | [Documentation] | Get PIDs of VPP processes from all DUTs in topology and\
 328 | | ... | set it as a test variable. The PIDs are stored as dictionary items\
 329 | | ... | where the key is the host and the value is the PID.
 330 | |
 331 | | ${setup_vpp_pids}= | Get VPP PIDs | ${nodes}
 332 | | ${keys}= | Get Dictionary Keys | ${setup_vpp_pids}
 333 | | ${duts}= | Get Matches | ${nodes} | DUT*
 334 | | FOR | ${key} | IN | @{keys}
 335 | | | ${pid}= | Get From Dictionary | ${setup_vpp_pids} | ${key}
 336 | | | Run Keyword If | $pid is None | FAIL | No VPP PID found on node ${key}
 337 | | END
 338 | | Set Test Variable | ${setup_vpp_pids}
 339
 340 | Verify VPP PID in Teardown
 341 | | [Documentation] | Check if the VPP PIDs on all DUTs are the same at the end\
 342 | | ... | of test as they were at the begining. If they are not, only a message\
 343 | | ... | is printed on console and to log. The test will not fail.
 344 | |
 345 | | ${teardown_vpp_pids}= | Get VPP PIDs | ${nodes}
 346 | | ${err_msg}= | Catenate | ${SUITE NAME} - ${TEST NAME}
 347 | | ... | \nThe VPP PIDs are not equal!\nTest Setup VPP PIDs:
 348 | | ... | ${setup_vpp_pids}\nTest Teardown VPP PIDs: ${teardown_vpp_pids}
 349 | | ${rc} | ${msg}= | Run keyword and ignore error
 350 | | ... | Dictionaries Should Be Equal
 351 | | ... | ${setup_vpp_pids} | ${teardown_vpp_pids}
 352 | | Run Keyword And Return If | '${rc}'=='FAIL' | Log | ${err_msg}
 353 | | ... | console=yes | level=WARN