tests/func/l2bd_base/eth2p-eth-l2bdbasemacstc-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/default.robot
  16 | Resource | resources/libraries/robot/bridge_domain.robot
  17 | Resource | resources/libraries/robot/testing_path.robot
  18 | Resource | resources/libraries/robot/qemu.robot
  19 | Library  | resources.libraries.python.Trace
  20 | Force Tags | HW_ENV | VM_ENV
  21 | Test Setup | Func Test Setup
  22 | Test Teardown | Func Test Teardown
  23 | Documentation | *L2 bridge-domain test cases*
  24 | ...
  25 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  26 | ... | with single links between nodes.
  27 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for L2 switching of
  28 | ... | IPv4; Eth-IPv6-ICMPv6 for L2 switching of IPv6 use. Both apply
  29 | ... | to all links.
  30 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  31 | ... | bridge-domain (L2BD) switching combined with static MACs.
  32 | ... | *[Ver] TG verification:* Test ICMPv4 (or ICMPv6) Echo Request packets
  33 | ... | are sent in both directions by TG on links to DUT1 and DUT2; on
  34 | ... | receive TG verifies packets for correctness and their IPv4 (IPv6)
  35 | ... | src-addr, dst-addr and MAC addresses.
  36 | ... | *[Ref] Applicable standard specifications:*
  37
  38 *** Variables ***
  39 | ${bd_id1}= | 1
  40 | ${bd_id2}= | 2
  41
  42 *** Test Cases ***
  43 | TC01: DUT1 and DUT2 with L2BD (static MACs) switch between two TG links
  44 | | [Documentation]
  45 | | ... | [Top] TG-DUT1-DUT2-TG. [Enc] Eth-IPv4-ICMPv4. [Cfg] On DUT1 and \
  46 | | ... | DUT2 configure two i/fs into L2BD with static MACs. [Ver] Make
  47 | | ... | TG verify ICMPv4 Echo Req pkts are switched thru DUT1 and DUT2
  48 | | ... | in both directions and are correct on receive. [Ref]
  49 | | [Tags] | 3_NODE_SINGLE_LINK_TOPO
  50 | | Given Path for 3-node testing is set
  51 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  52 | | And Interfaces in 3-node path are up
  53 | | When Bridge domain on DUT node is created | ${dut1_node} | ${bd_id1}
  54 | | ...                                       | learn=${FALSE}
  55 | | And Interface is added to bridge domain | ${dut1_node} | ${dut1_to_tg}
  56 | | ...                                     | ${bd_id1}
  57 | | And Interface is added to bridge domain | ${dut1_node} | ${dut1_to_dut2}
  58 | | ...                                     | ${bd_id1}
  59 | | And Destination port is added to L2FIB on DUT node | ${tg_node}
  60 | | ...                                                | ${tg_to_dut1}
  61 | | ...                                                | ${dut1_node}
  62 | | ...                                                | ${dut1_to_tg}
  63 | | ...                                                | ${bd_id1}
  64 | | And Destination port is added to L2FIB on DUT node | ${tg_node}
  65 | | ...                                                | ${tg_to_dut2}
  66 | | ...                                                | ${dut1_node}
  67 | | ...                                                | ${dut1_to_dut2}
  68 | | ...                                                | ${bd_id1}
  69 | | And Bridge domain on DUT node is created | ${dut2_node} | ${bd_id2}
  70 | | ...                                      | learn=${FALSE}
  71 | | And Interface is added to bridge domain | ${dut2_node} | ${dut2_to_tg}
  72 | | ...                                     | ${bd_id2}
  73 | | And Interface is added to bridge domain | ${dut2_node} | ${dut2_to_dut1}
  74 | | ...                                     | ${bd_id2}
  75 | | And Destination port is added to L2FIB on DUT node | ${tg_node}
  76 | | ...                                                | ${tg_to_dut1}
  77 | | ...                                                | ${dut2_node}
  78 | | ...                                                | ${dut2_to_dut1}
  79 | | ...                                                | ${bd_id2}
  80 | | And Destination port is added to L2FIB on DUT node | ${tg_node}
  81 | | ...                                                | ${tg_to_dut2}
  82 | | ...                                                | ${dut2_node}
  83 | | ...                                                | ${dut2_to_tg}
  84 | | ...                                                | ${bd_id2}
  85 | | Then Send and receive ICMPv4 bidirectionally | ${tg_node} | ${tg_to_dut1}
  86 | | ...                                          | ${tg_to_dut2}