tests/func/honeycomb/mgmt-cfg-l2bd-apihc-apivat-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 # Interfaces to run tests on.
  16 | @{interfaces}= | ${node['interfaces']['port1']['name']}
  17 | ... | ${node['interfaces']['port3']['name']}
  18 # Configuration which will be set and verified during tests.
  19 | ${bd1_name}= | bd-01
  20 | ${bd2_name}= | bd-02
  21 | &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
  22 | ... | unknown-unicast-flood=${True} | arp-termination=${True}
  23 | &{if_settings}= | split_horizon_group=${1} | bvi=${False}
  24 | &{if_settings2}= | split_horizon_group=${2} | bvi=${True}
  25
  26 *** Settings ***
  27 | Resource | resources/libraries/robot/default.robot
  28 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  29 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  30 | Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
  31 | Suite Teardown | Run keywords
  32 | ... | Run Keyword If Any Tests Failed
  33 | ... | Restart Honeycomb And VPP And Clear Persisted Configuration | ${node}
  34 | ... | AND | Honeycomb removes all bridge domains | ${node} | @{interfaces}
  35 | Force Tags | honeycomb_sanity
  36 | Documentation | *Honeycomb bridge domain management test suite.*
  37 | ...
  38 | ... | Test suite uses the first two interfaces on the first DUT node.
  39
  40 *** Test Cases ***
  41 | TC01: Honeycomb sets up l2 bridge domain
  42 | | [Documentation] | Check if Honeycomb can create bridge domains on VPP node.
  43 | | When Honeycomb creates first l2 bridge domain
  44 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  45 | | Then Bridge domain configuration from Honeycomb should be
  46 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  47 | | And Bridge domain configuration from VAT should be
  48 | | ... | ${node} | ${0} | ${bd_settings}
  49
  50 | TC02: Honeycomb manages multiple bridge domains on node
  51 | | [Documentation] | Check if Honeycomb can manage multiple bridge domains on\
  52 | | ... | a single node.
  53 | | Given Bridge domain configuration from Honeycomb should be
  54 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  55 | | When Honeycomb creates l2 bridge domain
  56 | | ... | ${node} | ${bd2_name} | ${bd_settings}
  57 | | Then Bridge domain configuration from Honeycomb should be
  58 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  59 | | And Bridge domain configuration from Honeycomb should be
  60 | | ... | ${node} | ${bd2_name} | ${bd_settings}
  61 | | And Bridge domain configuration from VAT should be
  62 | | ... | ${node} | ${0} | ${bd_settings}
  63 | | And Bridge domain configuration from VAT should be
  64 | | ... | ${node} | ${1} | ${bd_settings}
  65
  66 | TC03: Honeycomb removes bridge domains
  67 | | [Documentation] | Check if Honeycomb can remove bridge domains from a VPP\
  68 | | ... | node.
  69 | | Given Bridge domain configuration from Honeycomb should be
  70 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  71 | | When Honeycomb removes all bridge domains | ${node}
  72 | | Then Honeycomb should show no bridge domains | ${node}
  73 | | And VAT should show no bridge domains | ${node}
  74
  75 | TC04: Honeycomb assigns interfaces to bridge domain
  76 | | [Documentation] | Check if Honeycomb can assign VPP interfaces to an\
  77 | | ... | existing bridge domain.
  78 | | Given Honeycomb creates first l2 bridge domain
  79 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  80 | | When Honeycomb adds interfaces to bridge domain
  81 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  82 | | Then Honeycomb should show interfaces assigned to bridge domain
  83 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  84 | | And VAT should show interfaces assigned to bridge domain
  85 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings}
  86
  87 | TC05: Honeycomb removes bridge domain with an interface assigned
  88 | | [Documentation] | Check if Honeycomb can remove a bridge domain that has an\
  89 | | ... | interface assigned to it.
  90 # Bridge domain references not cleaned up on delete (HONEYCOMB-267)
  91 | | [Tags] | EXPECTED_FAILING
  92 | | Given Honeycomb should show interfaces assigned to bridge domain
  93 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  94 | | And VAT should show interfaces assigned to bridge domain
  95 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings}
  96 | | When Honeycomb removes all bridge domains | ${node}
  97 | | Then Honeycomb should show no bridge domains | ${node}
  98 | | And VAT should show no bridge domains | ${node}
  99 | | And Honeycomb should not show interfaces assigned to bridge domain
 100 | | ... | ${node} | @{interfaces} | ${bd1_name}