tests/func/lisp/ipv4_lispgpe_ipv4.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.topology.Topology
  16 | Library | resources.libraries.python.NodePath
  17 | Library | resources.libraries.python.Trace
  18 | Library | resources.libraries.python.IPUtil
  19 | Library | resources.libraries.python.InterfaceUtil
  20 | Library | resources.libraries.python.VhostUser
  21 | Resource | resources/libraries/robot/traffic.robot
  22 | Resource | resources/libraries/robot/default.robot
  23 | Resource | resources/libraries/robot/interfaces.robot
  24 | Resource | resources/libraries/robot/testing_path.robot
  25 | Resource | resources/libraries/robot/ipv4.robot
  26 | Resource | resources/libraries/robot/vrf.robot
  27 | Resource | resources/libraries/robot/qemu.robot
  28 | Resource | resources/libraries/robot/bridge_domain.robot
  29 | Resource | resources/libraries/robot/lisp/lispgpe.robot
  30 # Import configuration and test data:
  31 | Variables | resources/test_data/lisp/ipv4_lispgpe_ipv4/ipv4_lispgpe_ipv4.py
  32 | ...
  33 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | LISP
  34 | ...
  35 | Test Setup | Run Keywords | Setup all DUTs before test
  36 | ...        | AND          | Setup all TGs before traffic script
  37 | ...        | AND          | Update All Interface Data On All Nodes | ${nodes}
  38 | Test Teardown | Run Keywords | Show Packet Trace on All DUTs | ${nodes}
  39 | ...           | AND          | Show vpp trace dump on all DUTs
  40 | ...           | AND          | VPP Show Errors | ${nodes['DUT1']}
  41 | ...           | AND          | VPP Show Errors | ${nodes['DUT2']}
  42 | ...
  43 | Documentation | *ip4-lispgpe-ip4 encapsulation test cases*
  44 | ...
  45 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  46 | ... | with single links between nodes.
  47 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-LISP-IPv4-ICMPv4 on DUT1-DUT2,\
  48 | ... | Eth-IPv4-ICMPv4 on TG-DUTn for IPv4 routing over LISPoIPv4 tunnel.
  49 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4\
  50 | ... | routing and static routes. LISPoIPv4 tunnel is configured between\
  51 | ... | DUT1 and DUT2.
  52 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent in\
  53 | ... | both directions by TG on links to DUT1 and DUT2; on receive\
  54 | ... | TG verifies packets for correctness and their IPv4 src-addr, dst-addr\
  55 | ... | and MAC addresses.
  56 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  57
  58 *** Test Cases ***
  59 | TC01: DUT1 and DUT2 route IPv4 bidirectionally over LISP GPE tunnel using physical interfaces
  60 | | [Documentation]
  61 | | ... | [Top] TG-DUT1-DUT2-TG.
  62 | | ... | [Enc] Eth-IPv4-LISPGPE-IPv4-ICMPv4 on DUT1-DUT2, Eth-IPv4-ICMPv4 on\
  63 | | ... | TG-DUTn.
  64 | | ... | [Cfg] Configure IPv4 LISP static adjacencies on DUT1 and DUT2.
  65 | | ... | [Ver] Case: ip4-lispgpe-ip4 - phy2lisp
  66 | | ... | Make TG send ICMPv4 Echo Req between its interfaces across both\
  67 | | ... | DUTs and LISP GPE tunnel between them; verify IPv4 headers on\
  68 | | ... | received packets are correct.
  69 | | ... | [Ref] RFC6830.
  70 | | ...
  71 | | Given Path for 3-node testing is set
  72 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  73 | | And Interfaces in 3-node path are up
  74 | | And IP addresses are set on interfaces
  75 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip4} | ${prefix4}
  76 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip4} | ${prefix4}
  77 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip4} | ${prefix4}
  78 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip4} | ${prefix4}
  79 | | And VPP IP Probe | ${dut1_node} | ${dut1_to_dut2} | ${dut2_to_dut1_ip4}
  80 | | And VPP IP Probe | ${dut2_node} | ${dut2_to_dut1} | ${dut1_to_dut2_ip4}
  81 | | And Add Arp On Dut | ${dut2_node} | ${dut2_to_tg} | ${tg2_ip4}
  82 | | ... | ${tg_to_dut2_mac}
  83 | | And Add Arp On Dut | ${dut1_node} | ${dut1_to_tg} | ${tg1_ip4}
  84 | | ... | ${tg_to_dut1_mac}
  85 | | When Set up LISP GPE topology
  86 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
  87 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
  88 | | ... | ${duts_locator_set} | ${dut1_ip4_eid} | ${dut2_ip4_eid}
  89 | | ... | ${dut1_to_dut2_ip4_static_adjacency}
  90 | | ... | ${dut2_to_dut1_ip4_static_adjacency}
  91 | | Then Send Packet And Check Headers
  92 | | ... | ${tg_node} | ${tg1_ip4} | ${tg2_ip4}
  93 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
  94 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
  95 | | And Send Packet And Check Headers
  96 | | ... | ${tg_node} | ${tg2_ip4} | ${tg1_ip4}
  97 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
  98 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
  99
 100 | TC02: DUT1 and DUT2 route IPv4 bidirectionally over LISP GPE tunnel using physical interfaces and VRF is enabled
 101 | | [Documentation]
 102 | | ... | [Top] TG-DUT1-DUT2-TG.
 103 | | ... | [Enc] Eth-IPv4-LISPGPE-IPv4-ICMPv4 on DUT1-DUT2, Eth-IPv4-ICMPv4 on\
 104 | | ... | TG-DUTn.
 105 | | ... | [Cfg] Configure IPv4 LISP static adjacencies on DUT1 and DUT2.
 106 | | ... | [Ver] Case: ip4-lispgpe-ip4 - vrf, phy2lisp
 107 | | ... | Make TG send ICMPv4 Echo Req between its interfaces across both\
 108 | | ... | DUTs and LISP GPE tunnel between them; verify IPv4 headers on\
 109 | | ... | received packets are correct.
 110 | | ... | [Ref] RFC6830.
 111 | | ...
 112 | | [Teardown] | Run Keywords | Show Packet Trace on All DUTs | ${nodes}
 113 | | ... | AND | Show vpp trace dump on all DUTs
 114 | | ... | AND | VPP Show Errors | ${nodes['DUT1']}
 115 | | ... | AND | VPP Show Errors | ${nodes['DUT2']}
 116 | | ... | AND | Run keyword if test passed | Fail
 117 | | ...
 118 | | [Tags] | EXPECTED_FAILING
 119 | | ...
 120 | | Given Path for 3-node testing is set
 121 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
 122 | | And Interfaces in 3-node path are up
 123 | | And Set up LISP GPE topology
 124 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
 125 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
 126 | | ... | ${duts_locator_set} | ${dut1_ip4_eid} | ${dut2_ip4_eid}
 127 | | ... | ${dut1_to_dut2_ip4_static_adjacency}
 128 | | ... | ${dut2_to_dut1_ip4_static_adjacency}
 129 | | And IP addresses are set on interfaces
 130 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip4} | ${prefix4}
 131 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip4} | ${prefix4}
 132 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip4} | ${prefix4}
 133 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip4} | ${prefix4}
 134 | | When Setup VRF on DUT | ${dut1_node} | ${dut1_fib_table} | ${dut1_to_dut2}
 135 | | ... | ${dut2_to_dut1_ip4} | ${dut2_to_dut1_mac} | ${tg2_ip4} | ${dut1_to_tg}
 136 | | ... | ${tg1_ip4} | ${tg_to_dut1_mac} | ${prefix4}
 137 | | And Setup VRF on DUT | ${dut2_node} | ${dut2_fib_table} | ${dut2_to_dut1}
 138 | | ... | ${dut1_to_dut2_ip4} | ${dut1_to_dut2_mac} | ${tg1_ip4} | ${dut2_to_tg}
 139 | | ... | ${tg2_ip4} | ${tg_to_dut2_mac} | ${prefix4}
 140 | | Then Send Packet And Check Headers
 141 | | ... | ${tg_node} | ${tg1_ip4} | ${tg2_ip4}
 142 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
 143 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
 144 | | And Send Packet And Check Headers
 145 | | ... | ${tg_node} | ${tg2_ip4} | ${tg1_ip4}
 146 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 147 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
 148
 149 | TC03: DUT1 and DUT2 route IPv4 bidirectionally over LISP GPE tunnel using vhost interfaces
 150 | | [Documentation]
 151 | | ... | [Top] TG-DUT1-DUT2-TG.
 152 | | ... | [Enc] Eth-IPv4-LISPGPE-IPv4-ICMPv4 on DUT1-DUT2, Eth-IPv4-ICMPv4 on\
 153 | | ... | TG-DUTn.
 154 | | ... | [Cfg] Configure IPv4 LISP static adjacencies on DUT1 and DUT2.
 155 | | ... | [Ver] Case: ip4-lispgpe-ip4 - main fib, virt2lisp
 156 | | ... | Make TG send ICMPv4 Echo Req between its interfaces across both\
 157 | | ... | DUTs and LISP GPE tunnel between them; verify IPv4 headers on\
 158 | | ... | received packets are correct.
 159 | | ...
 160 | | [Teardown] | Run Keywords | Show Packet Trace on All DUTs | ${nodes}
 161 | | ... | AND | Show vpp trace dump on all DUTs
 162 | | ... | AND | VPP Show Errors | ${nodes['DUT1']}
 163 | | ... | AND | VPP Show Errors | ${nodes['DUT2']}
 164 | | ... | AND | Stop and Clear QEMU | ${dut1_node} | ${vm_node}
 165 | | ...
 166 | | [Tags] | EXPECTED_FAILING
 167 | | ...
 168 | | Given Path for 3-node testing is set
 169 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
 170 | | And Interfaces in 3-node path are up
 171 | | And IP addresses are set on interfaces
 172 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip4} | ${prefix4}
 173 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip4} | ${prefix4}
 174 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip4} | ${prefix4}
 175 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip4} | ${prefix4}
 176 | | And Add Arp On Dut | ${dut1_node} | ${dut1_to_tg} | ${tg1_ip4}
 177 | | ... | ${tg_to_dut1_mac}
 178 | | And Add Arp On Dut | ${dut2_node} | ${dut2_to_tg} | ${tg2_ip4}
 179 | | ... | ${tg_to_dut2_mac}
 180 | | And Add Arp On Dut | ${dut1_node} | ${dut1_to_dut2} | ${dut2_to_dut1_ip4}
 181 | | ... | ${dut2_to_dut1_mac}
 182 | | And Add Arp On Dut | ${dut2_node} | ${dut2_to_dut1} | ${dut1_to_dut2_ip4}
 183 | | ... | ${dut1_to_dut2_mac}
 184 | | When Set up LISP GPE topology
 185 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
 186 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
 187 | | ... | ${duts_locator_set} | ${dut1_ip4_eid} | ${dut2_ip4_eid}
 188 | | ... | ${dut1_to_dut2_ip4_static_adjacency}
 189 | | ... | ${dut2_to_dut1_ip4_static_adjacency}
 190 | | And Setup Qemu DUT1
 191 | | Then Send Packet And Check Headers
 192 | | ... | ${tg_node} | ${tg1_ip4} | ${tg2_ip4}
 193 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dst_vhost_mac}
 194 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
 195 | | And Send Packet And Check Headers
 196 | | ... | ${tg_node} | ${tg2_ip4} | ${tg1_ip4}
 197 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 198 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
 199
 200 | TC04: DUT1 and DUT2 route IPv4 bidirectionally over LISP GPE tunnel using vhost interfaces and VRF is enabled
 201 | | [Documentation]
 202 | | ... | [Top] TG-DUT1-DUT2-TG.
 203 | | ... | [Enc] Eth-IPv4-LISPGPE-IPv4-ICMPv4 on DUT1-DUT2, Eth-IPv4-ICMPv4 on\
 204 | | ... | TG-DUTn.
 205 | | ... | [Cfg] Configure IPv4 LISP static adjacencies on DUT1 and DUT2.
 206 | | ... | [Ver] Case: ip4-lispgpe-ip4 - vrf, virt2lisp
 207 | | ... | Make TG send ICMPv4 Echo Req between its interfaces across both\
 208 | | ... | DUTs and LISP GPE tunnel between them; verify IPv4 headers on\
 209 | | ... | received packets are correct.
 210 | | ... | [Ref] RFC6830.
 211 | | ...
 212 | | [Teardown] | Run Keywords | Show Packet Trace on All DUTs | ${nodes}
 213 | | ... | AND | Show vpp trace dump on all DUTs
 214 | | ... | AND | VPP Show Errors | ${nodes['DUT1']}
 215 | | ... | AND | VPP Show Errors | ${nodes['DUT2']}
 216 | | ... | AND | Stop and Clear QEMU | ${dut1_node} | ${vm_node}
 217 | | ...
 218 | | [Tags] | EXPECTED_FAILING
 219 | | ...
 220 | | Given Path for 3-node testing is set
 221 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
 222 | | And Interfaces in 3-node path are up
 223 | | When Setup VRF on DUT | ${dut1_node} | ${dut1_fib_table} | ${dut1_to_dut2}
 224 | | ... | ${dut2_to_dut1_ip4} | ${dut2_to_dut1_mac} | ${tg2_ip4} | ${dut1_to_tg}
 225 | | ... | ${tg1_ip4} | ${tg_to_dut1_mac} | ${prefix4}
 226 | | And Setup VRF on DUT | ${dut2_node} | ${dut2_fib_table} | ${dut2_to_dut1}
 227 | | ... | ${dut1_to_dut2_ip4} | ${dut1_to_dut2_mac} | ${tg1_ip4} | ${dut2_to_tg}
 228 | | ... | ${tg2_ip4} | ${tg_to_dut2_mac} | ${prefix4}
 229 | | And IP addresses are set on interfaces
 230 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip4} | ${prefix4}
 231 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip4} | ${prefix4}
 232 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip4} | ${prefix4}
 233 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip4} | ${prefix4}
 234 | | And Set up LISP GPE topology
 235 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
 236 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
 237 | | ... | ${duts_locator_set} | ${dut1_ip4_eid} | ${dut2_ip4_eid}
 238 | | ... | ${dut1_to_dut2_ip4_static_adjacency}
 239 | | ... | ${dut2_to_dut1_ip4_static_adjacency}
 240 | | And Setup Qemu DUT1
 241 | | Then Send Packet And Check Headers
 242 | | ... | ${tg_node} | ${tg1_ip4} | ${tg2_ip4}
 243 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dst_vhost_mac}
 244 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
 245 | | And Send Packet And Check Headers
 246 | | ... | ${tg_node} | ${tg2_ip4} | ${tg1_ip4}
 247 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 248 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
 249
 250 *** Keywords ***
 251 | Setup Qemu DUT1
 252 | | [Documentation] | Setup Vhosts on DUT1 and setup IP on one of them. Setup\
 253 | | ... | Qemu and bridge the vhosts.
 254 | | ...
 255 | | ${vhost1}= | Vpp Create Vhost User Interface | ${dut1_node} | ${sock1}
 256 | | ${vhost2}= | Vpp Create Vhost User Interface | ${dut1_node} | ${sock2}
 257 | | Set Interface State | ${dut1_node} | ${vhost1} | up
 258 | | Set Interface State | ${dut1_node} | ${vhost2} | up
 259 | | Bridge domain on DUT node is created | ${dut1_node} | ${bid} | learn=${TRUE}
 260 | | Interface is added to bridge domain | ${dut1_node}
 261 | | ... | ${dut1_to_tg} | ${bid} | 0
 262 | | Interface is added to bridge domain | ${dut1_node}
 263 | | ... | ${vhost1} | ${bid} | 0
 264 | | ${vhost_mac}= | Get Vhost User Mac By SW Index | ${dut1_node} | ${vhost2}
 265 | | Set test variable | ${dst_vhost_mac} | ${vhost_mac}
 266 | | VM for Vhost L2BD forwarding is setup | ${dut1_node} | ${sock1} | ${sock2}