resources/libraries/robot/shared/default.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Variables | resources/libraries/python/topology.py
  16 | Variables | resources/libraries/python/PapiHistory.py
  17 | Variables | resources/libraries/python/Constants.py
  18 |
  19 | Library | Collections
  20 | Library | OperatingSystem
  21 | Library | String
  22 |
  23 | Library | resources.libraries.python.Classify
  24 | Library | resources.libraries.python.CpuUtils
  25 | Library | resources.libraries.python.CoreDumpUtil
  26 | Library | resources.libraries.python.Cop
  27 | Library | resources.libraries.python.DUTSetup
  28 | Library | resources.libraries.python.L2Util
  29 | Library | resources.libraries.python.InterfaceUtil
  30 | Library | resources.libraries.python.IPUtil
  31 | Library | resources.libraries.python.IPv6Util
  32 | Library | resources.libraries.python.NodePath
  33 | Library | resources.libraries.python.Namespaces
  34 | Library | resources.libraries.python.PapiHistory
  35 | Library | resources.libraries.python.SchedUtils
  36 | Library | resources.libraries.python.Tap
  37 | Library | resources.libraries.python.TestConfig
  38 | Library | resources.libraries.python.TGSetup
  39 | Library | resources.libraries.python.topology.Topology
  40 | Library | resources.libraries.python.Trace
  41 | Library | resources.libraries.python.VppCounters
  42 | Library | resources.libraries.python.VPPUtil
  43 |
  44 | Resource | resources/libraries/robot/lb/load_balancer.robot
  45 | Resource | resources/libraries/robot/crypto/ipsec.robot
  46 | Resource | resources/libraries/robot/features/acl.robot
  47 | Resource | resources/libraries/robot/features/gbp.robot
  48 | Resource | resources/libraries/robot/features/policer.robot
  49 | Resource | resources/libraries/robot/ip/ip4.robot
  50 | Resource | resources/libraries/robot/ip/ip6.robot
  51 | Resource | resources/libraries/robot/ip/nat.robot
  52 | Resource | resources/libraries/robot/l2/l2_bridge_domain.robot
  53 | Resource | resources/libraries/robot/l2/l2_patch.robot
  54 | Resource | resources/libraries/robot/l2/l2_traffic.robot
  55 | Resource | resources/libraries/robot/l2/l2_xconnect.robot
  56 | Resource | resources/libraries/robot/l2/tagging.robot
  57 | Resource | resources/libraries/robot/overlay/srv6.robot
  58 | Resource | resources/libraries/robot/overlay/lisp.robot
  59 | Resource | resources/libraries/robot/overlay/lispgpe.robot
  60 | Resource | resources/libraries/robot/overlay/lisp_api.robot
  61 | Resource | resources/libraries/robot/performance/performance_configuration.robot
  62 | Resource | resources/libraries/robot/performance/performance_limits.robot
  63 | Resource | resources/libraries/robot/performance/performance_utils.robot
  64 | Resource | resources/libraries/robot/shared/interfaces.robot
  65 | Resource | resources/libraries/robot/shared/container.robot
  66 | Resource | resources/libraries/robot/shared/memif.robot
  67 | Resource | resources/libraries/robot/shared/suite_teardown.robot
  68 | Resource | resources/libraries/robot/shared/suite_setup.robot
  69 | Resource | resources/libraries/robot/shared/test_teardown.robot
  70 | Resource | resources/libraries/robot/shared/test_setup.robot
  71 | Resource | resources/libraries/robot/shared/testing_path.robot
  72 | Resource | resources/libraries/robot/shared/traffic.robot
  73 | Resource | resources/libraries/robot/shared/vm.robot
  74
  75 *** Keywords ***
  76 | Configure crypto device on all DUTs
  77 | | [Documentation] | Verify if Crypto QAT device virtual functions are
  78 | | ... | initialized on all DUTs. If parameter force_init is set to True, then
  79 | | ... | try to initialize/disable.
  80 | |
  81 | | ... | *Arguments:*
  82 | | ... | - crypto_type - Crypto device type - HW_DH895xcc or HW_C3xxx.
  83 | | ... | Type: string, default value: HW_DH895xcc
  84 | | ... | - numvfs - Number of VFs to initialize, 0 - disable the VFs
  85 | | ... | Type: integer, default value: ${32}
  86 | | ... | - force_init - Force to initialize. Type: boolean
  87 | |
  88 | | ... | *Example:*
  89 | |
  90 | | ... | \| Configure crypto device on all DUTs \| HW_DH895xcc \| ${32} \|
  91 | |
  92 | | [Arguments] | ${crypto_type} | ${numvfs} | ${force_init}=${False}
  93 | |
  94 | | FOR | ${dut} | IN | @{duts}
  95 | | | Crypto Device Verify | ${nodes['${dut}']} | ${crypto_type}
  96 | | | ... | ${numvfs} | force_init=${force_init}
  97 | | END
  98
  99 | Configure kernel module on all DUTs
 100 | | [Documentation] | Verify if specific kernel module is loaded on all DUTs.
 101 | | ... | If parameter force_load is set to True, then try to load.
 102 | |
 103 | | ... | *Arguments:*
 104 | | ... | - module - Module to verify. Type: string
 105 | | ... | - force_load - Try to load module. Type: boolean
 106 | |
 107 | | ... | *Example:*
 108 | |
 109 | | ... | \| Configure kernel module on all DUTs \| ${True} \|
 110 | |
 111 | | [Arguments] | ${module} | ${force_load}=${False}
 112 | |
 113 | | Verify Kernel Module on All DUTs | ${nodes} | ${module}
 114 | | ... | force_load=${force_load}
 115
 116 | Get Keyname for DUT
 117 | | [Documentation]
 118 | | ... | Get the Keyname for the DUT in the keyname list.
 119 | | ... | Returns lowercase keyname value.
 120 | |
 121 | | ... | *Arguments:*
 122 | | ... | - dutx - DUT to find keyname. Type: dict
 123 | | ... | - dut_keys - DUT Keynames to search. Type: list
 124 | |
 125 | | ... | *Example:*
 126 | |
 127 | | ... | \| Get Keyname for DUT \| ${dutx} \| ${duts} \|
 128 | |
 129 | | [Arguments] | ${dutx} | ${dut_keys}
 130 | |
 131 | | FOR | ${key} | IN | @{dut_keys}
 132 | | | ${found_key} | ${value}= | Run Keyword and Ignore Error
 133 | | | ... | Dictionaries Should Be Equal | ${nodes['${key}']} | ${dutx}
 134 | | | Run Keyword If | '${found_key}' == 'PASS' | EXIT FOR LOOP
 135 | | END
 136 | | Run Keyword If | '${found_key}' != 'PASS'
 137 | | ... | Fail | Keyname for ${dutx} not found
 138 | | ${keyname}= | Convert To Lowercase | ${key}
 139 | | Return From Keyword | ${keyname}
 140
 141 | Create base startup configuration of VPP on all DUTs
 142 | | [Documentation] | Create base startup configuration of VPP to all DUTs.
 143 | |
 144 | | FOR | ${dut} | IN | @{duts}
 145 | | | Import Library | resources.libraries.python.VppConfigGenerator
 146 | | | ... | WITH NAME | ${dut}
 147 | | | Run keyword | ${dut}.Set Node |  ${nodes['${dut}']} | node_key=${dut}
 148 | | | Run keyword | ${dut}.Add Unix Log
 149 | | | Run keyword | ${dut}.Add Unix CLI Listen
 150 | | | Run keyword | ${dut}.Add Unix Nodaemon
 151 | | | Run keyword | ${dut}.Add Unix Coredump
 152 | | | Run keyword | ${dut}.Add Socksvr | ${SOCKSVR_PATH}
 153 | | | Run keyword | ${dut}.Add Heapsize | 4G
 154 | | | Run keyword | ${dut}.Add Statseg size | 4G
 155 | | | Run keyword | ${dut}.Add Statseg Per Node Counters | on
 156 | | | Run keyword | ${dut}.Add Plugin | disable | default
 157 | | | Run keyword | ${dut}.Add Plugin | enable | @{plugins_to_enable}
 158 | | | Run keyword | ${dut}.Add IP6 Hash Buckets | 2000000
 159 | | | Run keyword | ${dut}.Add IP6 Heap Size | 4G
 160 | | | Run keyword | ${dut}.Add IP Heap Size | 4G
 161 | | END
 162
 163 | Add worker threads to all DUTs
 164 | | [Documentation] | Setup worker threads in vpp startup configuration on all
 165 | | ... | DUTs. Based on the SMT configuration of DUT if enabled keyword will
 166 | | ... | automatically map also the sibling logical cores.
 167 | | ... | Keyword will automatically set the appropriate test TAGs in format
 168 | | ... | mTnC, where m=logical_core_count and n=physical_core_count.
 169 | | ... | RXQ are computed automatically by dividing thread count with number 2
 170 | | ... | (TODO: Add division by actual number of interfaces). User can manually
 171 | | ... | override RX, RXD, TXD parameters if needed.
 172 | |
 173 | | ... | *Arguments:*
 174 | | ... | - phy_cores - Number of physical cores to use. Type: integer
 175 | | ... | - rx_queues - Number of RX queues. Type: integer
 176 | | ... | - rxd - Number of RX descriptors. Type: integer
 177 | | ... | - txd - Number of TX descriptors. Type: integer
 178 | |
 179 | | ... | *Example:*
 180 | |
 181 | | ... | \| Add worker threads to all DUTs \| ${1} \| ${1} \|
 182 | |
 183 | | [Arguments] | ${phy_cores} | ${rx_queues}=${None} | ${rxd}=${None}
 184 | | ... | ${txd}=${None}
 185 | |
 186 | | ${cpu_count_int} | Convert to Integer | ${phy_cores}
 187 | | ${thr_count_int} | Convert to Integer | ${phy_cores}
 188 | | ${rxd_count_int}= | Set variable | ${rxd}
 189 | | ${txd_count_int}= | Set variable | ${txd}
 190 | | FOR | ${dut} | IN | @{duts}
 191 | | | ${if1_status} | ${value}= | Run Keyword And Ignore Error
 192 | | | ... | Variable Should Exist | ${${dut}_if1}
 193 | | | @{if_list}= | Run Keyword If | '${if1_status}' == 'PASS'
 194 | | | ... | Create List | ${${dut}_if1}
 195 | | | ... | ELSE | Create List | ${${dut}_if1_1} | ${${dut}_if1_2}
 196 | | | ${if2_status} | ${value}= | Run Keyword And Ignore Error
 197 | | | ... | Variable Should Exist | ${${dut}_if2}
 198 | | | Run Keyword If | '${if2_status}' == 'PASS'
 199 | | | ... | Append To List | ${if_list} | ${${dut}_if2}
 200 | | | ... | ELSE
 201 | | | ... | Append To List | ${if_list} | ${${dut}_if2_1} | ${${dut}_if2_2}
 202 | | | ${numa}= | Get interfaces numa node | ${nodes['${dut}']} | @{if_list}
 203 | | | ${smt_used}= | Is SMT enabled | ${nodes['${dut}']['cpuinfo']}
 204 | | | ${skip_cnt}= | Set variable | ${CPU_CNT_SYSTEM}
 205 | | | ${cpu_main}= | Cpu list per node str | ${nodes['${dut}']} | ${numa}
 206 | | | ... | skip_cnt=${skip_cnt} | cpu_cnt=${CPU_CNT_MAIN}
 207 | | | ${skip_cnt}= | Evaluate | ${CPU_CNT_SYSTEM} + ${CPU_CNT_MAIN}
 208 | | | ${cpu_wt}= | Run keyword if | ${cpu_count_int} > 0 |
 209 | | | ... | Cpu list per node str | ${nodes['${dut}']} | ${numa}
 210 | | | ... | skip_cnt=${skip_cnt} | cpu_cnt=${cpu_count_int}
 211 | | | ... | smt_used=${smt_used}
 212 | | | ${thr_count_int}= | Run keyword if | ${smt_used}
 213 | | | ... | Evaluate | int(${cpu_count_int}*2)
 214 | | | ... | ELSE | Set variable | ${thr_count_int}
 215 | | | ${rxq_count_int}= | Run keyword if | ${rx_queues}
 216 | | | ... | Set variable | ${rx_queues}
 217 | | | ... | ELSE | Evaluate | int(${thr_count_int}/2)
 218 | | | ${rxq_count_int}= | Run keyword if | ${rxq_count_int} == 0
 219 | | | ... | Set variable | ${1}
 220 | | | ... | ELSE | Set variable | ${rxq_count_int}
 221 | | | Run Keyword | ${dut}.Add CPU Main Core | ${cpu_main}
 222 | | | Run keyword if | ${cpu_count_int} > 0
 223 | | | ... | ${dut}.Add CPU Corelist Workers | ${cpu_wt}
 224 | | | Run keyword if | ${smt_used}
 225 | | | ... | Run keyword | ${dut}.Add Buffers Per Numa | ${215040} | ELSE
 226 | | | ... | Run keyword | ${dut}.Add Buffers Per Numa | ${107520}
 227 | | | ${ipsec} | Get Match Count | ${TEST TAGS} | IPSEC
 228 | | | ... | case_insensitive=True
 229 | | | Run keyword if | ${ipsec} and ${jumbo}
 230 | | | ... | ${dut}.Add Buffers Default Data Size | 9200
 231 | | | Run keyword if | ${thr_count_int} > 1
 232 | | | ... | Set Tags | MTHREAD | ELSE | Set Tags | STHREAD
 233 | | | Set Tags | ${thr_count_int}T${cpu_count_int}C
 234 | | END
 235 | | Set Test Variable | ${smt_used}
 236 | | Set Test Variable | ${thr_count_int}
 237 | | Set Test Variable | ${cpu_count_int}
 238 | | Set Test Variable | ${rxq_count_int}
 239 | | Set Test Variable | ${rxd_count_int}
 240 | | Set Test Variable | ${txd_count_int}
 241
 242 | Add DPDK pci devices to all DUTs
 243 | | [Documentation]
 244 | | ... | Add PCI devices to VPP configuration file.
 245 | |
 246 | | FOR | ${dut} | IN | @{duts}
 247 | | | ${if1_status} | ${value}= | Run Keyword And Ignore Error
 248 | | | ... | Variable Should Exist | ${${dut}_if1}
 249 | | | ${if1_pci}= | Run Keyword If | '${if1_status}' == 'PASS'
 250 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if1}
 251 | | | ${if1_1_pci}= | Run Keyword Unless | '${if1_status}' == 'PASS'
 252 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if1_1}
 253 | | | ${if1_2_pci}= | Run Keyword Unless | '${if1_status}' == 'PASS'
 254 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if1_2}
 255 | | | ${if2_status} | ${value}= | Run Keyword And Ignore Error
 256 | | | ... | Variable Should Exist | ${${dut}_if2}
 257 | | | ${if2_pci}= | Run Keyword If | '${if2_status}' == 'PASS'
 258 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if2}
 259 | | | ${if2_1_pci}= | Run Keyword Unless | '${if2_status}' == 'PASS'
 260 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if2_1}
 261 | | | ${if2_2_pci}= | Run Keyword Unless | '${if2_status}' == 'PASS'
 262 | | | ... | Get Interface PCI Addr | ${nodes['${dut}']} | ${${dut}_if2_2}
 263 | | | @{pci_devs}= | Run Keyword If | '${if1_status}' == 'PASS'
 264 | | | ... | Create List | ${if1_pci}
 265 | | | ... | ELSE
 266 | | | ... | Create List | ${if1_1_pci} | ${if1_2_pci}
 267 | | | Run Keyword If | '${if2_status}' == 'PASS'
 268 | | | ... | Append To List | ${pci_devs} | ${if2_pci}
 269 | | | ... | ELSE
 270 | | | ... | Append To List | ${pci_devs} | ${if2_1_pci} | ${if2_2_pci}
 271 | | | Run keyword | ${dut}.Add DPDK Dev | @{pci_devs}
 272 | | | Run Keyword If | '${if1_status}' == 'PASS'
 273 | | | ... | Set Test Variable | ${${dut}_if1_pci} | ${if1_pci}
 274 | | | Run Keyword Unless | '${if1_status}' == 'PASS'
 275 | | | ... | Set Test Variable | ${${dut}_if1_1_pci} | ${if1_1_pci}
 276 | | | Run Keyword Unless | '${if1_status}' == 'PASS'
 277 | | | ... | Set Test Variable | ${${dut}_if1_2_pci} | ${if1_2_pci}
 278 | | | Run Keyword If | '${if2_status}' == 'PASS'
 279 | | | ... | Set Test Variable | ${${dut}_if2_pci} | ${if2_pci}
 280 | | | Run Keyword Unless | '${if2_status}' == 'PASS'
 281 | | | ... | Set Test Variable | ${${dut}_if2_1_pci} | ${if2_1_pci}
 282 | | | Run Keyword Unless | '${if2_status}' == 'PASS'
 283 | | | ... | Set Test Variable | ${${dut}_if2_2_pci} | ${if2_2_pci}
 284 | | END
 285
 286 | Add DPDK no PCI to all DUTs
 287 | | [Documentation] | Add DPDK no-pci to VPP startup configuration to all DUTs.
 288 | |
 289 | | FOR | ${dut} | IN | @{duts}
 290 | | | Run keyword | ${dut}.Add DPDK no PCI
 291 | | END
 292
 293 | Add VLAN strip offload switch off between DUTs in 3-node single link topology
 294 | | [Documentation]
 295 | | ... | Add VLAN Strip Offload switch off on PCI devices between DUTs to VPP
 296 | | ... | configuration file.
 297 | |
 298 | | Run keyword | DUT1.Add DPDK Dev Parameter | ${dut1_if2_pci}
 299 | | ... | vlan-strip-offload | off
 300 | | Run keyword | DUT2.Add DPDK Dev Parameter | ${dut2_if1_pci}
 301 | | ... | vlan-strip-offload | off
 302
 303 | Add VLAN strip offload switch off between DUTs in 3-node double link topology
 304 | | [Documentation]
 305 | | ... | Add VLAN Strip Offload switch off on PCI devices between DUTs to VPP
 306 | | ... | configuration file
 307 | |
 308 | | Run keyword | DUT1.Add DPDK Dev Parameter | ${dut1_if2_1_pci}
 309 | | ... | vlan-strip-offload | off
 310 | | Run keyword | DUT1.Add DPDK Dev Parameter | ${dut1_if2_2_pci}
 311 | | ... | vlan-strip-offload | off
 312 | | Run keyword | DUT2.Add DPDK Dev Parameter | ${dut2_if1_1_pci}
 313 | | ... | vlan-strip-offload | off
 314 | | Run keyword | DUT2.Add DPDK Dev Parameter | ${dut2_if1_2_pci}
 315 | | ... | vlan-strip-offload | off
 316
 317 | Add NAT to all DUTs
 318 | | [Documentation] | Add NAT configuration to all DUTs.
 319 | |
 320 | | FOR | ${dut} | IN | @{duts}
 321 | | | Run keyword | ${dut}.Add NAT
 322 | | END
 323
 324 | Write startup configuration on all VPP DUTs
 325 | | [Documentation] | Write VPP startup configuration without restarting VPP.
 326 | |
 327 | | FOR | ${dut} | IN | @{duts}
 328 | | | Run keyword | ${dut}.Write Config
 329 | | END
 330
 331 | Apply startup configuration on all VPP DUTs
 332 | | [Documentation] | Write VPP startup configuration and restart VPP on all
 333 | | ... | DUTs.
 334 | |
 335 | | ... | *Arguments:*
 336 | | ... | - with_trace - Enable packet trace after VPP restart Type: boolean
 337 | |
 338 | | ... | *Example:*
 339 | |
 340 | | ... | \| Apply startup configuration on all VPP DUTs \| False \|
 341 | |
 342 | | [Arguments] | ${with_trace}=${False}
 343 | |
 344 | | FOR | ${dut} | IN | @{duts}
 345 | | | Run keyword | ${dut}.Apply Config
 346 | | END
 347 | | Save VPP PIDs
 348 | | Enable Coredump Limit VPP on All DUTs | ${nodes}
 349 | | Update All Interface Data On All Nodes | ${nodes} | skip_tg=${True}
 350 | | Run keyword If | ${with_trace} | VPP Enable Traces On All Duts | ${nodes}
 351
 352 | Apply startup configuration on VPP DUT
 353 | | [Documentation] | Write VPP startup configuration and restart VPP DUT.
 354 | |
 355 | | ... | *Arguments:*
 356 | | ... | - dut - DUT on which to apply the configuration. Type: string
 357 | | ... | - with_trace - Enable packet trace after VPP restart Type: boolean
 358 | |
 359 | | [Arguments] | ${dut} | ${with_trace}=${False}
 360 | |
 361 | | Run keyword | ${dut}.Apply Config
 362 | | Save VPP PIDs on DUT | ${dut}
 363 | | Enable Coredump Limit VPP on DUT | ${nodes['${dut}']}
 364 | | ${dutnode}= | Copy Dictionary | ${nodes}
 365 | | Keep In Dictionary | ${dutnode} | ${dut}
 366 | | Update All Interface Data On All Nodes | ${dutnode} | skip_tg=${True}
 367 | | Run keyword If | ${with_trace} | VPP Enable Traces On Dut
 368 | | ... | ${nodes['${dut}']}
 369
 370 | Save VPP PIDs
 371 | | [Documentation] | Get PIDs of VPP processes from all DUTs in topology and\
 372 | | ... | set it as a test variable. The PIDs are stored as dictionary items\
 373 | | ... | where the key is the host and the value is the PID.
 374 | |
 375 | | ${setup_vpp_pids}= | Get VPP PIDs | ${nodes}
 376 | | ${keys}= | Get Dictionary Keys | ${setup_vpp_pids}
 377 | | ${duts}= | Get Matches | ${nodes} | DUT*
 378 | | FOR | ${key} | IN | @{keys}
 379 | | | ${pid}= | Get From Dictionary | ${setup_vpp_pids} | ${key}
 380 | | | Run Keyword If | $pid is None | FAIL | No VPP PID found on node ${key}
 381 | | END
 382 | | Set Test Variable | ${setup_vpp_pids}
 383
 384 | Save VPP PIDs on DUT
 385 | | [Documentation] | Get PID of VPP processes from DUT and\
 386 | | ... | set it as a test variable. The PID is stored as dictionary item\
 387 | | ... | where the key is the host and the value is the PID.
 388 | |
 389 | | [Arguments] | ${dut}
 390 | |
 391 | | ${vpp_pids}= | Get VPP PID | ${nodes['${dut}']}
 392 | | Run Keyword If | ${vpp_pids} is None | FAIL
 393 | | ... | No VPP PID found on node ${nodes['${dut}']['host']
 394 | | ${status} | ${message}= | Run Keyword And Ignore Error
 395 | | ... | Variable Should Exist | ${setup_vpp_pids}
 396 | | ${setup_vpp_pids}= | Run Keyword If | '${status}' == 'FAIL'
 397 | | ... | Create Dictionary | ${nodes['${dut}']['host']}=${vpp_pids}
 398 | | ... | ELSE | Set To Dictionary | ${setup_vpp_pids}
 399 | | ... | ${nodes['${dut}']['host']}=${vpp_pids}
 400 | | Set Test Variable | ${setup_vpp_pids}
 401
 402 | Verify VPP PID in Teardown
 403 | | [Documentation] | Check if the VPP PIDs on all DUTs are the same at the end\
 404 | | ... | of test as they were at the begining. If they are not, only a message\
 405 | | ... | is printed on console and to log. The test will not fail.
 406 | |
 407 | | ${teardown_vpp_pids}= | Get VPP PIDs | ${nodes}
 408 | | ${err_msg}= | Catenate | ${SUITE NAME} - ${TEST NAME}
 409 | | ... | \nThe VPP PIDs are not equal!\nTest Setup VPP PIDs:
 410 | | ... | ${setup_vpp_pids}\nTest Teardown VPP PIDs: ${teardown_vpp_pids}
 411 | | ${rc} | ${msg}= | Run keyword and ignore error
 412 | | ... | Dictionaries Should Be Equal
 413 | | ... | ${setup_vpp_pids} | ${teardown_vpp_pids}
 414 | | Run Keyword And Return If | '${rc}'=='FAIL' | Log | ${err_msg}
 415 | | ... | console=yes | level=WARN