CSIT-562 HC Test: Persistence suite rework, part1
[csit.git] / tests / func / honeycomb / mgmt-cfg-l2bd-apihc-apivat-func.robot
1 # Copyright (c) 2016 Cisco and/or its affiliates.
2 # Licensed under the Apache License, Version 2.0 (the "License");
3 # you may not use this file except in compliance with the License.
4 # You may obtain a copy of the License at:
5 #
6 #     http://www.apache.org/licenses/LICENSE-2.0
7 #
8 # Unless required by applicable law or agreed to in writing, software
9 # distributed under the License is distributed on an "AS IS" BASIS,
10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11 # See the License for the specific language governing permissions and
12 # limitations under the License.
13
14 *** Variables ***
15 # Interfaces to run tests on.
16 | @{interfaces}= | ${node['interfaces']['port1']['name']}
17 | ... | ${node['interfaces']['port3']['name']}
18 # Configuration which will be set and verified during tests.
19 | ${bd1_name}= | bd-01
20 | ${bd2_name}= | bd-02
21 | &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
22 | ... | unknown-unicast-flood=${True} | arp-termination=${True}
23 | &{if_settings}= | split_horizon_group=${1} | bvi=${False}
24 | &{if_settings2}= | split_horizon_group=${2} | bvi=${True}
25
26 *** Settings ***
27 | Resource | resources/libraries/robot/default.robot
28 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
29 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
30 | Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
31 | Suite Teardown | Run keywords
32 | ... | Run Keyword If Any Tests Failed
33 | ... | Restart Honeycomb and VPP | ${node}
34 | ... | AND | Honeycomb removes all bridge domains | ${node} | @{interfaces}
35 | Force Tags | HC_FUNC
36 | Documentation | *Honeycomb bridge domain management test suite.*
37
38 *** Test Cases ***
39 | TC01: Honeycomb sets up l2 bridge domain
40 | | [Documentation] | Check if Honeycomb can create bridge domains on VPP node.
41 | | When Honeycomb creates first l2 bridge domain
42 | | ... | ${node} | ${bd1_name} | ${bd_settings}
43 | | Then Bridge domain Operational Data From Honeycomb Should Be
44 | | ... | ${node} | ${bd1_name} | ${bd_settings}
45 | | And Bridge domain Operational Data From VAT Should Be
46 | | ... | ${node} | ${0} | ${bd_settings}
47
48 | TC02: Honeycomb manages multiple bridge domains on node
49 | | [Documentation] | Check if Honeycomb can manage multiple bridge domains on\
50 | | ... | a single node.
51 | | Given Bridge domain Operational Data From Honeycomb Should Be
52 | | ... | ${node} | ${bd1_name} | ${bd_settings}
53 | | When Honeycomb creates l2 bridge domain
54 | | ... | ${node} | ${bd2_name} | ${bd_settings}
55 | | Then Bridge domain Operational Data From Honeycomb Should Be
56 | | ... | ${node} | ${bd1_name} | ${bd_settings}
57 | | And Bridge domain Operational Data From Honeycomb Should Be
58 | | ... | ${node} | ${bd2_name} | ${bd_settings}
59 | | And Bridge domain Operational Data From VAT Should Be
60 | | ... | ${node} | ${0} | ${bd_settings}
61 | | And Bridge domain Operational Data From VAT Should Be
62 | | ... | ${node} | ${1} | ${bd_settings}
63
64 | TC03: Honeycomb removes bridge domains
65 | | [Documentation] | Check if Honeycomb can remove bridge domains from a VPP\
66 | | ... | node.
67 | | Given Bridge domain Operational Data From Honeycomb Should Be
68 | | ... | ${node} | ${bd1_name} | ${bd_settings}
69 | | When Honeycomb removes all bridge domains | ${node}
70 | | Then Honeycomb should show no bridge domains | ${node}
71 | | And VAT should show no bridge domains | ${node}
72
73 | TC04: Honeycomb assigns interfaces to bridge domain
74 | | [Documentation] | Check if Honeycomb can assign VPP interfaces to an\
75 | | ... | existing bridge domain.
76 | | Given Honeycomb creates first l2 bridge domain
77 | | ... | ${node} | ${bd1_name} | ${bd_settings}
78 | | When Honeycomb adds interfaces to bridge domain
79 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
80 | | Then Bridge domain Operational Data From Honeycomb Should Be
81 | | ... | ${node} | ${bd1_name} | ${bd_settings}
82 | | And Bridge domain Operational Data From VAT Should Be
83 | | ... | ${node} | ${0} | ${bd_settings}
84 | | And Honeycomb should show interfaces assigned to bridge domain
85 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
86 | | And VAT should show interfaces assigned to bridge domain
87 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings}
88
89 | TC05: Honeycomb cannot remove bridge domain with an interface assigned
90 | | [Documentation] | Check if Honeycomb can remove a bridge domain that has an\
91 | | ... | interface assigned to it. Expect to fail with code 500.
92 | | Given Bridge domain Operational Data From Honeycomb Should Be
93 | | ... | ${node} | ${bd1_name} | ${bd_settings}
94 | | And Bridge domain Operational Data From VAT Should Be
95 | | ... | ${node} | ${0} | ${bd_settings}
96 | | And Honeycomb should show interfaces assigned to bridge domain
97 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
98 | | And VAT should show interfaces assigned to bridge domain
99 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings}
100 | | When Run keyword and expect error | HoneycombError* Status code: 500.
101 | | ... | Honeycomb removes all bridge domains | ${node}
102 | | Then Bridge domain Operational Data From Honeycomb Should Be
103 | | ... | ${node} | ${bd1_name} | ${bd_settings}
104 | | And Bridge domain Operational Data From VAT Should Be
105 | | ... | ${node} | ${0} | ${bd_settings}
106 | | And Honeycomb should show interfaces assigned to bridge domain
107 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
108 | | And VAT should show interfaces assigned to bridge domain
109 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings}

©2016 FD.io a Linux Foundation Collaborative Project. All Rights Reserved.
Linux Foundation is a registered trademark of The Linux Foundation. Linux is a registered trademark of Linus Torvalds.
Please see our privacy policy and terms of use.