tests/func/lisp/ipv6_lispgpe_ipv4.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/default.robot
  16 | Resource | resources/libraries/robot/testing_path.robot
  17 | Resource | resources/libraries/robot/ipv4.robot
  18 | Resource | resources/libraries/robot/traffic.robot
  19 | Resource | resources/libraries/robot/lisp/lisp_static_adjacency.robot
  20 | Resource | resources/libraries/robot/l2_traffic.robot
  21 | Library  | resources.libraries.python.IPUtil
  22 | Library  | resources.libraries.python.Trace
  23 # import additional Lisp settings from resource file
  24 | Variables | resources/test_data/lisp/static_adjacency/lisp_static_adjacency.py
  25 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | 3_NODE_DOUBLE_LINK_TOPO
  26 | ... | VM_ENV | HW_ENV
  27 | Test Setup | Func Test Setup
  28 | Test Teardown | Func Test Teardown
  29 | Documentation | *LISP static adjacency test cases*
  30 | ...
  31 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  32 | ... | with single links between nodes.
  33 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISP-IPv4-ICMPv4 on\
  34 | ... | DUT1-DUT2, Eth-IPv4-ICMPv4 on TG-DUTn for IPv4 routing over LISPoIPv6\
  35 | ... | tunnel.
  36 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4\
  37 | ... | routing and static routes. LISPoIPv6 tunnel is configured\
  38 | ... | between DUT1 and DUT2.
  39 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets\
  40 | ... | are sent in both directions by TG on links to DUT1 and DUT2; on receive\
  41 | ... | TG verifies packets for correctness and their IPv4 src-addr,\
  42 | ... | dst-addr and MAC addresses.
  43 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  44
  45 *** Test Cases ***
  46 | TC01: DUT1 and DUT2 route IPv4 bidirectionally over LISPoIPv6 tunnel
  47 | | [Documentation]
  48 | | ... | [Top] TG-DUT1-DUT2-TG.
  49 | | ... | [Enc] Eth-IPv6-LISP-IPv4-ICMPv4 on DUT1-DUT2, Eth-IPv4-ICMPv4 on\
  50 | | ... | TG-DUTn.
  51 | | ... | [Cfg] On DUT1 and DUT2 configure IPv6 LISP static adjacencies.
  52 | | ... | [Ver] Make TG send ICMPv4 Echo Req between its interfaces across both\
  53 | | ... | DUTs and LISP tunnel between them; verify IPv4 headers on received\
  54 | | ... | packets are correct.
  55 | | ... | [Cfg2] Reconf LISP.
  56 | | ... | [Ver2] Verify packets are received again via LISP tunnel.
  57 | | ... | [Ref] RFC6830.
  58 | | Given Path for 3-node testing is set
  59 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  60 | | And   Interfaces in 3-node path are up
  61 | | And   IP addresses are set on interfaces
  62 | |       ... | ${dut1_node} | ${dut1_to_dut2}
  63 | |       ... | ${dut1_to_dut2_ip4o6} | ${dut_prefix4o6}
  64 | |       ... | ${dut1_node} | ${dut1_to_tg}
  65 | |       ... | ${dut1_to_tg_ip4o6} | ${tg_prefix4o6}
  66 | |       ... | ${dut2_node} | ${dut2_to_dut1}
  67 | |       ... | ${dut2_to_dut1_ip4o6} | ${dut_prefix4o6}
  68 | |       ... | ${dut2_node} | ${dut2_to_tg}
  69 | |       ... | ${dut2_to_tg_ip4o6} | ${tg_prefix4o6}
  70 | | And   VPP IP Probe | ${dut1_node} | ${dut1_to_dut2} | ${dut2_to_dut1_ip4o6}
  71 | | And   VPP IP Probe | ${dut2_node} | ${dut2_to_dut1} | ${dut1_to_dut2_ip4o6}
  72 | | And   Add Arp On Dut | ${dut2_node} | ${dut2_to_tg} | ${tg2_ip4o6}
  73 | |       ... | ${tg_to_dut2_mac}
  74 | | And   Add Arp On Dut | ${dut1_node} | ${dut1_to_tg} | ${tg1_ip4o6}
  75 | |       ... | ${tg_to_dut1_mac}
  76 | | When Set up Lisp topology
  77 | |      ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
  78 | |      ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
  79 | |      ... | ${duts_locator_set} | ${dut1_ip4o6_eid} | ${dut2_ip4o6_eid}
  80 | |      ... | ${dut1_ip4o6_static_adjacency} | ${dut2_ip4o6_static_adjacency}
  81 | | Then Send Packet And Check Headers
  82 | |      ... | ${tg_node} | ${tg1_ip4o6} | ${tg2_ip4o6}
  83 | |      ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
  84 | |      ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
  85 | | And Send Packet And Check Headers
  86 | |      ... | ${tg_node} | ${tg2_ip4o6} | ${tg1_ip4o6}
  87 | |      ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
  88 | |      ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
  89 | | When Change Lisp Configuration | ${dut1_node} | ${dut2_node}
  90 | |      ... | ${dut1_to_dut2} | ${dut2_to_dut1} | ${dut1_to_dut2_mac}
  91 | |      ... | ${dut2_to_dut1_mac} | ${dut1_to_dut2_ip4o6}
  92 | |      ... | ${dut2_to_dut1_ip4o6_reconf} | ${dut_prefix4o6}
  93 | |      ... | ${dut1_ip4o6_static_adjacency}
  94 | |      ... | ${dut1_ip4o6_static_adjacency_reconf}
  95 | | Then Send Packet And Check Headers
  96 | |      ... | ${tg_node} | ${tg1_ip4o6} | ${tg2_ip4o6}
  97 | |      ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
  98 | |      ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
  99 | | And Send Packet And Check Headers
 100 | |      ... | ${tg_node} | ${tg2_ip4o6} | ${tg1_ip4o6}
 101 | |      ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 102 | |      ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}