tests/func/honeycomb/mgmt-cfg-inttap-apihc-apivat-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 # Interfaces to run tests on.
  16 | ${interface}= | ${node['interfaces']['port1']['name']}
  17 | ${tap_interface}= | tap_test
  18 # Configuration which will be set and verified during tests.
  19 | &{tap_settings}= | tap-name=tap_test | mac=08:00:27:c0:5d:37
  20 | ... | device-instance=${1}
  21 | &{tap_settings2}= | tap-name=tap_test | mac=08:00:27:60:26:ab
  22 | ... | device-instance=${2}
  23
  24 *** Settings ***
  25 | Resource | resources/libraries/robot/default.robot
  26 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  27 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  28 | Resource | resources/libraries/robot/honeycomb/tap.robot
  29 | Force Tags | honeycomb_sanity
  30 | Suite Teardown | Run Keyword If Any Tests Failed
  31 | ... | Restart Honeycomb And VPP And Clear Persisted Configuration | ${node}
  32 | Documentation | *Honeycomb TAP management test suite.*
  33 | ...
  34 | ... | Test suite uses the first interface of the first DUT node.
  35
  36 *** Test Cases ***
  37 | TC01: Honeycomb configures TAP interface
  38 | | [Documentation] | Check if Honeycomb API can configure a TAP interface.
  39 | | Given TAP configuration from Honeycomb should be empty
  40 | | ... | ${node} | ${tap_interface}
  41 | | And TAP configuration from VAT should be empty
  42 | | ... | ${node} | ${tap_interface}
  43 | | When Honeycomb creates TAP interface
  44 | | ... | ${node} | ${tap_interface} | ${tap_settings}
  45 | | Then TAP configuration from Honeycomb should be
  46 | | ... | ${node} | ${tap_interface} | ${tap_settings}
  47 | | And TAP configuration from VAT should be
  48 | | ... | ${node} | ${tap_interface} | ${tap_settings}
  49
  50 | TC02: Honeycomb modifies existing TAP interface configuration
  51 | | [Documentation] | Check if Honeycomb API can re-configure and existing TAP\
  52 | | ... | interface with new settings.
  53 | | Given TAP configuration from Honeycomb should be
  54 | | ... | ${node} | ${tap_interface} | ${tap_settings}
  55 | | And TAP configuration from VAT should be
  56 | | ... | ${node} | ${tap_interface} | ${tap_settings}
  57 | | When Honeycomb configures TAP interface
  58 | | ... | ${node} | ${tap_interface} | ${tap_settings2}
  59 | | Then TAP configuration from Honeycomb should be
  60 | | ... | ${node} | ${tap_interface} | ${tap_settings2}
  61 | | And TAP configuration from VAT should be
  62 | | ... | ${node} | ${tap_interface} | ${tap_settings2}
  63
  64 | TC03: Honeycomb removes TAP interface
  65 | | [Documentation] | Check if Honeycomb API can remove TAP interface.
  66 | | Given TAP configuration from Honeycomb should be
  67 | | ... | ${node} | ${tap_interface} | ${tap_settings2}
  68 | | And TAP configuration from VAT should be
  69 | | ... | ${node} | ${tap_interface} | ${tap_settings2}
  70 | | When Honeycomb removes TAP interface | ${node} | ${tap_interface}
  71 | | Then TAP configuration from Honeycomb should be empty
  72 | | ... | ${node} | ${tap_interface}
  73 | | And TAP configuration from VAT should be empty
  74 | | ... | ${node} | ${tap_interface}