tests/func/honeycomb/mgmt-statepersist-apihc-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables***
  15 # Interface to run tests on.
  16 | ${interface}= | ${node['interfaces']['port1']['name']}
  17
  18 *** Settings ***
  19 | Resource | resources/libraries/robot/default.robot
  20 | Resource | resources/libraries/robot/honeycomb/persistence.robot
  21 | Suite Setup | Run Keywords
  22 | ... | Restart Honeycomb And VPP And Clear Persisted Configuration | ${node}
  23 | ... | AND | Configure Persistence | ${node} | enable
  24 | Suite Teardown | Configure Persistence | ${node} | disable
  25 | Force Tags | honeycomb_sanity
  26 | Documentation | *Honeycomb configuration persistence test suite.*
  27
  28 *** Test Cases ***
  29 | TC01: Honeycomb persists configuration through restart of both Honeycomb and VPP
  30 | | [Documentation] | Checks if Honeycomb maintains configuration after both\
  31 | | ... | Honeycomb and VPP are restarted.
  32 # Vxlan tunnel name is sometimes not properly restored (HONEYCOMB-301)
  33 | | [Tags] | EXPECTED_FAILING
  34 | | Given Honeycomb configures every setting | ${node} | ${interface}
  35 | | And Honeycomb and VPP should verify every setting | ${node} | ${interface}
  36 | | When Honeycomb and VPP are restarted | ${node}
  37 | | Then Honeycomb and VPP should verify every setting | ${node} | ${interface}
  38 | | And Honeycomb should show no rogue interfaces | ${node}
  39
  40 | TC02: Honeycomb persists configuration through restart of Honeycomb
  41 | | [Documentation] | Checks if Honeycomb maintains configuration after it\
  42 | | ... | is restarted.
  43 # Vxlan tunnel name is sometimes not properly restored (HONEYCOMB-301)
  44 | | [Tags] | EXPECTED_FAILING
  45 | | Given Honeycomb and VPP should verify every setting | ${node} | ${interface}
  46 | | When Honeycomb is restarted | ${node}
  47 | | Then Honeycomb and VPP should verify every setting | ${node} | ${interface}
  48 | | And Honeycomb should show no rogue interfaces | ${node}
  49
  50 | TC03: Honeycomb persists configuration through restart of VPP
  51 | | [Documentation] | Checks if Honeycomb updates VPP settings after VPP is\
  52 | | ... | restarted.
  53 # Vxlan tunnel name is sometimes not properly restored (HONEYCOMB-301)
  54 | | [Tags] | EXPECTED_FAILING
  55 | | Given Honeycomb and VPP should verify every setting | ${node} | ${interface}
  56 | | When VPP is restarted | ${node}
  57 | | Then Honeycomb and VPP should verify every setting | ${node} | ${interface}
  58 | | And Honeycomb should show no rogue interfaces | ${node}
  59
  60 | TC04: Honeycomb reverts to defaults if persistence files are invalid
  61 | | [Documentation] | Checks if Honeycomb reverts to default configuration when\
  62 | | ... | persistence files are damaged or invalid.
  63 | | [Teardown] | Run keyword if test failed
  64 | | ... | Restart Honeycomb And VPP And Clear Persisted Configuration | ${node}
  65 | | When Persistence file is damaged during restart | ${node}
  66 | | Then Honeycomb and VPP should have default configuration | ${node}