tests/func/vxlan/eth2p-ethip4vxlan-l2xcbase-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/default.robot
  16 | Resource | resources/libraries/robot/testing_path.robot
  17 | Resource | resources/libraries/robot/vxlan.robot
  18 | Resource | resources/libraries/robot/l2_traffic.robot
  19 | Library  | resources.libraries.python.Trace
  20 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | HW_ENV
  21 | Test Setup | Set up functional test
  22 | Test Teardown | Tear down functional test
  23 | Documentation | *RFC7348 VXLAN: L2 cross-connect with VXLAN test cases*
  24 | ...
  25 | ... | *[Top] Network topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  26 | ... | with single links between nodes.
  27 | ... | *[Enc] Packet encapsulations:* Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on
  28 | ... | DUT1-DUT2, Eth-IPv4-ICMPv4 on TG-DUTn for L2 switching of IPv4.
  29 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  30 | ... | cross-connect (L2XC) switching; VXLAN tunnels are configured between
  31 | ... | L2XCs on DUT1 and DUT2.
  32 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets
  33 | ... | are sent in both directions by TG on links to DUT1 and DUT2; on receive
  34 | ... | TG verifies packets for correctness and their IPv4 src-addr, dst-addr
  35 | ... | and MAC addresses.
  36 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  37
  38 *** Variables ***
  39 | ${VNI}= | 24
  40
  41 *** Test Cases ***
  42 | TC01: DUT1 and DUT2 with L2XC and VXLANoIPv4 tunnels switch ICMPv4 between TG links
  43 | | [Documentation]
  44 | | ... | [Top] TG-DUT1-DUT2-TG. [Enc] Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on \
  45 | | ... | [Ref] RFC7348.DUT1-DUT2, Eth-IPv4-ICMPv4 on TG-DUTn. [Cfg] On
  46 | | ... | DUT1 and DUT2 configure L2 cross-connect (L2XC), each with one
  47 | | ... | interface to TG and one VXLAN tunnel interface towards the other
  48 | | ... | DUT. [Ver] Make TG send ICMPv4 Echo Req between two of its
  49 | | ... | interfaces; verify all packets are received. [Ref] RFC7348.
  50 | | Given Configure path in 3-node circular topology
  51 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  52 | | And   Set interfaces in 3-node circular topology up
  53 | | ${dut1_to_dut2_name}= | Get interface name | ${dut1_node} | ${dut1_to_dut2}
  54 | | ${dut2_to_dut1_name}= | Get interface name | ${dut2_node} | ${dut2_to_dut1}
  55 | | And   Configure IP addresses and neighbors on interfaces | ${dut1_node} | ${dut1_to_dut2_name} | ${NONE}
  56 | |       ...                                | ${dut2_node} | ${dut2_to_dut1_name} | ${NONE}
  57 | | ${dut1s_vxlan}= | When Create VXLAN interface     | ${dut1_node} | ${VNI}
  58 | |                 | ...  | ${dut1s_ip_address} | ${dut2s_ip_address}
  59 | |                   And  Add interfaces to L2XC | ${dut1_node}
  60 | |                   ...  | ${dut1_to_tg} | ${dut1s_vxlan}
  61 | | ${dut2s_vxlan}= | And  Create VXLAN interface     | ${dut2_node} | ${VNI}
  62 | |                 | ...  | ${dut2s_ip_address} | ${dut1s_ip_address}
  63 | |                   And  Add interfaces to L2XC | ${dut2_node}
  64 | |                   ...  | ${dut2_to_tg} | ${dut2s_vxlan}
  65 | | Then Send ICMPv4 bidirectionally and verify received packets
  66 | | ... | ${tg_node} | ${tg_to_dut1} | ${tg_to_dut2}