tests/func/vxlan/eth2p-ethip6vxlan-l2bdbasemaclrn-eth-2vhost-1vm-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/default.robot
  16 | Resource | resources/libraries/robot/testing_path.robot
  17 | Resource | resources/libraries/robot/vxlan.robot
  18 | Resource | resources/libraries/robot/l2_traffic.robot
  19 | Resource | resources/libraries/robot/qemu.robot
  20 | Resource | resources/libraries/robot/double_qemu_setup.robot
  21 | Library  | resources.libraries.python.Trace
  22 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | HW_ENV
  23 | Test Setup | Func Test Setup
  24 | Test Teardown | Run Keywords | Func Test Teardown
  25 | ... | AND | Run keyword | Qemu Teardown | ${dut1_node}
  26 | ...                                     | ${${qemu1}} | ${qemu1}
  27 | ... | AND | Run keyword | Qemu Teardown | ${dut2_node}
  28 | ...                                     | ${${qemu2}} | ${qemu2}
  29 | Documentation | *L2BD with VM combined with VXLAN test cases - IPv6*
  30 | ...
  31 | ... | *[Top] Network topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  32 | ... | with single links between nodes.
  33 | ... | *[Enc] Packet encapsulations:* Eth-IPv6-VXLAN-Eth-IPv6-ICMPv6 on
  34 | ... | DUT1-DUT2, Eth-IPv6-ICMPv6 on TG-DUTn for L2 switching of IPv6.
  35 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  36 | ... | bridge-domain (L2BD) switching combined with MAC learning enabled;
  37 | ... | VXLAN tunnels are configured between L2BDs on DUT1 and DUT2.
  38 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets are sent
  39 | ... | in both directions by TG on links to DUT1 and DUT2; on receive TG
  40 | ... | verifies packets for correctness and their IPv6 src-addr, dst-addr
  41 | ... | and MAC addresses.
  42 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  43
  44 *** Variables ***
  45 | ${vni_1}= | 23
  46
  47 | ${bd_id1}= | 10
  48 | ${bd_id2}= | 20
  49
  50 | ${ip6_addr1}= | 3ffe:64::1
  51 | ${ip6_addr2}= | 3ffe:64::2
  52 | ${ip6_prefix}= | 64
  53
  54 | ${sock1}= | /tmp/sock1
  55 | ${sock2}= | /tmp/sock2
  56
  57 | ${qemu1}= | qemu_instance_1
  58 | ${qemu2}= | qemu_instance_2
  59
  60 | ${dut1_vhost1}= | dut1_vhost_if1
  61 | ${dut1_vhost2}= | dut1_vhost_if2
  62 | ${dut2_vhost1}= | dut2_vhost_if1
  63 | ${dut2_vhost2}= | dut2_vhost_if2
  64
  65 *** Test Cases ***
  66 | TC01:DUT1 and DUT2 with two L2BDs and VXLANoIPv6 tunnel switch ICMPv6 between TG links and VM links
  67 | | [Documentation]
  68 | | ... | [Top] TG-DUT1-VM-DUT1-DUT2-VM-DUT2-TG.
  69 | | ... | [Enc] Eth-IPv6-VXLAN-Eth-IPv6-ICMPv6 on DUT1-DUT2; Eth-IPv4-ICMPv4
  70 | | ... | on TG-DUTn and DUTn=VM.
  71 | | ... | [Cfg] On both DUTs configure two L2BDs (MAC learning enabled); first
  72 | | ... | L2BD with untagged interface to TG and vhost-user interface to local
  73 | | ... | VM, second one with vhost-user interface to local VM and VXLAN
  74 | | ... | interface towards the other DUT. Configure linux bridge on both VMs
  75 | | ... | to pass traffic between both vhost-user interfaces.
  76 | | ... | [Ver] Make TG send ICMPv6 Echo Req between two of its interfaces to
  77 | | ... | be switched by DUT1 and DUT2; verify packets are switched between
  78 | | ... | these TG interfaces.
  79 | | ... | [Ref] RFC7348.
  80 | | [Tags] | VPP_VM_ENV
  81 | | Given Path for 3-node testing is set
  82 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  83 | | And Interfaces in 3-node path are up
  84 | | When VPP Vhost interfaces for L2BD forwarding are setup | ${dut1_node}
  85 | | ...                                                     | ${sock1}
  86 | | ...                                                     | ${sock2}
  87 | | ...                                                     | ${dut1_vhost1}
  88 | | ...                                                     | ${dut1_vhost2}
  89 | | And VPP Vhost interfaces for L2BD forwarding are setup | ${dut2_node}
  90 | | ...                                                    | ${sock1}
  91 | | ...                                                    | ${sock2}
  92 | | ...                                                    | ${dut2_vhost1}
  93 | | ...                                                    | ${dut2_vhost2}
  94 | | And VM for Vhost L2BD forwarding is setup | ${dut1_node} | ${sock1}
  95 | | ...                                       | ${sock2} | ${qemu1}
  96 | | And VM for Vhost L2BD forwarding is setup | ${dut2_node} | ${sock1}
  97 | | ...                                       | ${sock2} | ${qemu2}
  98 | | And Set Interface Address | ${dut1_node} | ${dut1_to_dut2} | ${ip6_addr1}
  99 | | ...                       | ${ip6_prefix}
 100 | | And Set Interface Address | ${dut2_node} | ${dut2_to_dut1} | ${ip6_addr2}
 101 | | ...                       | ${ip6_prefix}
 102 | | And VPP IP Probe | ${dut1_node} | ${dut1_to_dut2} | ${ip6_addr2}
 103 | | And VPP IP Probe | ${dut2_node} | ${dut2_to_dut1} | ${ip6_addr1}
 104 | | ${dut1s_vxlan}= | And Create VXLAN interface | ${dut1_node} | ${vni_1}
 105 | |                 | ...                        | ${ip6_addr1} | ${ip6_addr2}
 106 | | ${dut2s_vxlan}= | And Create VXLAN interface | ${dut2_node} | ${vni_1}
 107 | |                 | ...                        | ${ip6_addr2} | ${ip6_addr1}
 108 | | And Interfaces are added to BD | ${dut1_node} | ${bd_id1}
 109 | | ...                            | ${dut1_to_tg} | ${${dut1_vhost1}}
 110 | | And Interfaces are added to BD | ${dut1_node} | ${bd_id2}
 111 | | ...                            | ${dut1s_vxlan} | ${${dut1_vhost2}}
 112 | | And Interfaces are added to BD | ${dut2_node} | ${bd_id1}
 113 | | ...                            | ${dut2_to_tg} | ${${dut2_vhost1}}
 114 | | And Interfaces are added to BD | ${dut2_node} | ${bd_id2}
 115 | | ...                            | ${dut2s_vxlan} | ${${dut2_vhost2}}
 116 | | Then Send and receive ICMPv6 bidirectionally
 117 | | ... | ${tg_node} | ${tg_to_dut1} | ${tg_to_dut2}