tests/func/ipv6/ipv6_multipath_routing.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14
  15 *** Settings ***
  16 | Resource | resources/libraries/robot/default.robot
  17 | Resource | resources/libraries/robot/counters.robot
  18 | Resource | resources/libraries/robot/interfaces.robot
  19 | Resource | resources/libraries/robot/testing_path.robot
  20 | Resource | resources/libraries/robot/ipv6.robot
  21 | Resource | resources/libraries/robot/traffic.robot
  22 | Library | resources.libraries.python.Trace
  23
  24 | Force Tags | HW_ENV | VM_ENV | 3_NODE_DOUBLE_LINK_TOPO
  25 | Suite Setup | Run Keywords | Setup all TGs before traffic script
  26 | ...         | AND          | Update All Interface Data On All Nodes | ${nodes}
  27 | Test Setup | Setup all DUTs before test
  28 | Test Teardown | Run Keywords | Show packet trace on all DUTs | ${nodes}
  29 | ...           | AND          | Vpp Show Errors | ${nodes['DUT1']}
  30 | ...           | AND          | Show vpp trace dump on all DUTs
  31 | Documentation | *Ipv6 Multipath routing test cases*
  32 | ...
  33 | ... | *[Top] Network topologies:* TG=DUT 2-node topology with two links\
  34 | ... | between nodes.
  35 | ... | *[Cfg] DUT configuration:* On DUT configure interfaces IPv4 adresses,\
  36 | ... | and multipath routing.
  37 | ... | *[Ver] TG verification:* Test packets are sent from TG on the first\
  38 | ... | link to DUT. Packet is received on TG on the second link from DUT1.
  39
  40 *** Variables ***
  41 | ${ip_1}= | 3ffe:61::1
  42 | ${ip_2}= | 3ffe:62::1
  43 | ${test_dst_ip}= | 3ffe:71::1
  44 | ${test_src_ip}= | 3ffe:51::1
  45 | ${prefix_length}= | 64
  46 | ${neighbor_1_ip}= | 3ffe:62::2
  47 | ${neighbor_1_mac}= | 02:00:00:00:00:02
  48 | ${neighbor_2_ip}= | 3ffe:62::3
  49 | ${neighbor_2_mac}= | 02:00:00:00:00:03
  50
  51 *** Test Cases ***
  52 | TC01: IPv6 Equal-cost multipath routing
  53 | | [Documentation]
  54 | | ... | [Top] TG=DUT
  55 | | ... | [Cfg] On DUT configure multipath routing wiht two equal-cost paths.
  56 | | ... | [Ver] TG sends 100 IPv6 ICMP packets traffic on the first link to\
  57 | | ... | DUT. On second link to TG verify if traffic is divided into two paths.
  58 | | Given Path for 2-node testing is set
  59 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
  60 | | And Interfaces in 2-node path are UP
  61 | | And Vpp Set If Ipv6 Addr | ${dut_node}
  62 | | ... | ${dut_to_tg_if2} | ${ip_1} | ${prefix_length}
  63 | | And Vpp Set If Ipv6 Addr | ${dut_node}
  64 | | ... | ${dut_to_tg_if1} | ${ip_2} | ${prefix_length}
  65 | | And Add Ip Neighbor
  66 | | ... | ${dut_node} | ${dut_to_tg_if1} | ${neighbor_1_ip} | ${neighbor_1_mac}
  67 | | And Add Ip Neighbor
  68 | | ... | ${dut_node} | ${dut_to_tg_if1} | ${neighbor_2_ip} | ${neighbor_2_mac}
  69 | | When Vpp Route Add
  70 | | ... | ${dut_node} | ${test_dst_ip} | ${prefix_length} | ${neighbor_1_ip}
  71 | | ... | ${dut_to_tg_if1} | resolve_attempts=${NONE} | multipath=${TRUE}
  72 | | And Vpp Route Add
  73 | | ... | ${dut_node} | ${test_dst_ip} | ${prefix_length} | ${neighbor_2_ip}
  74 | | ... | ${dut_to_tg_if1} | resolve_attempts=${NONE} | multipath=${TRUE}
  75 | | Then Send Packets And Check Multipath Routing | ${tg_node}
  76 | | ... | ${tg_to_dut_if2} | ${tg_to_dut_if1} | ${test_src_ip} | ${test_dst_ip}
  77 | | ... | ${tg_to_dut_if2_mac} | ${dut_to_tg_if2_mac} | ${dut_to_tg_if1_mac}
  78 | | ... | ${neighbor_1_mac} | ${neighbor_2_mac}