resources/libraries/robot/shared/default.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Variables | resources/libraries/python/topology.py
  16 | Variables | resources/libraries/python/PapiHistory.py
  17 | Variables | resources/libraries/python/Constants.py
  18 |
  19 | Library | Collections
  20 | Library | OperatingSystem
  21 | Library | String
  22 |
  23 | Library | resources.libraries.python.Adl
  24 | Library | resources.libraries.python.Classify
  25 | Library | resources.libraries.python.CpuUtils
  26 | Library | resources.libraries.python.CoreDumpUtil
  27 | Library | resources.libraries.python.DUTSetup
  28 | Library | resources.libraries.python.L2Util
  29 | Library | resources.libraries.python.InterfaceUtil
  30 | Library | resources.libraries.python.IPUtil
  31 | Library | resources.libraries.python.IPv6Util
  32 | Library | resources.libraries.python.IrqUtil
  33 | Library | resources.libraries.python.NodePath
  34 | Library | resources.libraries.python.Namespaces
  35 | Library | resources.libraries.python.PapiHistory
  36 | Library | resources.libraries.python.SchedUtils
  37 | Library | resources.libraries.python.Tap
  38 | Library | resources.libraries.python.Tap.TapFeatureMask
  39 | Library | resources.libraries.python.TestConfig
  40 | Library | resources.libraries.python.TGSetup
  41 | Library | resources.libraries.python.topology.Topology
  42 | Library | resources.libraries.python.Trace
  43 | Library | resources.libraries.python.VhostUser.VirtioFeatureMask
  44 | Library | resources.libraries.python.VppCounters
  45 | Library | resources.libraries.python.VPPUtil
  46 |
  47 | Resource | resources/libraries/robot/lb/load_balancer.robot
  48 | Resource | resources/libraries/robot/crypto/ipsec.robot
  49 | Resource | resources/libraries/robot/features/acl.robot
  50 | Resource | resources/libraries/robot/features/policer.robot
  51 | Resource | resources/libraries/robot/ip/ip4.robot
  52 | Resource | resources/libraries/robot/ip/ip6.robot
  53 | Resource | resources/libraries/robot/ip/nat.robot
  54 | Resource | resources/libraries/robot/l2/l2_bridge_domain.robot
  55 | Resource | resources/libraries/robot/l2/l2_patch.robot
  56 | Resource | resources/libraries/robot/l2/l2_traffic.robot
  57 | Resource | resources/libraries/robot/l2/l2_xconnect.robot
  58 | Resource | resources/libraries/robot/l2/tagging.robot
  59 | Resource | resources/libraries/robot/overlay/srv6.robot
  60 | Resource | resources/libraries/robot/overlay/lisp.robot
  61 | Resource | resources/libraries/robot/overlay/lispgpe.robot
  62 | Resource | resources/libraries/robot/overlay/lisp_api.robot
  63 | Resource | resources/libraries/robot/performance/performance_utils.robot
  64 | Resource | resources/libraries/robot/shared/interfaces.robot
  65 | Resource | resources/libraries/robot/shared/container.robot
  66 | Resource | resources/libraries/robot/shared/memif.robot
  67 | Resource | resources/libraries/robot/shared/suite_teardown.robot
  68 | Resource | resources/libraries/robot/shared/suite_setup.robot
  69 | Resource | resources/libraries/robot/shared/test_teardown.robot
  70 | Resource | resources/libraries/robot/shared/test_setup.robot
  71 | Resource | resources/libraries/robot/shared/traffic.robot
  72 | Resource | resources/libraries/robot/shared/vm.robot
  73
  74 *** Variables ***
  75 | ${cpu_alloc_str}= | ${0}
  76
  77 *** Keywords ***
  78 | Call Resetter
  79 | | [Documentation]
  80 | | ... | Check for a presence of test variable \${resetter}.
  81 | | ... | If it exists (and not None), call the resetter (as a Python callable).
  82 | | ... | This is usually used to reset any state on DUT before next trial.
  83 | |
  84 | | ... | TODO: Move to a more specific library if needed.
  85 | |
  86 | | ... | *Example:*
  87 | |
  88 | | ... | \| Call Resetter \|
  89 | |
  90 | | ${resetter} = | Get Resetter
  91 | | # See http://robotframework.org/robotframework/3.1.2/libraries/BuiltIn.html
  92 | | # #Evaluating%20expressions for $variable (without braces) syntax.
  93 | | # Parens are there to perform the call.
  94 | | Run Keyword If | $resetter | Evaluate | $resetter()
  95
  96 | Configure crypto device on all DUTs
  97 | | [Documentation] | Verify if Crypto QAT device virtual functions are
  98 | | ... | initialized on all DUTs. If parameter force_init is set to True, then
  99 | | ... | try to initialize/disable.
 100 | |
 101 | | ... | *Arguments:*
 102 | | ... | - crypto_type - Crypto device type - HW_DH895xcc or HW_C3xxx; default
 103 | | ... | value: HW_DH895xcc. Type: string
 104 | | ... | - numvfs - Number of VFs to initialize, 0 - disable the VFs; default
 105 | | ... | value: ${32} Type: integer
 106 | | ... | - force_init - Force to initialize. Type: boolean
 107 | |
 108 | | ... | *Example:*
 109 | |
 110 | | ... | \| Configure crypto device on all DUTs \| HW_DH895xcc \| ${32} \|
 111 | |
 112 | | [Arguments] | ${crypto_type} | ${numvfs} | ${force_init}=${False}
 113 | |
 114 | | FOR | ${dut} | IN | @{duts}
 115 | | | Crypto Device Verify | ${nodes['${dut}']} | ${crypto_type}
 116 | | | ... | ${numvfs} | force_init=${force_init}
 117 | | END
 118
 119 | Configure kernel module on all DUTs
 120 | | [Documentation] | Verify if specific kernel module is loaded on all DUTs.
 121 | | ... | If parameter force_load is set to True, then try to load.
 122 | |
 123 | | ... | *Arguments:*
 124 | | ... | - module - Module to verify. Type: string
 125 | | ... | - force_load - Try to load module. Type: boolean
 126 | |
 127 | | ... | *Example:*
 128 | |
 129 | | ... | \| Configure kernel module on all DUTs \| ${True} \|
 130 | |
 131 | | [Arguments] | ${module} | ${force_load}=${False}
 132 | |
 133 | | Verify Kernel Module on All DUTs | ${nodes} | ${module}
 134 | | ... | force_load=${force_load}
 135
 136 | Get Keyname for DUT
 137 | | [Documentation]
 138 | | ... | Get the Keyname for the DUT in the keyname list.
 139 | | ... | Returns lowercase keyname value.
 140 | |
 141 | | ... | *Arguments:*
 142 | | ... | - dutx - DUT to find keyname. Type: dict
 143 | | ... | - dut_keys - DUT Keynames to search. Type: list
 144 | |
 145 | | ... | *Example:*
 146 | |
 147 | | ... | \| Get Keyname for DUT \| ${dutx} \| ${duts} \|
 148 | |
 149 | | [Arguments] | ${dutx} | ${dut_keys}
 150 | |
 151 | | FOR | ${key} | IN | @{dut_keys}
 152 | | | ${found_key} | ${value}= | Run Keyword And Ignore Error
 153 | | | ... | Dictionaries Should Be Equal | ${nodes['${key}']} | ${dutx}
 154 | | | Run Keyword If | '${found_key}' == 'PASS' | EXIT FOR LOOP
 155 | | END
 156 | | Run Keyword If | '${found_key}' != 'PASS'
 157 | | ... | Fail | Keyname for ${dutx} not found
 158 | | ${keyname}= | Convert To Lowercase | ${key}
 159 | | Return From Keyword | ${keyname}
 160
 161 | Create base startup configuration of VPP on all DUTs
 162 | | [Documentation] | Create base startup configuration of VPP to all DUTs.
 163 | |
 164 | | FOR | ${dut} | IN | @{duts}
 165 | | | Import Library | resources.libraries.python.VppConfigGenerator
 166 | | | ... | WITH NAME | ${dut}
 167 | | | Run Keyword | ${dut}.Set Node | ${nodes['${dut}']} | node_key=${dut}
 168 | | | Run Keyword | ${dut}.Add Unix Log
 169 | | | Run Keyword | ${dut}.Add Unix CLI Listen
 170 | | | Run Keyword | ${dut}.Add Unix Nodaemon
 171 | | | Run Keyword | ${dut}.Add Unix Coredump
 172 | | | Run Keyword | ${dut}.Add Socksvr | ${SOCKSVR_PATH}
 173 | | | Run Keyword | ${dut}.Add Main Heap Size | ${${heap_size_mult}*${2}}G
 174 | | | Run Keyword | ${dut}.Add Main Heap Page Size | 2M
 175 | | | Run Keyword | ${dut}.Add Statseg Size | 2G
 176 | | | Run Keyword | ${dut}.Add Statseg Page Size | 2M
 177 | | | Run Keyword | ${dut}.Add Statseg Per Node Counters | on
 178 | | | Run Keyword | ${dut}.Add Plugin | disable | default
 179 | | | Run Keyword | ${dut}.Add Plugin | enable | @{plugins_to_enable}
 180 | | | Run Keyword | ${dut}.Add IP6 Hash Buckets | 2000000
 181 | | | Run Keyword | ${dut}.Add IP6 Heap Size | 4G
 182 | | | Run Keyword | ${dut}.Add Graph Node Variant | ${GRAPH_NODE_VARIANT}
 183 | | END
 184
 185 | Add worker threads to all DUTs
 186 | | [Documentation] | Setup worker threads in vpp startup configuration on all
 187 | | ... | DUTs. Based on the SMT configuration of DUT if enabled keyword will
 188 | | ... | automatically map also the sibling logical cores.
 189 | | ... | Keyword will automatically set the appropriate test TAGs in format
 190 | | ... | mTnC, where m=logical_core_count and n=physical_core_count.
 191 | | ... | User can manually override RXQ, RXD, TXD parameters if needed.
 192 | |
 193 | | ... | *Arguments:*
 194 | | ... | - phy_cores - Number of physical cores to use. Type: integer
 195 | | ... | - rx_queues - Number of RX queues. Type: integer
 196 | | ... | - rxd - Number of RX descriptors. Type: integer
 197 | | ... | - txd - Number of TX descriptors. Type: integer
 198 | |
 199 | | ... | *Example:*
 200 | |
 201 | | ... | \| Add worker threads to all DUTs \| ${1} \| ${1} \|
 202 | |
 203 | | [Arguments] | ${phy_cores} | ${rx_queues}=${None} | ${rxd}=${None}
 204 | | ... | ${txd}=${None}
 205 | |
 206 | | FOR | ${dut} | IN | @{duts}
 207 | | | &{compute_resource_info}= | Get Affinity Vswitch
 208 | | | ... | ${nodes} | ${dut} | ${phy_cores} | rx_queues=${rx_queues}
 209 | | | ... | rxd=${rxd} | txd=${txd}
 210 | | | Set Test Variable | &{compute_resource_info}
 211 | | | Create compute resources variables
 212 | | | Run Keyword | ${dut}.Add CPU Main Core | ${cpu_main}
 213 | | | Run Keyword If | ${cpu_count_int} > 0
 214 | | | ... | ${dut}.Add CPU Corelist Workers | ${cpu_wt}
 215 | | | Run Keyword | ${dut}.Add Buffers Per Numa | ${buffers_numa}
 216 | | END
 217
 218 | Create compute resources variables
 219 | | [Documentation]
 220 | | ... | Create compute resources variables
 221 | |
 222 | | ... | _NOTE:_ This KW sets various suite variables based on computed
 223 | | ... | resources.
 224 | |
 225 | | ${variables}= | Get Dictionary Keys | ${compute_resource_info}
 226 | | FOR | ${variable} | IN | @{variables}
 227 | | | ${value}= | Get From Dictionary | ${compute_resource_info} | ${variable}
 228 | | | Set Test Variable | ${${variable}} | ${value}
 229 | | END
 230 | | Run Keyword If | ${dp_count_int} > 1
 231 | | ... | Set Tags | MTHREAD | ELSE | Set Tags | STHREAD
 232 | | Set Tags | ${dp_count_int}T${cpu_count_int}C
 233
 234 | Add DPDK VLAN strip offload switch off between DUTs
 235 | | [Documentation]
 236 | | ... | Add VLAN Strip Offload switch off on PCI devices between DUTs to VPP
 237 | | ... | configuration file.
 238 | |
 239 | | FOR | ${pf} | IN RANGE | 1 | ${nic_pfs} + 1
 240 | | | ${_even}= | Evaluate | ${pf} % 2
 241 | | | Run Keyword Unless | ${even}
 242 | | | ... | DUT1.Add DPDK Dev Parameter | ${DUT1_${int}${pf}_pci}[0]
 243 | | | ... | vlan-strip-offload | off
 244 | | END
 245 | | FOR | ${pf} | IN RANGE | 1 | ${nic_pfs} + 1
 246 | | | ${_even}= | Evaluate | ${pf} % 2
 247 | | | Run Keyword If | ${even}
 248 | | | ... | DUT2.Add DPDK Dev Parameter | ${DUT2_${int}${pf}_pci}[0]
 249 | | | ... | vlan-strip-offload | off
 250 | | END
 251
 252 | Add NAT to all DUTs
 253 | | [Documentation] | Add NAT configuration to all DUTs.
 254 | |
 255 | | ... | *Arguments:*
 256 | | ... | - nat_mode - NAT mode; default value: deterministic. Type: string
 257 | |
 258 | | ... | *Example:*
 259 | |
 260 | | ... | \| Add NAT to all DUTs \| nat_mode=endpoint-dependent \|
 261 | |
 262 | | [Arguments] | ${nat_mode}=deterministic
 263 | |
 264 | | FOR | ${dut} | IN | @{duts}
 265 | | | Run Keyword | ${dut}.Add NAT | value=${nat_mode}
 266 | | END
 267
 268 | Add NAT max translations per thread to all DUTs
 269 | | [Documentation] | Add NAT maximum number of translations per thread
 270 | | ... | configuration.
 271 | |
 272 | | ... | *Arguments:*
 273 | | ... | - max_translations_per_thread - NAT maximum number of translations per
 274 | | ... | thread. Type: string
 275 | |
 276 | | ... | *Example:*
 277 | |
 278 | | ... | \| Add NAT translation memory to all DUTs \
 279 | | ... | \| max_translations_per_thread=2048 \|
 280 | |
 281 | | [Arguments] | ${max_translations_per_thread}=1024
 282 | |
 283 | | FOR | ${dut} | IN | @{duts}
 284 | | | Run Keyword | ${dut}.Add NAT max translations per thread
 285 | | | ... | value=${max_translations_per_thread}
 286 | | END
 287
 288 | Write startup configuration on all VPP DUTs
 289 | | [Documentation] | Write VPP startup configuration without restarting VPP.
 290 | |
 291 | | FOR | ${dut} | IN | @{duts}
 292 | | | Run Keyword | ${dut}.Write Config
 293 | | END
 294
 295 | Apply startup configuration on all VPP DUTs
 296 | | [Documentation] | Write VPP startup configuration and restart VPP on all
 297 | | ... | DUTs.
 298 | |
 299 | | ... | *Arguments:*
 300 | | ... | - with_trace - Enable packet trace after VPP restart Type: boolean
 301 | |
 302 | | ... | *Example:*
 303 | |
 304 | | ... | \| Apply startup configuration on all VPP DUTs \| False \|
 305 | |
 306 | | [Arguments] | ${with_trace}=${False}
 307 | |
 308 | | FOR | ${dut} | IN | @{duts}
 309 | | | Run Keyword | ${dut}.Apply Config
 310 | | END
 311 | | Save VPP PIDs
 312 | | Enable Coredump Limit VPP on All DUTs | ${nodes}
 313 | | Update All Interface Data On All Nodes | ${nodes} | skip_tg=${True}
 314 | | Run Keyword If | ${with_trace} | VPP Enable Traces On All Duts | ${nodes}
 315
 316 | Apply startup configuration on VPP DUT
 317 | | [Documentation] | Write VPP startup configuration and restart VPP DUT.
 318 | |
 319 | | ... | *Arguments:*
 320 | | ... | - dut - DUT on which to apply the configuration. Type: string
 321 | | ... | - with_trace - Enable packet trace after VPP restart Type: boolean
 322 | |
 323 | | [Arguments] | ${dut} | ${with_trace}=${False}
 324 | |
 325 | | Run Keyword | ${dut}.Apply Config
 326 | | Save VPP PIDs on DUT | ${dut}
 327 | | Enable Coredump Limit VPP on DUT | ${nodes['${dut}']}
 328 | | ${dutnode}= | Copy Dictionary | ${nodes}
 329 | | Keep In Dictionary | ${dutnode} | ${dut}
 330 | | Update All Interface Data On All Nodes | ${dutnode} | skip_tg=${True}
 331 | | Run Keyword If | ${with_trace} | VPP Enable Traces On Dut
 332 | | ... | ${nodes['${dut}']}
 333
 334 | Save VPP PIDs
 335 | | [Documentation] | Get PIDs of VPP processes from all DUTs in topology and\
 336 | | ... | set it as a test variable. The PIDs are stored as dictionary items\
 337 | | ... | where the key is the host and the value is the PID.
 338 | |
 339 | | ${setup_vpp_pids}= | Get VPP PIDs | ${nodes}
 340 | | ${keys}= | Get Dictionary Keys | ${setup_vpp_pids}
 341 | | FOR | ${key} | IN | @{keys}
 342 | | | ${pid}= | Get From Dictionary | ${setup_vpp_pids} | ${key}
 343 | | | Run Keyword If | $pid is None | FAIL | No VPP PID found on node ${key}
 344 | | END
 345 | | Set Test Variable | ${setup_vpp_pids}
 346
 347 | Save VPP PIDs on DUT
 348 | | [Documentation] | Get PID of VPP processes from DUT and\
 349 | | ... | set it as a test variable. The PID is stored as dictionary item\
 350 | | ... | where the key is the host and the value is the PID.
 351 | |
 352 | | [Arguments] | ${dut}
 353 | |
 354 | | ${vpp_pids}= | Get VPP PID | ${nodes['${dut}']}
 355 | | Run Keyword If | ${vpp_pids} is None | FAIL
 356 | | ... | No VPP PID found on node ${nodes['${dut}']['host']
 357 | | ${status} | ${message}= | Run Keyword And Ignore Error
 358 | | ... | Variable Should Exist | ${setup_vpp_pids}
 359 | | ${setup_vpp_pids}= | Run Keyword If | '${status}' == 'FAIL'
 360 | | ... | Create Dictionary | ${nodes['${dut}']['host']}=${vpp_pids}
 361 | | ... | ELSE | Set To Dictionary | ${setup_vpp_pids}
 362 | | ... | ${nodes['${dut}']['host']}=${vpp_pids}
 363 | | Set Test Variable | ${setup_vpp_pids}
 364
 365 | Verify VPP PID in Teardown
 366 | | [Documentation] | Check if the VPP PIDs on all DUTs are the same at the end\
 367 | | ... | of test as they were at the begining. If they are not, only a message\
 368 | | ... | is printed on console and to log. The test will not fail.
 369 | |
 370 | | ${teardown_vpp_pids}= | Get VPP PIDs | ${nodes}
 371 | | ${err_msg}= | Catenate | ${SUITE NAME} - ${TEST NAME}
 372 | | ... | \nThe VPP PIDs are not equal!\nTest Setup VPP PIDs:
 373 | | ... | ${setup_vpp_pids}\nTest Teardown VPP PIDs: ${teardown_vpp_pids}
 374 | | ${rc} | ${msg}= | Run Keyword And Ignore Error
 375 | | ... | Dictionaries Should Be Equal
 376 | | ... | ${setup_vpp_pids} | ${teardown_vpp_pids}
 377 | | Run Keyword And Return If | '${rc}'=='FAIL' | Log | ${err_msg}
 378 | | ... | console=yes | level=WARN