tests/func/dhcp/dhcp_v6_proxy.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/default.robot
  16 | Resource | resources/libraries/robot/testing_path.robot
  17 | Resource | resources/libraries/robot/dhcp_proxy.robot
  18 | Resource | resources/libraries/robot/ipv6.robot
  19 | Library | resources.libraries.python.Trace
  20 | Force Tags | HW_ENV | VM_ENV | 3_NODE_DOUBLE_LINK_TOPO
  21 | Test Setup | Run Keywords | Setup all DUTs before test
  22 | ...        | AND          | Setup all TGs before traffic script
  23 | Test Teardown | Run Keywords | Show Packet Trace on All DUTs | ${nodes}
  24 | ...           | AND          | Show vpp trace dump on all DUTs
  25 | Documentation | *DHCPv6 proxy test cases*
  26 | ...
  27 | ... | *[Top] Network Topologies:* TG = DUT
  28 | ... |        with two links between the nodes.
  29 | ... | *[Cfg] DUT configuration:* DUT is configured with DHCP proxy.
  30 | ... | *[Ver] TG verification:*Test DHCP packets are sent
  31 | ... |        on TG on first link to DUT and received on TG on second link.
  32 | ... |        On receive TG verifies if DHCP packets are valid
  33 | ... | *[Ref] Applicable standard specifications:* RFC 3315
  34
  35
  36 *** Variables ***
  37 | ${dut_to_tg_if1_ip}= | 3ffe:62::1
  38 | ${dut_to_tg_if2_ip}= | 3ffe:63::1
  39 | ${dhcp_server_ip}= | 3ffe:63::2
  40 | ${prefix_length}= | 64
  41
  42
  43 *** Test Cases ***
  44 | TC01: VPP proxies valid DHCPv6 request to DHCPv6 server
  45 | | [Documentation] |
  46 | | ... | [Top] TG=DUT
  47 | | ... | [Cfg] On DUT setup DHCP proxy.
  48 | | ... | [Ver] Make TG verify matching DHCPv6 packets between client and DHCP \
  49 | | ... | server through DHCP proxy.
  50 | | ... | [Ref] RFC 3315
  51 | | ...
  52 | | [Tags] | EXPECTED_FAILING
  53 | | Given Path for 2-node testing is set
  54 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
  55 | | And Interfaces in 2-node path are up
  56 | | And Vpp Set If Ipv6 Addr | ${dut_node}
  57 | | ... | ${dut_to_tg_if1} | ${dut_to_tg_if1_ip} | ${prefix_length}
  58 | | And Vpp Set If Ipv6 Addr | ${dut_node}
  59 | | ... | ${dut_to_tg_if2} | ${dut_to_tg_if2_ip} | ${prefix_length}
  60 | | And VPP Route Add | ${dut_node} | ff02::1:2 | 128 | ${NONE} | local
  61 | | ... | ${FALSE} | ${NONE}
  62 | | And Add IP Neighbor | ${dut_node} | ${dut_to_tg_if2} | ${dhcp_server_ip}
  63 | | ... | ${tg_to_dut_if2_mac}
  64 | | And Vpp All Ra Suppress Link Layer | ${nodes}
  65 | | When DHCP Proxy Config | ${dut_node} | ${dhcp_server_ip}
  66 | | ... | ${dut_to_tg_if1_ip}
  67 | | Then Send DHCPv6 Messages | ${tg_node} | ${tg_to_dut_if1} | ${tg_to_dut_if2}
  68 | | ... | ${dut_to_tg_if1_ip} | ${dut_to_tg_if1_mac} | ${dhcp_server_ip}
  69 | | ... | ${tg_to_dut_if2_mac} | ${tg_to_dut_if1_mac} |  ${dut_to_tg_if2_mac}