tests/func/honeycomb/081_ietf_acl_traffic.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 | &{if_settings}= | enabled=True
  16 # Bridge domain settings
  17 | ${bd_name}= | bd1
  18 | &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
  19 | ... | unknown-unicast-flood=${True} | arp-termination=${False}
  20 | &{bd_if_settings}= | split_horizon_group=${0} | bvi=${False}
  21 # Names for AC lists
  22 | ${acl_name_l2}= | acl_l2
  23 | ${acl_name_l3_ip4}= | acl_l3_ip4
  24 | ${acl_name_l3_ip6}= | acl_l3_ip6
  25 | ${acl_name_l4}= | acl_l4
  26 | ${acl_name_mixed}= | acl_mixed
  27 | ${acl_name_multirule}= | acl_multirule
  28
  29 *** Settings ***
  30 | Resource | resources/libraries/robot/default.robot
  31 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  32 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  33 | Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
  34 | Resource | resources/libraries/robot/honeycomb/access_control_lists.robot
  35 | Resource | resources/libraries/robot/testing_path.robot
  36 | Resource | resources/libraries/robot/traffic.robot
  37 | Library | resources.libraries.python.honeycomb.HcAPIKwACL.ACLKeywords
  38 | Library | resources.libraries.python.Trace
  39 | Library | resources.libraries.python.IPv4Setup
  40 | Library | resources.libraries.python.IPv4Util
  41 | Library | resources.libraries.python.IPv6Util
  42 | Library | resources.libraries.python.Routing
  43 | Test Teardown | Run Keywords | Clear IETF-ACL settings
  44 | ... | ${node} | ${dut_to_tg_if1} | AND
  45 | ... | Show Packet Trace on All DUTs | ${nodes}
  46 | Suite Teardown | Run Keyword If Any Tests Failed
  47 | ... | Restart Honeycomb And VPP And Clear Persisted Configuration | ${node}
  48 | Documentation | *Honeycomb access control lists test suite for IETF-ACL node.*
  49 # Test suite out of date since https://gerrit.fd.io/r/#/c/4331/
  50 # | Force Tags | Honeycomb_sanity
  51
  52 *** Test Cases ***
  53 | TC01: L2 ACL MAC filtering through IETF-ACL node
  54 | | [Documentation]
  55 | | ... | [Top] TG=DUT1=TG.
  56 | | ... | [Enc] Eth-IPv4-TCP.
  57 | | ... | [Cfg] (Using Honeycomb API) On DUT1 bridge both interfaces to TG\
  58 | | ... | and configure L2 MAC ACL on ingress interface.
  59 | | ... | [Ver] Send simple TCP packets from one TG interface to the other,\
  60 | | ... | using different MACs. Receive all packets except those with\
  61 | | ... | MACs in the filtered ranges.
  62 | | [Teardown] | Run Keywords
  63 | | ... | Clear IETF-ACL Settings | ${node} | ${dut_to_tg_if1} | AND
  64 | | ... | Show Packet Trace On All DUTs | ${nodes} | AND
  65 | | ... | Honeycomb Removes All Bridge Domains
  66 | | ... | ${node} | ${dut_to_tg_if1} | ${dut_to_tg_if2}
  67 | | Given Setup Interfaces And Bridge Domain For IETF-ACL Test
  68 | | ... | L2 | ${acl_name_l2}
  69 | | When Honeycomb Creates ACL Chain Through IETF Node
  70 | | ... | ${dut_node} | ${acl_name_l2} | L2 | ${acl_settings}
  71 | | And Honeycomb Assigns IETF-ACL Chain To Interface
  72 | | ... | ${dut_node} | ${dut_to_tg_if1} | L2 | ingress | ${acl_name_l2}
  73 | | ... | permit
  74 | | Then Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
  75 | | ... | ${tg_to_dut_if1} | ${src_mac}
  76 | | ... | ${tg_to_dut_if2} | ${dst_mac}
  77 | | ... | TCP | ${src_port} | ${dst_port}
  78 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
  79 | | ... | Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
  80 | | ... | ${tg_to_dut_if1} | ${classify_src}
  81 | | ... | ${tg_to_dut_if2} | ${classify_dst}
  82 | | ... | TCP | ${src_port} | ${dst_port}
  83 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
  84 | | ... | Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
  85 | | ... | ${tg_to_dut_if1} | ${classify_src2}
  86 | | ... | ${tg_to_dut_if2} | ${classify_dst2}
  87 | | ... | TCP | ${src_port} | ${dst_port}
  88
  89 | TC02: L2 ACL MAC filtering through IETF-ACL node on egress interface
  90 | | [Documentation]
  91 | | ... | [Top] TG=DUT1=TG.
  92 | | ... | [Enc] Eth-IPv4-TCP.
  93 | | ... | [Cfg] (Using Honeycomb API) On DUT1 bridge both interfaces to TG\
  94 | | ... | and configure L2 MAC ACL on egress interface.
  95 | | ... | [Ver] Send simple TCP packets from one TG interface to the other,\
  96 | | ... | using different MACs. Receive all packets except those with\
  97 | | ... | MACs in the filtered ranges.
  98 | | [Teardown] | Run Keywords
  99 | | ... | Clear IETF-ACL Settings | ${node} | ${dut_to_tg_if2} | AND
 100 | | ... | Show Packet Trace On All DUTs | ${nodes} | AND
 101 | | ... | Honeycomb Removes All Bridge Domains
 102 | | ... | ${node} | ${dut_to_tg_if1} | ${dut_to_tg_if2}
 103 | | Given Setup Interfaces And Bridge Domain For IETF-ACL Test
 104 | | ... | L2 | ${acl_name_l2}
 105 | | When Honeycomb Creates ACL Chain Through IETF Node
 106 | | ... | ${dut_node} | ${acl_name_l2} | L2 | ${acl_settings}
 107 | | And Honeycomb Assigns IETF-ACL Chain To Interface
 108 | | ... | ${dut_node} | ${dut_to_tg_if2} | L2 | egress | ${acl_name_l2}
 109 | | ... | permit
 110 | | Then Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
 111 | | ... | ${tg_to_dut_if1} | ${src_mac}
 112 | | ... | ${tg_to_dut_if2} | ${dst_mac}
 113 | | ... | TCP | ${src_port} | ${dst_port}
 114 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
 115 | | ... | Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
 116 | | ... | ${tg_to_dut_if1} | ${classify_src}
 117 | | ... | ${tg_to_dut_if2} | ${classify_dst}
 118 | | ... | TCP | ${src_port} | ${dst_port}
 119 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
 120 | | ... | Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
 121 | | ... | ${tg_to_dut_if1} | ${classify_src2}
 122 | | ... | ${tg_to_dut_if2} | ${classify_dst2}
 123 | | ... | TCP | ${src_port} | ${dst_port}
 124
 125 | TC03: L3 ACL IPv4 filtering through IETF-ACL node
 126 | | [Documentation]
 127 | | ... | [Top] TG=DUT1=TG.
 128 | | ... | [Enc] Eth-IPv4-TCP.
 129 | | ... | [Cfg] (Using Honeycomb API) On DUT1 set IPv4 addresses on both\
 130 | | ... | interfaces to TG, add ARP entry and routes, and configure L3 IPv4 ACL\
 131 | | ... | on ingress interface with src/dst IP and protocol.
 132 | | ... | [Ver] Send simple TCP and UDP packets from one TG interface\
 133 | | ... | to the other, using different IPv4 IPs. Receive all packets except\
 134 | | ... | those with IPs in the filtered ranges and UDP protocol payload.
 135 | | Given Setup Interface IPs And Routes For IPv4 IETF-ACL Test
 136 | | ... | L3_IP4 | ${acl_name_l3_ip4}
 137 | | When Honeycomb Creates ACL Chain Through IETF Node
 138 | | ... | ${dut_node} | ${acl_name_l3_ip4} | L3_IP4 | ${acl_settings}
 139 | | And Honeycomb Assigns IETF-ACL Chain To Interface
 140 | | ... | ${dut_node} | ${dut_to_tg_if1} | L3_IP4 | ingress | ${acl_name_l3_ip4}
 141 | | ... | permit
 142 | | Then Send TCP Or UDP Packet | ${tg_node}
 143 | | ... | ${src_ip} | ${dst_ip}
 144 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac}
 145 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if1_mac}
 146 | | ... | UDP | ${src_port} | ${dst_port}
 147 | | And Send TCP Or UDP Packet | ${tg_node}
 148 | | ... | ${classify_src} | ${classify_dst}
 149 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac}
 150 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if1_mac}
 151 | | ... | TCP | ${src_port} | ${dst_port}
 152 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
 153 | | ... | Send TCP Or UDP Packet | ${tg_node}
 154 | | ... | ${classify_src} | ${classify_dst}
 155 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac}
 156 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if1_mac}
 157 | | ... | UDP | ${src_port} | ${dst_port}
 158
 159 | TC04: L3 ACL IPv6 filtering through IETF-ACL node
 160 | | [Documentation]
 161 | | ... | [Top] TG=DUT1=TG.
 162 | | ... | [Enc] Eth-IPv4-TCP.
 163 | | ... | [Cfg] (Using Honeycomb API) On DUT1 set IPv6 addresses on both\
 164 | | ... | interfaces to TG, add IP neighbor entry and routes, and configure\
 165 | | ... | L3 IPv6 ACL on ingress interface with src/dst IP and next-header.
 166 | | ... | [Ver] Send simple TCP and UDP packets from one TG interface\
 167 | | ... | to the other, using different IPv6 IPs. Receive all packets except\
 168 | | ... | those with IPs in the filtered ranges and UDP protocol payload.
 169 | | Given Path for 2-node testing is set
 170 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
 171 | | And Import Variables | resources/test_data/honeycomb/ietf_acl.py
 172 | | ... | L3_IP6 | ${acl_name_l3_ip6}
 173 | | And Honeycomb sets interface state | ${dut_node} | ${dut_to_tg_if1} | up
 174 | | And Honeycomb sets interface state | ${dut_node} | ${dut_to_tg_if2} | up
 175 # TODO: Configure addresses through Honeycomb when implemented. (Honeycomb-102)
 176 | | And Set Interface Address | ${dut_node}
 177 | | ... | ${dut_to_tg_if1} | ${dut_to_tg_if1_ip} | ${prefix_length}
 178 | | And Set Interface Address | ${dut_node}
 179 | | ... | ${dut_to_tg_if2} | ${dut_to_tg_if2_ip} | ${prefix_length}
 180 | | And VPP RA suppress link layer | ${dut_node} | ${dut_to_tg_if2}
 181 # TODO: Configure route through Honeycomb when implemented.(Honeycomb-58)
 182 | | And Add IP Neighbor
 183 | | ... | ${node} | ${dut_to_tg_if2} | ${gateway} | ${tg_to_dut_if2_mac}
 184 | | And VPP Route Add | ${node} | ${dst_net} | ${prefix_length}
 185 | | ... | ${gateway} | interface=${dut_to_tg_if2} | use_sw_index=False
 186 | | And VPP Route Add | ${node} | ${classify_dst_net} | ${prefix_length}
 187 | | ... | ${gateway} | interface=${dut_to_tg_if2} | use_sw_index=False
 188 | | When Honeycomb Creates ACL Chain Through IETF Node
 189 | | ... | ${dut_node} | ${acl_name_l3_ip6} | L3_IP6 | ${acl_settings}
 190 | | And Honeycomb Assigns IETF-ACL Chain To Interface
 191 | | ... | ${dut_node} | ${dut_to_tg_if1} | L3_IP6 | ingress | ${acl_name_l3_ip6}
 192 | | ... | permit
 193 | | Then Send TCP Or UDP Packet | ${tg_node}
 194 | | ... | ${src_ip} | ${dst_ip}
 195 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac}
 196 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if1_mac}
 197 | | ... | UDP | ${src_port} | ${dst_port}
 198 | | And Send TCP Or UDP Packet | ${tg_node}
 199 | | ... | ${classify_src} | ${classify_dst}
 200 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac}
 201 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if1_mac}
 202 | | ... | TCP | ${src_port} | ${dst_port}
 203 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
 204 | | ... | Send TCP Or UDP Packet | ${tg_node}
 205 | | ... | ${classify_src} | ${classify_dst}
 206 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac}
 207 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if1_mac}
 208 | | ... | UDP | ${src_port} | ${dst_port}
 209
 210 | TC05: L4 ACL port filtering through IETF-ACL node
 211 | | [Documentation]
 212 | | ... | [Top] TG=DUT1=TG.
 213 | | ... | [Enc] Eth-IPv4-TCP.
 214 | | ... | [Cfg] (Using Honeycomb API) On DUT1 set IPv4 addresses on both\
 215 | | ... | interfaces to TG, add ARP entry and routes, and configure L4 port ACL\
 216 | | ... | on ingress interface with src/dst port ranges.
 217 | | ... | [Ver] Send simple TCP and UDP packets from one TG interface\
 218 | | ... | to the other, using different ports. Receive all packets except\
 219 | | ... | those with ports in the filtered ranges.
 220 | | Given Setup Interface IPs And Routes For IPv4 IETF-ACL Test
 221 | | ... | L4 | ${acl_name_l4}
 222 | | When Honeycomb Creates ACL Chain Through IETF Node
 223 | | ... | ${dut_node} | ${acl_name_l4} | mixed | ${acl_settings}
 224 | | And Honeycomb Assigns IETF-ACL Chain To Interface
 225 | | ... | ${dut_node} | ${dut_to_tg_if1} | mixed | ingress | ${acl_name_l4}
 226 | | ... | permit | L3
 227 | | Then Send TCP Or UDP Packet | ${tg_node}
 228 | | ... | ${src_ip} | ${dst_ip}
 229 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac}
 230 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if1_mac}
 231 | | ... | TCP | ${src_port} | ${dst_port}
 232 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
 233 | | ... | Send TCP Or UDP Packet | ${tg_node}
 234 | | ... | ${src_ip} | ${dst_ip}
 235 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac}
 236 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if1_mac}
 237 | | ... | TCP | ${classify_src} | ${classify_dst}
 238
 239 | TC06: L2,L3 and L4 ACL together on L2-mode interface
 240 | | [Documentation]
 241 | | ... | [Top] TG=DUT1=TG.
 242 | | ... | [Enc] Eth-IPv4-TCP.
 243 | | ... | [Cfg] (Using Honeycomb API) On DUT1 bridge both interfaces to TG\
 244 | | ... | and configure L2, L3 and L4 ACL on ingress interface\
 245 | | ... | with src/dst MAC, src/dst IP, protocol and src/dst port ranges.
 246 | | ... | [Ver] Send simple TCP and UDP packets from one TG interface\
 247 | | ... | to the other, using different MACs, IPv4 IPs and ports. Receive\
 248 | | ... | all packets except those with MACs, IPs and ports in the filtered\
 249 | | ... | ranges and UDP protocol payload.
 250 | | [Teardown] | Run Keywords
 251 | | ... | Clear IETF-ACL Settings | ${node} | ${dut_to_tg_if1} | AND
 252 | | ... | Show Packet Trace On All DUTs | ${nodes} | AND
 253 | | ... | Honeycomb Removes All Bridge Domains
 254 | | ... | ${node} | ${dut_to_tg_if1} | ${dut_to_tg_if2}
 255 | | Given Setup Interfaces And Bridge Domain For IETF-ACL Test
 256 | | ... | mixed | ${acl_name_mixed}
 257 | | When Honeycomb Creates ACL Chain Through IETF Node
 258 | | ... | ${dut_node} | ${acl_name_mixed} | mixed | ${acl_settings}
 259 | | And Honeycomb Assigns IETF-ACL Chain To Interface
 260 | | ... | ${dut_node} | ${dut_to_tg_if1} | mixed | ingress | ${acl_name_mixed}
 261 | | ... | permit | L2
 262 | | Then Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
 263 | | ... | ${tg_to_dut_if1} | ${classify_src_mac}
 264 | | ... | ${tg_to_dut_if2} | ${classify_dst_mac}
 265 | | ... | TCP | ${src_port} | ${dst_port}
 266 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
 267 | | ... | Send TCP Or UDP Packet | ${tg_node}
 268 | | ... | ${classify_src_ip} | ${classify_dst_ip}
 269 | | ... | ${tg_to_dut_if1} | ${classify_src_mac}
 270 | | ... | ${tg_to_dut_if2} | ${classify_dst_mac}
 271 | | ... | UDP | ${classify_src_port} | ${classify_dst_port}
 272
 273 | TC07: L2,L3 and L4 ACL together on L3-mode interface
 274 | | [Documentation]
 275 | | ... | [Top] TG=DUT1=TG.
 276 | | ... | [Enc] Eth-IPv4-TCP.
 277 | | ... | [Cfg] (Using Honeycomb API) On DUT1 set IPv4 addresses on both\
 278 | | ... | interfaces to TG, add ARP entry and routes, and configure\
 279 | | ... | L2, L3 and L4 ACL on ingress interface with src/dst MAC, src/dst IP,\
 280 | | ... | protocol and src/dst port ranges.
 281 | | ... | [Ver] Send simple TCP and UDP packets from one TG interface\
 282 | | ... | to the other, using different MACs, IPv4 IPs and ports. Receive\
 283 | | ... | all packets except those with MACs, IPs and ports in the filtered\
 284 | | ... | ranges and UDP protocol payload.
 285 | | Setup Interface IPs And Routes For IPv4 IETF-ACL Test
 286 | | ... | mixed | ${acl_name_mixed}
 287 | | When Honeycomb Creates ACL Chain Through IETF Node
 288 | | ... | ${dut_node} | ${acl_name_mixed} | mixed | ${acl_settings}
 289 | | And Honeycomb Assigns IETF-ACL Chain To Interface
 290 | | ... | ${dut_node} | ${dut_to_tg_if1} | mixed | ingress | ${acl_name_mixed}
 291 | | ... | permit | L3
 292 | | Then Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
 293 | | ... | ${tg_to_dut_if1} | ${classify_src_mac}
 294 | | ... | ${tg_to_dut_if2} | ${classify_dst_mac}
 295 | | ... | TCP | ${src_port} | ${dst_port}
 296 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
 297 | | ... | Send TCP Or UDP Packet | ${tg_node}
 298 | | ... | ${classify_src_ip} | ${classify_dst_ip}
 299 | | ... | ${tg_to_dut_if1} | ${classify_src_mac}
 300 | | ... | ${tg_to_dut_if2} | ${classify_dst_mac}
 301 | | ... | UDP | ${classify_src_port} | ${classify_dst_port}
 302
 303 | TC08: Multiple classify rules in one ACL
 304 | | [Documentation]
 305 | | ... | [Top] TG=DUT1=TG.
 306 | | ... | [Enc] Eth-IPv4-TCP.
 307 | | ... | [Cfg] (Using Honeycomb API) On DUT1 bridge both interfaces to TG\
 308 | | ... | and configure a series of L2 MAC ACL rules on ingress interface.
 309 | | ... | [Ver] Send simple TCP packets from one TG interface to the other,\
 310 | | ... | using different MACs. Receive all packets except those with\
 311 | | ... | MACs in the ranges filtered by any rule.
 312 | | [Teardown] | Run Keywords
 313 | | ... | Clear IETF-ACL Settings | ${node} | ${dut_to_tg_if1} | AND
 314 | | ... | Show Packet Trace On All DUTs | ${nodes} | AND
 315 | | ... | Honeycomb Removes All Bridge Domains
 316 | | ... | ${node} | ${dut_to_tg_if1} | ${dut_to_tg_if2}
 317 | | Given Setup Interfaces And Bridge Domain For IETF-ACL Test
 318 | | ... | multirule | ${acl_name_multirule}
 319 | | When Honeycomb Creates ACL Chain Through IETF Node
 320 | | ... | ${dut_node} | ${acl_name_multirule} | L2 | ${acl_settings}
 321 | | And Honeycomb Assigns IETF-ACL Chain To Interface
 322 | | ... | ${dut_node} | ${dut_to_tg_if1} | L2 | ingress | ${acl_name_multirule}
 323 | | ... | permit
 324 | | Then Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
 325 | | ... | ${tg_to_dut_if1} | ${src_mac}
 326 | | ... | ${tg_to_dut_if2} | ${dst_mac}
 327 | | ... | TCP | ${src_port} | ${dst_port}
 328 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
 329 | | ... | Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
 330 | | ... | ${tg_to_dut_if1} | ${classify_src}
 331 | | ... | ${tg_to_dut_if2} | ${classify_dst}
 332 | | ... | TCP | ${src_port} | ${dst_port}
 333 | | And Run Keyword And Expect Error | TCP/UDP Rx timeout
 334 | | ... | Send TCP Or UDP Packet | ${tg_node} | ${src_ip} | ${dst_ip}
 335 | | ... | ${tg_to_dut_if1} | ${classify_src2}
 336 | | ... | ${tg_to_dut_if2} | ${classify_dst2}
 337 | | ... | TCP | ${src_port} | ${dst_port}
 338
 339 *** Keywords ***
 340 | Setup interface IPs and routes for IPv4 ietf-ACL test
 341 | | [Arguments] | ${test_data_id} | ${acl_name}
 342 | | Path for 2-node testing is set
 343 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
 344 | | Import Variables | resources/test_data/honeycomb/ietf_acl.py
 345 | | ... | ${test_data_id} | ${acl_name}
 346 | | Honeycomb sets interface state | ${dut_node} | ${dut_to_tg_if1} | up
 347 | | Honeycomb sets interface state | ${dut_node} | ${dut_to_tg_if2} | up
 348 | | Honeycomb sets interface ipv4 address with prefix | ${dut_node}
 349 | | ... | ${dut_to_tg_if1} | ${dut_to_tg_if1_ip} | ${prefix_length}
 350 | | Honeycomb sets interface ipv4 address with prefix | ${dut_node}
 351 | | ... | ${dut_to_tg_if2} | ${dut_to_tg_if2_ip} | ${prefix_length}
 352 # TODO: Configure routes through Honeycomb when implemented.(Honeycomb-58)
 353 | | Add ARP on DUT
 354 | | ... | ${node} | ${dut_to_tg_if2} | ${gateway} | ${tg_to_dut_if2_mac}
 355 | | VPP Route Add
 356 | | ... | ${node} | ${dst_net} | ${prefix_length} | ${gateway}
 357 | | ... | interface=${dut_to_tg_if2} | use_sw_index=False
 358 | | VPP Route Add
 359 | | ... | ${node} | ${classify_dst_net} | ${prefix_length} | ${gateway}
 360 | | ... | interface=${dut_to_tg_if2} | use_sw_index=False
 361
 362 | Setup interfaces and bridge domain for ietf-ACL test
 363 | | [Arguments] | ${test_data_id} | ${acl_name}
 364 | | Path For 2-node Testing Is Set
 365 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
 366 | | Import Variables | resources/test_data/honeycomb/ietf_acl.py
 367 | | ... | ${test_data_id} | ${acl_name}
 368 | | Honeycomb Sets Interface State | ${dut_node} | ${dut_to_tg_if1} | up
 369 | | Honeycomb Sets Interface State | ${dut_node} | ${dut_to_tg_if2} | up
 370 | | Honeycomb Creates first L2 Bridge Domain
 371 | | ... | ${dut_node} | ${bd_name} | ${bd_settings}
 372 | | Honeycomb Adds Interfaces To Bridge Domain
 373 | | ... | ${dut_node} | ${dut_to_tg_if1} | ${dut_to_tg_if2}
 374 | | ... | ${bd_name} | ${bd_if_settings}