terraform-ci-infra/3n_aws_c5n/deploy/main.tf

   1 provider "aws" {
   2   region = var.region
   3 }
   4
   5 resource "aws_vpc" "CSITVPC" {
   6   cidr_block = var.vpc_cidr_mgmt
   7
   8   tags = {
   9     "Name"        = "${var.resources_name_prefix}_${var.testbed_name}-vpc"
  10     "Environment" = var.environment_name
  11   }
  12 }
  13
  14 resource "aws_security_group" "CSITSG" {
  15   name        = "${var.resources_name_prefix}_${var.testbed_name}-sg"
  16   description = "Allow inbound traffic"
  17   vpc_id      = aws_vpc.CSITVPC.id
  18   depends_on  = [aws_vpc.CSITVPC]
  19
  20   ingress {
  21     from_port   = 22
  22     to_port     = 22
  23     protocol    = "tcp"
  24     cidr_blocks = ["0.0.0.0/0"]
  25   }
  26
  27   ingress {
  28     from_port = 0
  29     to_port   = 0
  30     protocol  = -1
  31     self      = true
  32   }
  33
  34   egress {
  35     from_port   = 0
  36     to_port     = 0
  37     protocol    = "-1"
  38     cidr_blocks = ["0.0.0.0/0"]
  39   }
  40
  41   tags = {
  42     "Name"        = "${var.resources_name_prefix}_${var.testbed_name}-sg"
  43     "Environment" = var.environment_name
  44   }
  45 }
  46
  47 resource "aws_vpc_ipv4_cidr_block_association" "b" {
  48   vpc_id     = aws_vpc.CSITVPC.id
  49   cidr_block = var.vpc_cidr_b
  50   depends_on = [aws_vpc.CSITVPC]
  51 }
  52 resource "aws_vpc_ipv4_cidr_block_association" "c" {
  53   vpc_id     = aws_vpc.CSITVPC.id
  54   cidr_block = var.vpc_cidr_c
  55   depends_on = [aws_vpc.CSITVPC]
  56 }
  57 resource "aws_vpc_ipv4_cidr_block_association" "d" {
  58   vpc_id     = aws_vpc.CSITVPC.id
  59   cidr_block = var.vpc_cidr_d
  60   depends_on = [aws_vpc.CSITVPC]
  61 }
  62
  63 # Subnets
  64 resource "aws_subnet" "mgmt" {
  65   vpc_id            = aws_vpc.CSITVPC.id
  66   cidr_block        = var.vpc_cidr_mgmt
  67   availability_zone = var.avail_zone
  68   depends_on        = [aws_vpc.CSITVPC]
  69
  70   tags = {
  71     "Environment" = var.environment_name
  72   }
  73 }
  74 resource "aws_subnet" "b" {
  75   vpc_id            = aws_vpc.CSITVPC.id
  76   cidr_block        = var.vpc_cidr_b
  77   availability_zone = var.avail_zone
  78   depends_on        = [aws_vpc.CSITVPC, aws_vpc_ipv4_cidr_block_association.b]
  79
  80   tags = {
  81     "Environment" = var.environment_name
  82   }
  83 }
  84 resource "aws_subnet" "c" {
  85   vpc_id            = aws_vpc.CSITVPC.id
  86   cidr_block        = var.vpc_cidr_c
  87   availability_zone = var.avail_zone
  88   depends_on        = [aws_vpc.CSITVPC, aws_vpc_ipv4_cidr_block_association.c]
  89
  90   tags = {
  91     "Environment" = var.environment_name
  92   }
  93 }
  94 resource "aws_subnet" "d" {
  95   vpc_id            = aws_vpc.CSITVPC.id
  96   cidr_block        = var.vpc_cidr_d
  97   availability_zone = var.avail_zone
  98   depends_on        = [aws_vpc.CSITVPC, aws_vpc_ipv4_cidr_block_association.d]
  99
 100   tags = {
 101     "Environment" = var.environment_name
 102   }
 103 }
 104
 105 resource "aws_internet_gateway" "CSITGW" {
 106   vpc_id     = aws_vpc.CSITVPC.id
 107   depends_on = [aws_vpc.CSITVPC]
 108
 109   tags = {
 110     "Environment" = var.environment_name
 111   }
 112 }
 113
 114 # SSH keypair
 115 # Temporary key for provisioning only
 116 resource "tls_private_key" "CSITTLS" {
 117   algorithm = "RSA"
 118   rsa_bits  = 4096
 119 }
 120 resource "aws_key_pair" "CSITKP" {
 121   key_name   = "CSIT_3n_aws_c5n_${var.testbed_name}-key"
 122   public_key = tls_private_key.CSITTLS.public_key_openssh
 123 }
 124
 125 resource "aws_placement_group" "CSITPG" {
 126   name     = "${var.resources_name_prefix}_${var.testbed_name}-pg"
 127   strategy = "cluster"
 128 }
 129
 130 # NICs
 131 resource "aws_network_interface" "dut1_if1" {
 132   subnet_id         = aws_subnet.b.id
 133   source_dest_check = false
 134   private_ip        = var.dut1_if1_ip
 135   private_ips       = [var.dut1_if1_ip]
 136   security_groups   = [aws_security_group.CSITSG.id]
 137   depends_on        = [aws_vpc.CSITVPC, aws_subnet.b]
 138
 139   attachment {
 140     instance     = aws_instance.dut1.id
 141     device_index = 1
 142   }
 143
 144   tags = {
 145     "Environment" = var.environment_name
 146   }
 147 }
 148
 149 resource "aws_network_interface" "dut1_if2" {
 150   subnet_id         = aws_subnet.c.id
 151   source_dest_check = false
 152   private_ip        = var.dut1_if2_ip
 153   private_ips       = [var.dut1_if2_ip]
 154   security_groups   = [aws_security_group.CSITSG.id]
 155   depends_on        = [aws_vpc.CSITVPC]
 156
 157   attachment {
 158     instance     = aws_instance.dut1.id
 159     device_index = 2
 160   }
 161
 162   tags = {
 163     "Environment" = var.environment_name
 164   }
 165 }
 166
 167 resource "aws_network_interface" "dut2_if1" {
 168   subnet_id         = aws_subnet.c.id
 169   source_dest_check = false
 170   private_ip        = var.dut2_if1_ip
 171   private_ips       = [var.dut2_if1_ip]
 172   security_groups   = [aws_security_group.CSITSG.id]
 173   depends_on        = [aws_vpc.CSITVPC, aws_subnet.c]
 174
 175   attachment {
 176     instance     = aws_instance.dut2.id
 177     device_index = 1
 178   }
 179
 180   tags = {
 181     "Environment" = var.environment_name
 182   }
 183 }
 184
 185 resource "aws_network_interface" "dut2_if2" {
 186   subnet_id         = aws_subnet.d.id
 187   source_dest_check = false
 188   private_ip        = var.dut2_if2_ip
 189   private_ips       = [var.dut2_if2_ip]
 190   security_groups   = [aws_security_group.CSITSG.id]
 191   depends_on        = [aws_vpc.CSITVPC, aws_subnet.d]
 192
 193   attachment {
 194     instance     = aws_instance.dut2.id
 195     device_index = 2
 196   }
 197
 198   tags = {
 199     "Environment" = var.environment_name
 200   }
 201 }
 202
 203 resource "aws_network_interface" "tg_if1" {
 204   subnet_id         = aws_subnet.b.id
 205   source_dest_check = false
 206   private_ip        = var.tg_if1_ip
 207   private_ips       = [var.tg_if1_ip]
 208   security_groups   = [aws_security_group.CSITSG.id]
 209   depends_on        = [aws_vpc.CSITVPC, aws_subnet.b]
 210
 211   attachment {
 212     instance     = aws_instance.tg.id
 213     device_index = 1
 214   }
 215
 216   tags = {
 217     "Environment" = var.environment_name
 218   }
 219 }
 220
 221 resource "aws_network_interface" "tg_if2" {
 222   subnet_id         = aws_subnet.d.id
 223   source_dest_check = false
 224   private_ip        = var.tg_if2_ip
 225   private_ips       = [var.tg_if2_ip]
 226   security_groups   = [aws_security_group.CSITSG.id]
 227   depends_on        = [aws_vpc.CSITVPC, aws_subnet.d]
 228
 229   attachment {
 230     instance     = aws_instance.tg.id
 231     device_index = 2
 232   }
 233
 234   tags = {
 235     "Environment" = var.environment_name
 236   }
 237 }
 238
 239 data "aws_network_interface" "dut1_if1" {
 240   id = aws_network_interface.dut1_if1.id
 241 }
 242
 243 data "aws_network_interface" "dut1_if2" {
 244   id = aws_network_interface.dut1_if2.id
 245 }
 246
 247 data "aws_network_interface" "dut2_if1" {
 248   id = aws_network_interface.dut2_if1.id
 249 }
 250
 251 data "aws_network_interface" "dut2_if2" {
 252   id = aws_network_interface.dut2_if2.id
 253 }
 254
 255 data "aws_network_interface" "tg_if1" {
 256   id = aws_network_interface.tg_if1.id
 257 }
 258
 259 data "aws_network_interface" "tg_if2" {
 260   id = aws_network_interface.tg_if2.id
 261 }
 262
 263 # Instances
 264 resource "aws_instance" "tg" {
 265   depends_on                  = [aws_vpc.CSITVPC, aws_placement_group.CSITPG]
 266   ami                         = var.ami_image
 267   availability_zone           = var.avail_zone
 268   instance_type               = var.instance_type
 269   key_name                    = aws_key_pair.CSITKP.key_name
 270   associate_public_ip_address = true
 271   subnet_id                   = aws_subnet.mgmt.id
 272   private_ip                  = var.tg_mgmt_ip
 273   vpc_security_group_ids      = [aws_security_group.CSITSG.id]
 274   placement_group             = aws_placement_group.CSITPG.id
 275   source_dest_check           = false
 276   # host_id                   = "1"
 277
 278   root_block_device {
 279     volume_size = 50
 280   }
 281
 282   tags = {
 283     "Name"        = "${var.resources_name_prefix}_${var.testbed_name}-tg"
 284     "Environment" = var.environment_name
 285   }
 286 }
 287
 288 resource "aws_instance" "dut1" {
 289   depends_on                  = [aws_vpc.CSITVPC, aws_placement_group.CSITPG]
 290   ami                         = var.ami_image
 291   availability_zone           = var.avail_zone
 292   instance_type               = var.instance_type
 293   key_name                    = aws_key_pair.CSITKP.key_name
 294   associate_public_ip_address = true
 295   subnet_id                   = aws_subnet.mgmt.id
 296   private_ip                  = var.dut1_mgmt_ip
 297   vpc_security_group_ids      = [aws_security_group.CSITSG.id]
 298   placement_group             = aws_placement_group.CSITPG.id
 299   source_dest_check           = false
 300   # host_id                   = "2"
 301
 302   root_block_device {
 303     volume_size = 50
 304   }
 305
 306   tags = {
 307     "Name"        = "${var.resources_name_prefix}_${var.testbed_name}-dut1"
 308     "Environment" = var.environment_name
 309   }
 310 }
 311
 312 resource "aws_instance" "dut2" {
 313   depends_on                  = [aws_vpc.CSITVPC, aws_placement_group.CSITPG]
 314   ami                         = var.ami_image
 315   availability_zone           = var.avail_zone
 316   instance_type               = var.instance_type
 317   key_name                    = aws_key_pair.CSITKP.key_name
 318   associate_public_ip_address = true
 319   subnet_id                   = aws_subnet.mgmt.id
 320   private_ip                  = var.dut2_mgmt_ip
 321   vpc_security_group_ids      = [aws_security_group.CSITSG.id]
 322   placement_group             = aws_placement_group.CSITPG.id
 323   source_dest_check           = false
 324   # host_id                   = "3"
 325
 326   root_block_device {
 327     volume_size = 50
 328   }
 329
 330   tags = {
 331     "Name"        = "${var.resources_name_prefix}_${var.testbed_name}-dut2"
 332     "Environment" = var.environment_name
 333   }
 334 }
 335
 336 # Routes
 337 resource "aws_route" "CSIT-igw" {
 338   route_table_id         = aws_vpc.CSITVPC.main_route_table_id
 339   gateway_id             = aws_internet_gateway.CSITGW.id
 340   destination_cidr_block = "0.0.0.0/0"
 341   depends_on             = [aws_vpc.CSITVPC, aws_internet_gateway.CSITGW]
 342 }
 343 resource "aws_route" "dummy-trex-port-0" {
 344   route_table_id         = aws_vpc.CSITVPC.main_route_table_id
 345   network_interface_id   = aws_instance.tg.primary_network_interface_id
 346   destination_cidr_block = var.trex_dummy_cidr_port_0
 347   depends_on             = [aws_vpc.CSITVPC, aws_instance.dut1]
 348 }
 349 resource "aws_route" "dummy-trex-port-1" {
 350   route_table_id         = aws_vpc.CSITVPC.main_route_table_id
 351   network_interface_id   = aws_instance.tg.primary_network_interface_id
 352   destination_cidr_block = var.trex_dummy_cidr_port_1
 353   depends_on             = [aws_vpc.CSITVPC, aws_instance.dut1]
 354 }
 355
 356 # Deployment/Ansible
 357 resource "null_resource" "deploy_tg" {
 358   depends_on = [
 359     aws_instance.tg,
 360     aws_network_interface.tg_if1,
 361     aws_network_interface.tg_if2
 362   ]
 363
 364   connection {
 365     user        = "ubuntu"
 366     host        = aws_instance.tg.public_ip
 367     private_key = tls_private_key.CSITTLS.private_key_pem
 368   }
 369
 370   provisioner "remote-exec" {
 371     inline = var.first_run_commands
 372   }
 373
 374   provisioner "ansible" {
 375     plays {
 376       playbook {
 377         file_path      = var.ansible_file_path
 378         force_handlers = true
 379       }
 380       hosts      = ["tg_aws"]
 381       extra_vars = {
 382         ansible_ssh_pass           = var.ansible_provision_pwd
 383         ansible_python_interpreter = var.ansible_python_executable
 384         aws                        = true
 385       }
 386     }
 387   }
 388 }
 389
 390 resource "null_resource" "deploy_dut1" {
 391   depends_on = [
 392     aws_instance.dut1,
 393     aws_network_interface.dut1_if1,
 394     aws_network_interface.dut1_if2
 395   ]
 396
 397   connection {
 398     user        = "ubuntu"
 399     host        = aws_instance.dut1.public_ip
 400     private_key = tls_private_key.CSITTLS.private_key_pem
 401   }
 402
 403   provisioner "remote-exec" {
 404     inline = var.first_run_commands
 405   }
 406
 407   provisioner "ansible" {
 408     plays {
 409       playbook {
 410         file_path      = var.ansible_file_path
 411         force_handlers = true
 412       }
 413       hosts      = ["sut_aws"]
 414       extra_vars = {
 415         ansible_ssh_pass           = var.ansible_provision_pwd
 416         ansible_python_interpreter = var.ansible_python_executable
 417         aws                        = true
 418       }
 419     }
 420   }
 421 }
 422
 423 resource "null_resource" "deploy_dut2" {
 424   depends_on = [
 425     aws_instance.dut2,
 426     aws_network_interface.dut2_if1,
 427     aws_network_interface.dut2_if2
 428   ]
 429
 430   connection {
 431     user        = "ubuntu"
 432     host        = aws_instance.dut2.public_ip
 433     private_key = tls_private_key.CSITTLS.private_key_pem
 434   }
 435
 436   provisioner "remote-exec" {
 437     inline = var.first_run_commands
 438   }
 439
 440   provisioner "ansible" {
 441     plays {
 442       playbook {
 443         file_path      = var.ansible_file_path
 444         force_handlers = true
 445       }
 446       hosts      = ["sut_aws"]
 447       extra_vars = {
 448         ansible_ssh_pass           = var.ansible_provision_pwd
 449         ansible_python_interpreter = var.ansible_python_executable
 450         aws                        = true
 451       }
 452     }
 453   }
 454 }
 455
 456 resource "null_resource" "deploy_topology" {
 457   depends_on = [ aws_instance.tg, aws_instance.dut1, aws_instance.dut2 ]
 458
 459   provisioner "ansible" {
 460     plays {
 461       playbook {
 462         file_path = var.ansible_topology_path
 463       }
 464       hosts      = ["local"]
 465       extra_vars = {
 466         ansible_python_interpreter = var.ansible_python_executable
 467         testbed_name               = var.testbed_name
 468         cloud_topology             = var.topology_name
 469         tg_if1_mac                 = data.aws_network_interface.tg_if1.mac_address
 470         tg_if2_mac                 = data.aws_network_interface.tg_if2.mac_address
 471         dut1_if1_mac               = data.aws_network_interface.dut1_if1.mac_address
 472         dut1_if2_mac               = data.aws_network_interface.dut1_if2.mac_address
 473         dut2_if1_mac               = data.aws_network_interface.dut2_if1.mac_address
 474         dut2_if2_mac               = data.aws_network_interface.dut2_if2.mac_address
 475         tg_public_ip               = aws_instance.tg.public_ip
 476         dut1_public_ip             = aws_instance.dut1.public_ip
 477         dut2_public_ip             = aws_instance.dut2.public_ip
 478         public_ip_list             = "${aws_instance.tg.public_ip},${aws_instance.dut1.public_ip},${aws_instance.dut2.public_ip}"
 479       }
 480     }
 481   }
 482 }