tests/func/lisp/eth2p-ethip4lispgpe-ip6base-eth-2vhost-1vm-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/default.robot
  16 | Resource | resources/libraries/robot/testing_path.robot
  17 | Resource | resources/libraries/robot/ipv4.robot
  18 | Resource | resources/libraries/robot/traffic.robot
  19 | Resource | resources/libraries/robot/lisp/lisp_static_adjacency.robot
  20 | Resource | resources/libraries/robot/l2_traffic.robot
  21 | Resource | resources/libraries/robot/lisp/lispgpe.robot
  22 | Resource | resources/libraries/robot/bridge_domain.robot
  23 | Resource | resources/libraries/robot/qemu.robot
  24 | Library  | resources.libraries.python.IPUtil
  25 | Library | resources.libraries.python.VhostUser
  26 | Library  | resources.libraries.python.Trace
  27 | Library  | resources.libraries.python.VPPUtil
  28 # import additional Lisp settings from resource file
  29 | Variables | resources/test_data/lisp/static_adjacency/lisp_static_adjacency.py
  30 | ...
  31 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | 3_NODE_DOUBLE_LINK_TOPO
  32 | ... | VM_ENV | HW_ENV
  33 | ...
  34 | Test Setup | Set up functional test
  35 | ...
  36 | Test Teardown | Tear down LISP functional test with QEMU | ${vm_node}
  37 | ...
  38 | Documentation | *LISP static adjacency test cases*
  39 | ...
  40 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  41 | ... | with single links between nodes.
  42 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-LISP-IPv6-ICMPv6 on DUT1-DUT2,\
  43 | ... | Eth-IPv6-ICMPv6 on TG-DUTn for IPv6 routing over LISPoIPv4 tunnel.
  44 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
  45 | ... | routing and static routes. LISPoIPv4 tunnel is configured\
  46 | ... | between DUT1 and DUT2.
  47 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets\
  48 | ... | are sent in both directions by TG on links to DUT1 and DUT2; on receive\
  49 | ... | TG verifies packets for correctness and their IPv6 src-addr,\
  50 | ... | dst-addr and MAC addresses.
  51 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  52
  53 *** Test Cases ***
  54 | TC01: DUT1 and DUT2 route IPv6 bidirectionally over LISP GPE tunnel using vhost interfaces
  55 | | [Documentation]
  56 | | ... | [Top] TG-DUT1-DUT2-TG.
  57 | | ... | [Enc] Eth-IPv4-LISPGPE-IPv6-ICMPv6 on DUT1-DUT2, Eth-IPv6-ICMPv6 on\
  58 | | ... | TG-DUTn.
  59 | | ... | [Cfg] Configure IPv4 LISP static adjacencies on DUT1 and DUT2.
  60 | | ... | [Ver] Case: ip6-lispgpe-ip4 - main fib, virt2lisp
  61 | | ... | Make TG send ICMPv6 Echo Req between its interfaces across both\
  62 | | ... | DUTs and LISP GPE tunnel between them; verify IPv6 headers on\
  63 | | ... | received packets are correct.
  64 | | ...
  65 | | Given Configure path in 3-node circular topology
  66 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  67 | | And Set interfaces in 3-node circular topology up
  68 | | And Configure IP addresses on interfaces
  69 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip6o4}
  70 | | ... | ${dut_prefix6o4}
  71 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip6o4} | ${tg_prefix6o4}
  72 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip6o4}
  73 | | ... | ${dut_prefix6o4}
  74 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip6o4} | ${tg_prefix6o4}
  75 | | And Add Arp On Dut | ${dut1_node} | ${dut1_to_tg} | ${tg1_ip6o4}
  76 | | ... | ${tg_to_dut1_mac}
  77 | | And Add Arp On Dut | ${dut2_node} | ${dut2_to_tg} | ${tg2_ip6o4}
  78 | | ... | ${tg_to_dut2_mac}
  79 | | And Add Arp On Dut | ${dut1_node} | ${dut1_to_dut2} | ${dut2_to_dut1_ip6o4}
  80 | | ... | ${dut2_to_dut1_mac}
  81 | | And Add Arp On Dut | ${dut2_node} | ${dut2_to_dut1} | ${dut1_to_dut2_ip6o4}
  82 | | ... | ${dut1_to_dut2_mac}
  83 | | And Vpp All RA Suppress Link Layer | ${nodes}
  84 | | When Configure LISP GPE topology in 3-node circular topology
  85 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
  86 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
  87 | | ... | ${duts_locator_set} | ${dut1_ip6o4_eid} | ${dut2_ip6o4_eid}
  88 | | ... | ${dut1_ip6o4_static_adjacency}
  89 | | ... | ${dut2_ip6o4_static_adjacency}
  90 | | And Setup Qemu DUT1
  91 | | Then Send packet and verify headers
  92 | | ... | ${tg_node} | ${tg1_ip6o4} | ${tg2_ip6o4}
  93 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dst_vhost_mac}
  94 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
  95 | | And Send packet and verify headers
  96 | | ... | ${tg_node} | ${tg2_ip6o4} | ${tg1_ip6o4}
  97 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
  98 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
  99
 100 *** Keywords ***
 101 | Setup Qemu DUT1
 102 | | [Documentation] | Setup Vhosts on DUT1 and setup IP on one of them. Setup\
 103 | | ... | Qemu and bridge the vhosts.
 104 | | ...
 105 | | ${vhost1}= | Vpp Create Vhost User Interface | ${dut1_node} | ${sock1}
 106 | | ${vhost2}= | Vpp Create Vhost User Interface | ${dut1_node} | ${sock2}
 107 | | Set Interface Address | ${dut1_node} | ${vhost2} | ${vhost_ip} | ${prefix4}
 108 | | Set Interface State | ${dut1_node} | ${vhost1} | up
 109 | | Set Interface State | ${dut1_node} | ${vhost2} | up
 110 | | Create bridge domain | ${dut1_node} | ${bid} | learn=${TRUE}
 111 | | Add interface to bridge domain | ${dut1_node}
 112 | | ... | ${dut1_to_tg} | ${bid} | 0
 113 | | Add interface to bridge domain | ${dut1_node}
 114 | | ... | ${vhost1} | ${bid} | 0
 115 | | ${vhost_mac}= | Get Vhost User Mac By SW Index | ${dut1_node} | ${vhost2}
 116 | | Set test variable | ${dst_vhost_mac} | ${vhost_mac}
 117 | | Configure VM for vhost L2BD forwarding | ${dut1_node} | ${sock1} | ${sock2}