tests/func/lisp/ipv6_lispgpe_ipv4.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/default.robot
  16 | Resource | resources/libraries/robot/testing_path.robot
  17 | Resource | resources/libraries/robot/ipv4.robot
  18 | Resource | resources/libraries/robot/traffic.robot
  19 | Resource | resources/libraries/robot/lisp/lisp_static_adjacency.robot
  20 | Resource | resources/libraries/robot/l2_traffic.robot
  21 | Library  | resources.libraries.python.IPUtil
  22 | Library  | resources.libraries.python.Trace
  23 # import additional Lisp settings from resource file
  24 | Variables | resources/test_data/lisp/static_adjacency/lisp_static_adjacency.py
  25 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | 3_NODE_DOUBLE_LINK_TOPO
  26 | ... | VM_ENV | HW_ENV
  27 | Test Setup | Run Keywords | Setup all DUTs before test
  28 | ...        | AND          | Setup all TGs before traffic script
  29 | ...        | AND          | Update All Interface Data On All Nodes | ${nodes}
  30 | Test Teardown | Run Keywords | Show Packet Trace on All DUTs | ${nodes}
  31 | ...           | AND          | Show vpp trace dump on all DUTs
  32 | Documentation | *LISP static adjacency test cases*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  35 | ... | with single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISP-IPv4-ICMPv4 on\
  37 | ... | DUT1-DUT2, Eth-IPv4-ICMPv4 on TG-DUTn for IPv4 routing over LISPoIPv6\
  38 | ... | tunnel.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4\
  40 | ... | routing and static routes. LISPoIPv6 tunnel is configured\
  41 | ... | between DUT1 and DUT2.
  42 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets\
  43 | ... | are sent in both directions by TG on links to DUT1 and DUT2; on receive\
  44 | ... | TG verifies packets for correctness and their IPv4 src-addr,\
  45 | ... | dst-addr and MAC addresses.
  46 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  47
  48 *** Test Cases ***
  49 | TC01: DUT1 and DUT2 route IPv4 bidirectionally over LISPoIPv6 tunnel
  50 | | [Documentation]
  51 | | ... | [Top] TG-DUT1-DUT2-TG.
  52 | | ... | [Enc] Eth-IPv6-LISP-IPv4-ICMPv4 on DUT1-DUT2, Eth-IPv4-ICMPv4 on\
  53 | | ... | TG-DUTn.
  54 | | ... | [Cfg] On DUT1 and DUT2 configure IPv6 LISP static adjacencies.
  55 | | ... | [Ver] Make TG send ICMPv4 Echo Req between its interfaces across both\
  56 | | ... | DUTs and LISP tunnel between them; verify IPv4 headers on received\
  57 | | ... | packets are correct.
  58 | | ... | [Cfg2] Reconf LISP.
  59 | | ... | [Ver2] Verify packets are received again via LISP tunnel.
  60 | | ... | [Ref] RFC6830.
  61 | | Given Path for 3-node testing is set
  62 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  63 | | And   Interfaces in 3-node path are up
  64 | | And   IP addresses are set on interfaces
  65 | |       ... | ${dut1_node} | ${dut1_to_dut2}
  66 | |       ... | ${dut1_to_dut2_ip4o6} | ${dut_prefix4o6}
  67 | |       ... | ${dut1_node} | ${dut1_to_tg}
  68 | |       ... | ${dut1_to_tg_ip4o6} | ${tg_prefix4o6}
  69 | |       ... | ${dut2_node} | ${dut2_to_dut1}
  70 | |       ... | ${dut2_to_dut1_ip4o6} | ${dut_prefix4o6}
  71 | |       ... | ${dut2_node} | ${dut2_to_tg}
  72 | |       ... | ${dut2_to_tg_ip4o6} | ${tg_prefix4o6}
  73 | | And   VPP IP Probe | ${dut1_node} | ${dut1_to_dut2} | ${dut2_to_dut1_ip4o6}
  74 | | And   VPP IP Probe | ${dut2_node} | ${dut2_to_dut1} | ${dut1_to_dut2_ip4o6}
  75 | | And   Add Arp On Dut | ${dut2_node} | ${dut2_to_tg} | ${tg2_ip4o6}
  76 | |       ... | ${tg_to_dut2_mac}
  77 | | And   Add Arp On Dut | ${dut1_node} | ${dut1_to_tg} | ${tg1_ip4o6}
  78 | |       ... | ${tg_to_dut1_mac}
  79 | | When Set up Lisp topology
  80 | |      ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
  81 | |      ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
  82 | |      ... | ${duts_locator_set} | ${dut1_ip4o6_eid} | ${dut2_ip4o6_eid}
  83 | |      ... | ${dut1_ip4o6_static_adjacency} | ${dut2_ip4o6_static_adjacency}
  84 | | Then Send Packet And Check Headers
  85 | |      ... | ${tg_node} | ${tg1_ip4o6} | ${tg2_ip4o6}
  86 | |      ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
  87 | |      ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
  88 | | And Send Packet And Check Headers
  89 | |      ... | ${tg_node} | ${tg2_ip4o6} | ${tg1_ip4o6}
  90 | |      ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
  91 | |      ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
  92 | | When Change Lisp Configuration | ${dut1_node} | ${dut2_node}
  93 | |      ... | ${dut1_to_dut2} | ${dut2_to_dut1} | ${dut1_to_dut2_mac}
  94 | |      ... | ${dut2_to_dut1_mac} | ${dut1_to_dut2_ip4o6}
  95 | |      ... | ${dut2_to_dut1_ip4o6_reconf} | ${dut_prefix4o6}
  96 | |      ... | ${dut1_ip4o6_static_adjacency}
  97 | |      ... | ${dut1_ip4o6_static_adjacency_reconf}
  98 | | Then Send Packet And Check Headers
  99 | |      ... | ${tg_node} | ${tg1_ip4o6} | ${tg2_ip4o6}
 100 | |      ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
 101 | |      ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
 102 | | And Send Packet And Check Headers
 103 | |      ... | ${tg_node} | ${tg2_ip4o6} | ${tg1_ip4o6}
 104 | |      ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 105 | |      ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}