tests/func/lisp/lisp_ipv6_lispgpe_ipv6.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.topology.Topology
  16 | Library | resources.libraries.python.NodePath
  17 | Library | resources.libraries.python.Trace
  18 | Library | resources.libraries.python.IPUtil
  19 | Library | resources.libraries.python.IPv6Setup
  20 | Resource | resources/libraries/robot/traffic.robot
  21 | Resource | resources/libraries/robot/default.robot
  22 | Resource | resources/libraries/robot/interfaces.robot
  23 | Resource | resources/libraries/robot/testing_path.robot
  24 | Resource | resources/libraries/robot/qemu.robot
  25 | Resource | resources/libraries/robot/bridge_domain.robot
  26 | Resource | resources/libraries/robot/vrf.robot
  27 | Resource | resources/libraries/robot/lisp/lispgpe.robot
  28 # Import configuration and test data:
  29 | Variables | resources/test_data/lisp/ipv6_lispgpe_ipv6/ipv6_lispgpe_ipv6.py
  30 | ...
  31 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | LISP
  32 | ...
  33 | Test Setup | Run Keywords | Setup all DUTs before test
  34 | ...        | AND          | Setup all TGs before traffic script
  35 | ...        | AND          | Update All Interface Data On All Nodes | ${nodes}
  36 | Test Teardown | Run Keywords | Show Packet Trace on All DUTs | ${nodes}
  37 | ...           | AND          | Show vpp trace dump on all DUTs
  38 | ...           | AND          | VPP Show Errors | ${nodes['DUT1']}
  39 | ...           | AND          | VPP Show Errors | ${nodes['DUT2']}
  40 | ...
  41 | Documentation | *ip6-lispgpe-ip6 encapsulation test cases*
  42 | ...
  43 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  44 | ... | with single links between nodes.
  45 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISP-IPv6-ICMPv6 on DUT1-DUT2,\
  46 | ... | Eth-IPv6-ICMPv6 on TG-DUTn for IPv6 routing over LISPoIPv6 tunnel.
  47 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
  48 | ... | routing and static routes. LISPoIPv6 tunnel is configured between\
  49 | ... | DUT1 and DUT2.
  50 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets are sent in\
  51 | ... | both directions by TG on links to DUT1 and DUT2; on receive\
  52 | ... | TG verifies packets for correctness and their IPv6 src-addr, dst-addr\
  53 | ... | and MAC addresses.
  54 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  55
  56 *** Test Cases ***
  57 | TC01: DUT1 and DUT2 route IPv6 bidirectionally over LISP GPE tunnel using physical interfaces
  58 | | [Documentation]
  59 | | ... | [Top] TG-DUT1-DUT2-TG.
  60 | | ... | [Enc] Eth-IPv6-LISPGPE-IPv6-ICMPv6 on DUT1-DUT2, Eth-IPv6-ICMPv6 on\
  61 | | ... | TG-DUTn.
  62 | | ... | [Cfg] Configure IPv6 LISP static adjacencies on DUT1 and DUT2.
  63 | | ... | [Ver] Case: ip6-lispgpe-ip6 - phy2lisp
  64 | | ... | Make TG send ICMPv6 Echo Req between its interfaces across both\
  65 | | ... | DUTs and LISP GPE tunnel between them; verify IPv6 headers on\
  66 | | ... | received packets are correct.
  67 | | ... | [Ref] RFC6830.
  68 | | ...
  69 | | Given Path for 3-node testing is set
  70 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  71 | | And Interfaces in 3-node path are up
  72 | | And Vpp Set If IPv6 Addr
  73 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip6} | ${prefix6}
  74 | | And Vpp Set If IPv6 Addr
  75 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip6} | ${prefix6}
  76 | | And Vpp Set If IPv6 Addr
  77 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip6} | ${prefix6}
  78 | | And Vpp Set If IPv6 Addr
  79 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip6} | ${prefix6}
  80 | | Add IP Neighbor | ${dut1_node} | ${dut1_to_tg} | ${tg1_ip6}
  81 | | ... | ${tg_to_dut1_mac}
  82 | | Add IP Neighbor | ${dut2_node} | ${dut2_to_tg} | ${tg2_ip6}
  83 | | ... | ${tg_to_dut2_mac}
  84 | | Add IP Neighbor | ${dut1_node} | ${dut1_to_dut2} | ${dut2_to_dut1_ip6}
  85 | | ... | ${dut2_to_dut1_mac}
  86 | | Add IP Neighbor | ${dut2_node} | ${dut2_to_dut1} | ${dut1_to_dut2_ip6}
  87 | | ... | ${dut1_to_dut2_mac}
  88 | | When Set up LISP GPE topology
  89 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
  90 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
  91 | | ... | ${duts_locator_set} | ${dut1_ip6_eid} | ${dut2_ip6_eid}
  92 | | ... | ${dut1_to_dut2_ip6_static_adjacency}
  93 | | ... | ${dut2_to_dut1_ip6_static_adjacency}
  94 | | Then Send Packet And Check Headers
  95 | | ... | ${tg_node} | ${tg1_ip6} | ${tg2_ip6}
  96 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
  97 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
  98 | | And Send Packet And Check Headers
  99 | | ... | ${tg_node} | ${tg2_ip6} | ${tg1_ip6}
 100 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 101 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
 102
 103 | TC02: DUT1 and DUT2 route IPv6 bidirectionally over LISP GPE tunnel using physical interfaces and VRF is enabled
 104 | | [Documentation]
 105 | | ... | [Top] TG-DUT1-DUT2-TG.
 106 | | ... | [Enc] Eth-IPv6-LISPGPE-IPv6-ICMPv6 on DUT1-DUT2, Eth-IPv6-ICMPv6 on\
 107 | | ... | TG-DUTn.
 108 | | ... | [Cfg] Configure IPv6 LISP static adjacencies on DUT1 and DUT2.
 109 | | ... | [Ver] Case: ip6-lispgpe-ip6 - vrf, phy2lisp
 110 | | ... | Make TG send ICMPv6 Echo Req between its interfaces across both\
 111 | | ... | DUTs and LISP GPE tunnel between them; verify IPv6 headers on\
 112 | | ... | received packets are correct.
 113 | | ... | [Ref] RFC6830.
 114 | | ...
 115 | | Given Path for 3-node testing is set
 116 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
 117 | | And Interfaces in 3-node path are up
 118 | | When Setup VRF on DUT | ${dut1_node} | ${dut1_fib_table} | ${dut1_to_dut2}
 119 | | ... | ${dut2_to_dut1_ip6} | ${dut2_to_dut1_mac} | ${tg2_ip6} | ${dut1_to_tg}
 120 | | ... | ${tg1_ip6} | ${tg_to_dut1_mac} | ${prefix6}
 121 | | And Setup VRF on DUT | ${dut2_node} | ${dut2_fib_table} | ${dut2_to_dut1}
 122 | | ... | ${dut1_to_dut2_ip6} | ${dut1_to_dut2_mac} | ${tg1_ip6} | ${dut2_to_tg}
 123 | | ... | ${tg2_ip6} | ${tg_to_dut2_mac} | ${prefix6}
 124 | | And Vpp Set If IPv6 Addr
 125 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip6} | ${prefix6}
 126 | | And Vpp Set If IPv6 Addr
 127 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip6} | ${prefix6}
 128 | | And Vpp Set If IPv6 Addr
 129 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip6} | ${prefix6}
 130 | | And Vpp Set If IPv6 Addr
 131 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip6} | ${prefix6}
 132 | | And Set up LISP GPE topology
 133 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
 134 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
 135 | | ... | ${duts_locator_set} | ${dut1_ip6_eid} | ${dut2_ip6_eid}
 136 | | ... | ${dut1_to_dut2_ip6_static_adjacency}
 137 | | ... | ${dut2_to_dut1_ip6_static_adjacency}
 138 | | Then Send Packet And Check Headers
 139 | | ... | ${tg_node} | ${tg1_ip6} | ${tg2_ip6}
 140 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
 141 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
 142 | | And Send Packet And Check Headers
 143 | | ... | ${tg_node} | ${tg2_ip6} | ${tg1_ip6}
 144 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 145 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
 146
 147 | TC03: DUT1 and DUT2 route IPv6 bidirectionally over LISP GPE tunnel using vhost interfaces
 148 | | [Documentation]
 149 | | ... | [Top] TG-DUT1-DUT2-TG.
 150 | | ... | [Enc] Eth-IPv6-LISPGPE-IPv6-ICMPv6 on DUT1-DUT2, Eth-IPv6-ICMPv6 on\
 151 | | ... | TG-DUTn.
 152 | | ... | [Cfg] Configure IPv6 LISP static adjacencies on DUT1 and DUT2.
 153 | | ... | [Ver] Case: ip6-ipsec-lispgpe-ip6 - main fib, virt2lisp
 154 | | ... | Make TG send ICMPv6 Echo Req between its interfaces across both\
 155 | | ... | DUTs and LISP GPE tunnel between them; verify IPv6 headers on\
 156 | | ... | received packets are correct.
 157 | | ...
 158 | | [Teardown] | Run Keywords | Show Packet Trace on All DUTs | ${nodes}
 159 | | ... | AND | Show vpp trace dump on all DUTs
 160 | | ... | AND | VPP Show Errors | ${nodes['DUT1']}
 161 | | ... | AND | VPP Show Errors | ${nodes['DUT2']}
 162 | | ... | AND | Stop and Clear QEMU | ${dut1_node} | ${vm_node}
 163 | | ...
 164 | | [Tags] | EXPECTED_FAILING
 165 | | ...
 166 | | Given Path for 3-node testing is set
 167 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
 168 | | And Interfaces in 3-node path are up
 169 | | And Vpp Set If IPv6 Addr
 170 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip6} | ${prefix6}
 171 | | And Vpp Set If IPv6 Addr
 172 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip6} | ${prefix6}
 173 | | And Vpp Set If IPv6 Addr
 174 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip6} | ${prefix6}
 175 | | And Vpp Set If IPv6 Addr
 176 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip6} | ${prefix6}
 177 | | Add IP Neighbor | ${dut1_node} | ${dut1_to_tg} | ${tg1_ip6}
 178 | | ... | ${tg_to_dut1_mac}
 179 | | Add IP Neighbor | ${dut2_node} | ${dut2_to_tg} | ${tg2_ip6}
 180 | | ... | ${tg_to_dut2_mac}
 181 | | Add IP Neighbor | ${dut1_node} | ${dut1_to_dut2} | ${dut2_to_dut1_ip6}
 182 | | ... | ${dut2_to_dut1_mac}
 183 | | Add IP Neighbor | ${dut2_node} | ${dut2_to_dut1} | ${dut1_to_dut2_ip6}
 184 | | ... | ${dut1_to_dut2_mac}
 185 | | When Set up LISP GPE topology
 186 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
 187 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
 188 | | ... | ${duts_locator_set} | ${dut1_ip6_eid} | ${dut2_ip6_eid}
 189 | | ... | ${dut1_to_dut2_ip6_static_adjacency}
 190 | | ... | ${dut2_to_dut1_ip6_static_adjacency}
 191 | | And Setup Qemu DUT1
 192 | | Then Send Packet And Check Headers
 193 | | ... | ${tg_node} | ${tg1_ip6} | ${tg2_ip6}
 194 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dst_vhost_mac}
 195 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
 196 | | And Send Packet And Check Headers
 197 | | ... | ${tg_node} | ${tg2_ip6} | ${tg1_ip6}
 198 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 199 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
 200
 201 | TC04: DUT1 and DUT2 route IPv6 bidirectionally over LISP GPE tunnel using vhost interfaces and VRF is enabled
 202 | | [Documentation]
 203 | | ... | [Top] TG-DUT1-DUT2-TG.
 204 | | ... | [Enc] Eth-IPv6-LISPGPE-IPv6-ICMPv6 on DUT1-DUT2, Eth-IPv6-ICMPv6 on\
 205 | | ... | TG-DUTn.
 206 | | ... | [Cfg] Configure IPv6 LISP static adjacencies on DUT1 and DUT2.
 207 | | ... | [Ver] Case: ip6-lispgpe-ip6 - vrf, virt2lisp
 208 | | ... | Make TG send ICMPv6 Echo Req between its interfaces across both\
 209 | | ... | DUTs and LISP GPE tunnel between them; verify IPv6 headers on\
 210 | | ... | received packets are correct.
 211 | | ... | [Ref] RFC6830.
 212 | | ...
 213 | | [Teardown] | Run Keywords | Show Packet Trace on All DUTs | ${nodes}
 214 | | ... | AND | Show vpp trace dump on all DUTs
 215 | | ... | AND | VPP Show Errors | ${nodes['DUT1']}
 216 | | ... | AND | VPP Show Errors | ${nodes['DUT2']}
 217 | | ... | AND | Stop and Clear QEMU | ${dut1_node} | ${vm_node}
 218 | | ...
 219 | | [Tags] | EXPECTED_FAILING
 220 | | ...
 221 | | Given Path for 3-node testing is set
 222 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
 223 | | And Interfaces in 3-node path are up
 224 | | When Setup VRF on DUT | ${dut1_node} | ${dut1_fib_table} | ${dut1_to_dut2}
 225 | | ... | ${dut2_to_dut1_ip6} | ${dut2_to_dut1_mac} | ${tg2_ip6} | ${dut1_to_tg}
 226 | | ... | ${tg1_ip6} | ${tg_to_dut1_mac} | ${prefix6}
 227 | | And Setup VRF on DUT | ${dut2_node} | ${dut2_fib_table} | ${dut2_to_dut1}
 228 | | ... | ${dut1_to_dut2_ip6} | ${dut1_to_dut2_mac} | ${tg1_ip6} | ${dut2_to_tg}
 229 | | ... | ${tg2_ip6} | ${tg_to_dut2_mac} | ${prefix6}
 230 | | And Vpp Set If IPv6 Addr
 231 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip6} | ${prefix6}
 232 | | And Vpp Set If IPv6 Addr
 233 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip6} | ${prefix6}
 234 | | And Vpp Set If IPv6 Addr
 235 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip6} | ${prefix6}
 236 | | And Vpp Set If IPv6 Addr
 237 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip6} | ${prefix6}
 238 | | And Set up LISP GPE topology
 239 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
 240 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
 241 | | ... | ${duts_locator_set} | ${dut1_ip6_eid} | ${dut2_ip6_eid}
 242 | | ... | ${dut1_to_dut2_ip6_static_adjacency}
 243 | | ... | ${dut2_to_dut1_ip6_static_adjacency}
 244 | | And Setup Qemu DUT1
 245 | | Then Send Packet And Check Headers
 246 | | ... | ${tg_node} | ${tg1_ip6} | ${tg2_ip6}
 247 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dst_vhost_mac}
 248 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
 249 | | And Send Packet And Check Headers
 250 | | ... | ${tg_node} | ${tg2_ip6} | ${tg1_ip6}
 251 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 252 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
 253
 254 *** Keywords ***
 255 | Setup Qemu DUT1
 256 | | [Documentation] | Setup Vhosts on DUT1 and setup IP on one of them. Setup\
 257 | | ... | Qemu and bridge the vhosts.
 258 | | ...
 259 | | ${vhost1}= | Vpp Create Vhost User Interface | ${dut1_node} | ${sock1}
 260 | | ${vhost2}= | Vpp Create Vhost User Interface | ${dut1_node} | ${sock2}
 261 | | Set Interface State | ${dut1_node} | ${vhost1} | up
 262 | | Set Interface State | ${dut1_node} | ${vhost2} | up
 263 | | Bridge domain on DUT node is created | ${dut1_node} | ${bid} | learn=${TRUE}
 264 | | Interface is added to bridge domain | ${dut1_node}
 265 | | ... | ${dut1_to_tg} | ${bid} | 0
 266 | | Interface is added to bridge domain | ${dut1_node}
 267 | | ... | ${vhost1} | ${bid} | 0
 268 | | ${vhost_mac}= | Get Vhost User Mac By SW Index | ${dut1_node} | ${vhost2}
 269 | | Set test variable | ${dst_vhost_mac} | ${vhost_mac}
 270 | | VM for Vhost L2BD forwarding is setup | ${dut1_node} | ${sock1} | ${sock2}