tests/func/honeycomb/020_bridge_domain.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 # Interfaces to run tests on.
  16 | @{interfaces}= | ${node['interfaces']['port1']['name']}
  17 | ... | ${node['interfaces']['port3']['name']}
  18 # Configuration which will be set and verified during tests.
  19 | ${bd1_name}= | bd-01
  20 | ${bd2_name}= | bd-02
  21 | &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
  22 | ... | unknown-unicast-flood=${True} | arp-termination=${True}
  23 | &{if_settings}= | split_horizon_group=${1} | bvi=${False}
  24 | &{if_settings2}= | split_horizon_group=${2} | bvi=${True}
  25
  26 *** Settings ***
  27 | Resource | resources/libraries/robot/default.robot
  28 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  29 | Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
  30 | Suite Teardown | Honeycomb removes all bridge domains | ${node}
  31 | Force Tags | honeycomb_sanity
  32 | Documentation | *Honeycomb bridge domain management test suite.*
  33 | ...
  34 | ... | Test suite uses the first two interfaces on the first DUT node.
  35
  36 *** Test Cases ***
  37 | Honeycomb sets up l2 bridge domain
  38 | | [Documentation] | Check if Honeycomb can create bridge domains on VPP node.
  39 | | When Honeycomb creates first l2 bridge domain
  40 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  41 | | Then Bridge domain configuration from Honeycomb should be
  42 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  43 | | And Bridge domain configuration from VAT should be
  44 | | ... | ${node} | ${0} | ${bd_settings}
  45
  46 | Honeycomb manages multiple bridge domains on node
  47 | | [Documentation] | Check if Honeycomb can manage multiple bridge domains on\
  48 | | ... | a single node.
  49 | | Given Bridge domain configuration from Honeycomb should be
  50 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  51 | | When Honeycomb creates l2 bridge domain
  52 | | ... | ${node} | ${bd2_name} | ${bd_settings}
  53 | | Then Bridge domain configuration from Honeycomb should be
  54 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  55 | | And Bridge domain configuration from Honeycomb should be
  56 | | ... | ${node} | ${bd2_name} | ${bd_settings}
  57 | | And Bridge domain configuration from VAT should be
  58 | | ... | ${node} | ${0} | ${bd_settings}
  59 | | And Bridge domain configuration from VAT should be
  60 | | ... | ${node} | ${1} | ${bd_settings}
  61
  62 | Honeycomb removes bridge domains
  63 | | [Documentation] | Check if Honeycomb can remove bridge domains from a VPP\
  64 | | ... | node.
  65 | | Given Bridge domain configuration from Honeycomb should be
  66 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  67 | | When Honeycomb removes all bridge domains | ${node}
  68 | | Then Honeycomb should show no bridge domains | ${node}
  69 | | And VAT should show no bridge domains | ${node}
  70
  71 | Honeycomb assigns interfaces to bridge domain
  72 | | [Documentation] | Check if Honeycomb can assign VPP interfaces to an\
  73 | | ... | existing bridge domain.
  74 | | Given Honeycomb creates first l2 bridge domain
  75 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  76 | | When Honeycomb adds interfaces to bridge domain
  77 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  78 | | Then Honeycomb should show interfaces assigned to bridge domain
  79 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  80 | | And VAT should show interfaces assigned to bridge domain
  81 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings}
  82
  83 | Honeycomb removes bridge domain with an interface assigned
  84 | | [Documentation] | Check if Honeycomb can remove a bridge domain that has an\
  85 | | ... | interface assigned to it.
  86 | | Given Honeycomb should show interfaces assigned to bridge domain
  87 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  88 | | And VAT should show interfaces assigned to bridge domain
  89 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings}
  90 | | When Honeycomb removes all bridge domains | ${node}
  91 | | Then Honeycomb should show no bridge domains | ${node}
  92 | | And VAT should show no bridge domains | ${node}