tests/func/honeycomb/mgmt-cfg-lisp-apihc-apivat-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables***
  15 | ${interface}= | ${node['interfaces']['port1']['name']}
  16 | ${bd_name}= | bd_lisp
  17 | ${bd2_name}= | bd2_lisp
  18 | &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
  19 | ... | unknown-unicast-flood=${True} | arp-termination=${True}
  20
  21 *** Settings ***
  22 | Resource | resources/libraries/robot/default.robot
  23 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  24 | Resource | resources/libraries/robot/honeycomb/lisp.robot
  25 | Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
  26 | Variables | resources/test_data/honeycomb/lisp.py
  27 | Documentation | *Honeycomb Lisp test suite.*
  28 | Suite Teardown | Run Keyword If Any Tests Failed
  29 | ... | Restart Honeycomb And VPP And Clear Persisted Configuration | ${node}
  30 | Force Tags | honeycomb_sanity
  31
  32 *** Test Cases ***
  33 | TC01: Honeycomb enables Lisp feature
  34 | | [Documentation] | Check if Honeycomb can enable the Lisp feature.
  35 | | Given Lisp Should Not Be Configured | ${node}
  36 | | When Honeycomb Enables Lisp | ${node}
  37 | | Then Lisp state From Honeycomb Should Be | ${node} | enabled
  38 | | And Lisp state From VAT Should Be | ${node} | enabled
  39
  40 | TC02: Honeycomb adds locator set and locator
  41 | | [Documentation] | Check if Honeycomb can configure a locator set.
  42 | | Given Lisp state From Honeycomb Should Be | ${node} | enabled
  43 | | When Honeycomb adds locator set | ${node} | ${interface} | ${locator_set}
  44 | | Then Locator Set From Honeycomb Should Be
  45 | | ... | ${node} | ${interface} | ${locator_set}
  46
  47 | TC03: Honeycomb configures Lisp - remote mapping - Bridge Domain
  48 | | [Documentation] | Check if Honeycomb can configure a remote Lisp mapping\
  49 | | ... | with a bridge domain.
  50 | | Given Lisp state From Honeycomb Should Be | ${node} | enabled
  51 | | And Honeycomb creates first l2 bridge domain
  52 | | ... | ${node} | ${bd_name} | ${bd_settings}
  53 | | When Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_remote_bd}
  54 | | Then Lisp mapping From Honeycomb Should Be
  55 | | ... | ${node} | ${remote_bd_subtable}
  56 | | And Lisp mapping From VAT Should Be
  57 | | ... | ${node} | ${vat_remote_bd}
  58
  59 | TC04: Honeycomb can remove Lisp mapping
  60 | | [Documentation] | Check if Honeycomb can remove a configured Lisp mapping.
  61 | | Given Lisp mapping From Honeycomb Should Be
  62 | | ... | ${node} | ${remote_bd_subtable}
  63 | | And Lisp mapping From VAT Should Be
  64 | | ... | ${node} | ${vat_remote_bd}
  65 | | When Honeycomb removes all lisp mappings | ${node}
  66 | | Then Lisp mappings from Honeycomb should not exist
  67 | | ... | ${node}
  68 | | And Lisp mappings from VAT should not exist
  69 | | ... | ${node}
  70
  71 | TC05: Honeycomb configures Lisp - remote mapping - VRF
  72 | | [Documentation] | Check if Honeycomb can configure a remote Lisp mapping\
  73 | | ... | with VRF.
  74 | | [Teardown] | Honeycomb removes all lisp mappings | ${node}
  75 | | Given Lisp mappings from Honeycomb should not exist
  76 | | ... | ${node}
  77 | | And Lisp mappings from VAT should not exist
  78 | | ... | ${node}
  79 | | When Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_remote_vrf}
  80 | | Then Lisp mapping From Honeycomb Should Be
  81 | | ... | ${node} | ${remote_vrf_subtable}
  82 | | And Lisp mapping From VAT Should Be | ${node} | ${vat_remote_vrf}
  83
  84 | TC06: Honeycomb configures Lisp - local mapping - Bridge Domain
  85 | | [Documentation] | Check if Honeycomb can configure a local Lisp mapping\
  86 | | ... | with a bridge domain.
  87 | | [Teardown] | Honeycomb removes all lisp mappings | ${node}
  88 | | Given Locator Set From Honeycomb Should Be
  89 | | ... | ${node} | ${interface} | ${locator_set}
  90 | | And Lisp mappings from Honeycomb should not exist
  91 | | ... | ${node}
  92 | | And Lisp mappings from VAT should not exist
  93 | | ... | ${node}
  94 | | And Honeycomb creates first l2 bridge domain
  95 | | ... | ${node} | ${bd2_name} | ${bd_settings}
  96 | | When Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_local_bd}
  97 | | Then Lisp mapping From Honeycomb Should Be | ${node} | ${local_bd_subtable}
  98 | | And Lisp mapping From VAT Should Be | ${node} | ${vat_local_bd}
  99
 100 | TC07: Honeycomb configures Lisp - local mapping - VRF
 101 | | [Documentation] | Check if Honeycomb can configure a local Lisp mapping\
 102 | | ... | with VRF.
 103 | | [Teardown] | Honeycomb removes all lisp mappings | ${node}
 104 | | Given Locator Set From Honeycomb Should Be
 105 | | ... | ${node} | ${interface} | ${locator_set}
 106 | | And Lisp mappings from Honeycomb should not exist
 107 | | ... | ${node}
 108 | | And Lisp mappings from VAT should not exist
 109 | | ... | ${node}
 110 | | When Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_local_vrf}
 111 | | Then Lisp mapping From Honeycomb Should Be | ${node} | ${local_vrf_subtable}
 112 | | And Lisp mapping From VAT Should Be | ${node} | ${vat_local_vrf}
 113
 114 | TC08: Honeycomb configures Lisp mapping with adjacency
 115 | | [Documentation] | Check if Honeycomb can configure local and remote Lisp\
 116 | | ... | mappings with VRF, and configure adjacency.
 117 | | [Teardown] | Honeycomb removes all lisp mappings | ${node}
 118 | | Given Locator Set From Honeycomb Should Be
 119 | | ... | ${node} | ${interface} | ${locator_set}
 120 | | And Honeycomb creates first l2 bridge domain
 121 | | ... | ${node} | ${bd2_name} | ${bd_settings}
 122 | | And Lisp mappings from Honeycomb should not exist
 123 | | ... | ${node}
 124 | | And Lisp mappings from VAT should not exist
 125 | | ... | ${node}
 126 | | And Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_both_vrf}
 127 | | When Honeycomb adds Lisp adjacency | ${node} | ${7} | remote_map_vrf
 128 | | ... | adj01 | ${vrf_adjacency}
 129 | | Then Lisp mapping from Honeycomb should be
 130 | | ... | ${node} | ${adj_subtable}
 131
 132 | TC09: Honeycomb configures Lisp map resolver
 133 | | [Documentation] | Check if Honeycomb can configure a Lisp map resolver.
 134 | | Given Lisp state From Honeycomb Should Be | ${node} | enabled
 135 | | And Lisp state From VAT Should Be | ${node} | enabled
 136 | | When Honeycomb adds Lisp Map resolver | ${node} | 192.168.0.4
 137 | | Then Map resolver from Honeycomb should be | ${node} | 192.168.0.4
 138 | | And Map resolver from VAT should be | ${node} | 192.168.0.4
 139
 140 | TC10: Honeycomb enabled Lisp PITR feature
 141 | | [Documentation] | Check if Honeycomb can configure the Lisp PITR feature.
 142 | | Given Locator Set From Honeycomb Should Be
 143 | | ... | ${node} | ${interface} | ${locator_set}
 144 | | When Honeycomb enables Lisp PITR feature | ${node} | ${locator_set}
 145 | | Then PITR config from Honeycomb should be | ${node} | ${locator_set}
 146 | | And PITR config from VAT should be | ${node} | ${locator_set}
 147
 148 | TC11: Honeycomb can remove configuration of Lisp features
 149 | | [Documentation] | Check if Honeycomb can disable all Lisp features.
 150 | | Given Map resolver from Honeycomb should be | ${node} | 192.168.0.4
 151 | | And PITR config from Honeycomb should be | ${node} | ${locator_set}
 152 | | When Honeycomb disables all Lisp features | ${node}
 153 | | Then Lisp Should Not Be Configured | ${node}