tests/func/lisp/eth2p-ethip6lispgpe-ip6basevrf-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.topology.Topology
  16 | Library | resources.libraries.python.NodePath
  17 | Library | resources.libraries.python.Trace
  18 | Library | resources.libraries.python.IPUtil
  19 | Library | resources.libraries.python.IPv6Setup
  20 | Library | resources.libraries.python.VPPUtil
  21 | Resource | resources/libraries/robot/traffic.robot
  22 | Resource | resources/libraries/robot/default.robot
  23 | Resource | resources/libraries/robot/interfaces.robot
  24 | Resource | resources/libraries/robot/testing_path.robot
  25 | Resource | resources/libraries/robot/qemu.robot
  26 | Resource | resources/libraries/robot/bridge_domain.robot
  27 | Resource | resources/libraries/robot/vrf.robot
  28 | Resource | resources/libraries/robot/lisp/lispgpe.robot
  29 # Import configuration and test data:
  30 | Variables | resources/test_data/lisp/ipv6_lispgpe_ipv6/ipv6_lispgpe_ipv6.py
  31 | ...
  32 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | LISP
  33 | ...
  34 | Test Setup | Run Keywords | Set up functional test
  35 | ... | AND | Vpp All Ra Suppress Link Layer | ${nodes}
  36 | Test Teardown | Run Keywords | Show Packet Trace on All DUTs | ${nodes}
  37 | ... | AND | Show VAT History On All DUTs | ${nodes}
  38 | ... | AND | Show Vpp Settings | ${nodes['DUT1']}
  39 | ... | AND | Show Vpp Settings | ${nodes['DUT2']}
  40 | ... | AND | Verify VPP PID in Teardown
  41 | ...
  42 | Documentation | *ip6-lispgpe-ip6 encapsulation test cases*
  43 | ...
  44 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  45 | ... | with single links between nodes.
  46 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISP-IPv6-ICMPv6 on DUT1-DUT2,\
  47 | ... | Eth-IPv6-ICMPv6 on TG-DUTn for IPv6 routing over LISPoIPv6 tunnel.
  48 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
  49 | ... | routing and static routes. LISPoIPv6 tunnel is configured between\
  50 | ... | DUT1 and DUT2.
  51 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets are sent in\
  52 | ... | both directions by TG on links to DUT1 and DUT2; on receive\
  53 | ... | TG verifies packets for correctness and their IPv6 src-addr, dst-addr\
  54 | ... | and MAC addresses.
  55 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  56
  57 *** Test Cases ***
  58 | TC01: DUT1 and DUT2 route IPv6 bidirectionally over LISP GPE tunnel using physical interfaces and VRF is enabled
  59 | | [Documentation]
  60 | | ... | [Top] TG-DUT1-DUT2-TG.
  61 | | ... | [Enc] Eth-IPv6-LISPGPE-IPv6-ICMPv6 on DUT1-DUT2, Eth-IPv6-ICMPv6 on\
  62 | | ... | TG-DUTn.
  63 | | ... | [Cfg] Configure IPv6 LISP static adjacencies on DUT1 and DUT2.
  64 | | ... | [Ver] Case: ip6-lispgpe-ip6 - vrf, phy2lisp
  65 | | ... | Make TG send ICMPv6 Echo Req between its interfaces across both\
  66 | | ... | DUTs and LISP GPE tunnel between them; verify IPv6 headers on\
  67 | | ... | received packets are correct.
  68 | | ... | [Ref] RFC6830.
  69 | | ...
  70 | | Given Configure path in 3-node circular topology
  71 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  72 | | And Set interfaces in 3-node circular topology up
  73 | | And Assign Interface To Fib Table | ${dut1_node}
  74 | | ... | ${dut1_to_tg} | ${fib_table_1} | ipv6=${TRUE}
  75 | | And Assign Interface To Fib Table | ${dut2_node}
  76 | | ... | ${dut2_to_tg} | ${fib_table_1} | ipv6=${TRUE}
  77 | | And Vpp Set If IPv6 Addr
  78 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip6} | ${prefix6}
  79 | | And Vpp Set If IPv6 Addr
  80 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip6} | ${prefix6}
  81 | | And Vpp Set If IPv6 Addr
  82 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip6} | ${prefix6}
  83 | | And Vpp Set If IPv6 Addr
  84 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip6} | ${prefix6}
  85 | | And Add IP Neighbors
  86 | | And Vpp All RA Suppress Link Layer | ${nodes}
  87 | | When Configure LISP GPE topology in 3-node circular topology
  88 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
  89 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
  90 | | ... | ${duts_locator_set} | ${dut1_ip6_eid} | ${dut2_ip6_eid}
  91 | | ... | ${dut1_to_dut2_ip6_static_adjacency}
  92 | | ... | ${dut2_to_dut1_ip6_static_adjacency}
  93 | | ... | ${dut1_dut2_vni} | ${fib_table_1}
  94 | | Then Send packet and verify headers
  95 | | ... | ${tg_node} | ${tg1_ip6} | ${tg2_ip6}
  96 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
  97 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
  98 | | And Send packet and verify headers
  99 | | ... | ${tg_node} | ${tg2_ip6} | ${tg1_ip6}
 100 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 101 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
 102
 103 *** Keywords ***
 104 | Add IP Neighbors
 105 | | [Documentation]
 106 | | ... | Add IP neighbors to physical interfaces on DUTs.
 107 | | ...
 108 | | Add IP Neighbor | ${dut1_node} | ${dut1_to_tg} | ${tg1_ip6}
 109 | | ... | ${tg_to_dut1_mac}
 110 | | Add IP Neighbor | ${dut2_node} | ${dut2_to_tg} | ${tg2_ip6}
 111 | | ... | ${tg_to_dut2_mac}
 112 | | Add IP Neighbor | ${dut1_node} | ${dut1_to_dut2} | ${dut2_to_dut1_ip6}
 113 | | ... | ${dut2_to_dut1_mac}
 114 | | Add IP Neighbor | ${dut2_node} | ${dut2_to_dut1} | ${dut1_to_dut2_ip6}
 115 | | ... | ${dut1_to_dut2_mac}