resources/libraries/robot/shared/test_teardown.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 """Keywords used in test teardowns."""
  15
  16 *** Settings ***
  17 | Resource | resources/libraries/robot/shared/container.robot
  18 | Library | resources.libraries.python.PapiHistory
  19 | Library | resources.libraries.python.topology.Topology
  20 | Variables | resources/libraries/python/Constants.py
  21 |
  22 | Documentation | Test teardown keywords.
  23
  24 *** Keywords ***
  25 | Tear down test
  26 | | [Documentation]
  27 | | ... | Common test teardown for VPP tests.
  28 | |
  29 | | ... | *Arguments:*
  30 | | ... | - ${actions} - Additional teardown action. Type: list
  31 | |
  32 | | [Arguments] | @{actions}
  33 | |
  34 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
  35 | | Show PAPI History On All DUTs | ${nodes}
  36 | | Run Keyword If Test Failed
  37 | | ... | Show Log On All DUTs | ${nodes}
  38 | | Run Keyword If Test Failed
  39 | | ... | Get Core Files on All Nodes | ${nodes}
  40 | | Run Keyword If Test Failed
  41 | | ... | Verify VPP PID in Teardown
  42 | | Run Keyword If Test Failed
  43 | | ... | VPP Show Memory On All DUTs | ${nodes}
  44 | | FOR | ${action} | IN | @{actions}
  45 | | | Run Keyword | Additional Test Tear Down Action For ${action}
  46 | | END
  47 | | Clean Sockets On All Nodes | ${nodes}
  48
  49 | Tear down test raw
  50 | | [Documentation]
  51 | | ... | Common test teardown for raw tests.
  52 | |
  53 | | ... | *Arguments:*
  54 | | ... | - ${actions} - Additional teardown action. Type: list
  55 | |
  56 | | [Arguments] | @{actions}
  57 | |
  58 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
  59 | | FOR | ${action} | IN | @{actions}
  60 | | | Run Keyword | Additional Test Tear Down Action For ${action}
  61 | | END
  62 | | Clean Sockets On All Nodes | ${nodes}
  63
  64 # Additional Test Tear Down Actions in alphabetical order
  65 | Additional Test Tear Down Action For acl
  66 | | [Documentation]
  67 | | ... | Additional teardown for tests which uses ACL feature.
  68 | |
  69 | | Run Keyword If Test Failed
  70 | | ... | Vpp Log Plugin Acl Settings | ${dut1}
  71 | | Run Keyword If Test Failed
  72 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
  73
  74 | Additional Test Tear Down Action For classify
  75 | | [Documentation]
  76 | | ... | Additional teardown for tests which uses classify tables.
  77 | |
  78 | | Run Keyword If Test Failed
  79 | | ... | Show Classify Tables Verbose on all DUTs | ${nodes}
  80
  81 | Additional Test Tear Down Action For container
  82 | | [Documentation]
  83 | | ... | Additional teardown for tests which uses containers.
  84 | |
  85 | | FOR | ${container_group} | IN | @{container_groups}
  86 | | | Destroy all '${container_group}' containers
  87 | | END
  88
  89 | Additional Test Tear Down Action For det44
  90 | | [Documentation]
  91 | | ... | Additional teardown for tests which uses DET44 feature.
  92 | |
  93 | | FOR | ${dut} | IN | @{duts}
  94 | | | Run Keyword If Test Failed
  95 | | | ... | Show DET44 verbose | ${nodes['${dut}']}
  96 | | END
  97
  98 | Additional Test Tear Down Action For geneve4
  99 | | [Documentation]
 100 | | ... | Additional teardown for tests which uses GENEVE IPv4 tunnel.
 101 | |
 102 | | FOR | ${dut} | IN | @{duts}
 103 | | | Run Keyword If Test Failed
 104 | | | ... | Show Geneve Tunnel Data | ${nodes['${dut}']}
 105 | | END
 106
 107 | Additional Test Tear Down Action For ipsec_sa
 108 | | [Documentation]
 109 | | ... | Additional teardown for tests which uses IPSec security association.
 110 | |
 111 | | FOR | ${dut} | IN | @{duts}
 112 | | | Run Keyword If Test Failed
 113 | | | ... | Show Ipsec Security Association | ${nodes['${dut}']}
 114 | | END
 115
 116 | Additional Test Tear Down Action For linux_bridge
 117 | | [Documentation]
 118 | | ... | Additional teardown for tests which uses linux_bridge.
 119 | |
 120 | | FOR | ${dut} | IN | @{duts}
 121 | | | Linux Del Bridge | ${nodes['${dut}']} | ${bid_TAP}
 122 | | END
 123
 124 | Additional Test Tear Down Action For macipacl
 125 | | [Documentation]
 126 | | ... | Additional teardown for tests which uses MACIP ACL feature.
 127 | |
 128 | | Run Keyword If Test Failed
 129 | | ... | Vpp Log Macip Acl Settings | ${dut1}
 130 | | Run Keyword If Test Failed
 131 | | ... | Vpp Log Macip Acl Interface Assignment | ${dut1}
 132
 133 | Additional Test Tear Down Action For namespace
 134 | | [Documentation]
 135 | | ... | Additional teardown for tests which uses namespace.
 136 | |
 137 | | FOR | ${dut} | IN | @{duts}
 138 | | | Clean Up Namespaces | ${nodes['${dut}']}
 139 | | END
 140
 141 | Additional Test Tear Down Action For nat-ed
 142 | | [Documentation]
 143 | | ... | Additional teardown for tests which uses NAT feature.
 144 | |
 145 | | FOR | ${dut} | IN | @{duts}
 146 | | | Show NAT44 Config | ${nodes['${dut}']}
 147 | | | Show NAT44 Summary | ${nodes['${dut}']}
 148 | | | Show NAT Base Data | ${nodes['${dut}']}
 149 | | | Vpp Get Ip Table Summary | ${nodes['${dut}']}
 150 | | END
 151
 152 | Additional Test Tear Down Action For packet_trace
 153 | | [Documentation]
 154 | | ... | Additional teardown for tests which uses packet trace.
 155 | |
 156 | | Show Packet Trace on All DUTs | ${nodes}
 157
 158 | Additional Test Tear Down Action For performance
 159 | | [Documentation]
 160 | | ... | Additional teardown for tests which uses performance measurement.
 161 | | ... | Optionally, call \${resetter} (if defined) to reset DUT state.
 162 | |
 163 | | ... | TODO: Document what test variables are required or optional.
 164 | |
 165 | | Run Keyword If Test Passed | Return From Keyword
 166 | | ${use_latency} = | Get Use Latency
 167 | | ${rate_for_teardown} = | Get Rate For Teardown
 168 | | Call Resetter
 169 | | Set Test Variable | \${extended_debug} | ${True}
 170 | | Send traffic at specified rate
 171 | | ... | trial_duration=${1.0}
 172 | | ... | rate=${rate_for_teardown}
 173 | | ... | trial_multiplicity=${1}
 174 | | ... | use_latency=${use_latency}
 175 | | ... | duration_limit=${1.0}
 176
 177 | Additional Test Tear Down Action For srv6
 178 | | [Documentation]
 179 | | ... | Additional teardown for tests which uses SRv6.
 180 | |
 181 | | Run Keyword If Test Failed
 182 | | ... | Show SR Policies on all DUTs | ${nodes}
 183 | | Run Keyword If Test Failed
 184 | | ... | Show SR Steering Policies on all DUTs | ${nodes}
 185 | | Run Keyword If Test Failed
 186 | | ... | Show SR LocalSIDs on all DUTs | ${nodes}
 187
 188 | Additional Test Tear Down Action For vhost
 189 | | [Documentation]
 190 | | ... | Additional teardown for tests which uses vhost(s) and VM(s).
 191 | |
 192 | | Show VPP vhost on all DUTs | ${nodes}
 193 | | ${vnf_status} | ${value}= | Run Keyword And Ignore Error
 194 | | ... | Keyword Should Exist | vnf_manager.Kill All VMs
 195 | | Run Keyword If | '${vnf_status}' == 'PASS' | vnf_manager.Kill All VMs
 196
 197 | Additional Test Tear Down Action For vhost-pt
 198 | | [Documentation]
 199 | | ... | Additional teardown for tests which uses pci-passtrough and VM(s).
 200 | |
 201 | | ${vnf_status} | ${value}= | Run Keyword And Ignore Error
 202 | | ... | Keyword Should Exist | vnf_manager.Kill All VMs
 203 | | Run Keyword If | '${vnf_status}' == 'PASS' | vnf_manager.Kill All VMs