Fix TC02 test case in mgmt-cfg-int-subint-apihc-apivat-func
[csit.git] / tests / honeycomb / func / mgmt-cfg-int-subint-apihc-apivat-func.robot
1 # Copyright (c) 2016 Cisco and/or its affiliates.
2 # Licensed under the Apache License, Version 2.0 (the "License");
3 # you may not use this file except in compliance with the License.
4 # You may obtain a copy of the License at:
5 #
6 #     http://www.apache.org/licenses/LICENSE-2.0
7 #
8 # Unless required by applicable law or agreed to in writing, software
9 # distributed under the License is distributed on an "AS IS" BASIS,
10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11 # See the License for the specific language governing permissions and
12 # limitations under the License.
13
14 *** Settings ***
15 | Resource | resources/libraries/robot/shared/default.robot
16 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
17 | Resource | resources/libraries/robot/honeycomb/sub_interface.robot
18 | Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
19 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
20 | Library | resources.libraries.python.InterfaceUtil
21 | Variables | resources/test_data/honeycomb/sub_interfaces.py
22 | ...
23 | Suite Setup | Set Up Honeycomb Functional Test Suite | ${node}
24 | ...
25 | Suite Teardown | Tear Down Honeycomb Functional Test Suite | ${node}
26 | ...
27 | Force Tags | HC_FUNC
28 | ...
29 | Documentation | *Honeycomb sub-interface management test suite.*
30
31 *** Variables ***
32 # Test interfaces and their sub-interface parameters:
33 | ${super_if}= | ${node['interfaces']['port1']['name']}
34 | ${super_if2}= | ${node['interfaces']['port3']['name']}
35 | ${sub_if_id}= | ${sub_if_1_settings['identifier']}
36 | ${sub_if_name}= | ${super_if}.${sub_if_id}
37 | ${sub_if2_name}= | ${super_if2}.${sub_if_id}
38
39 *** Test Cases ***
40 | TC01: Honeycomb creates sub-interface
41 | | [Documentation] | Check if Honeycomb creates a sub-interface.
42 | | ...
43 | | Given Honeycomb configures interface state | ${node} | ${super_if} | down
44 | | And sub-interface Operational Data From Honeycomb Should Be empty
45 | | ... | ${node} | ${super_if} | ${sub_if_id}
46 | | And interface Operational Data From VAT Should Be empty
47 | | ... | ${node} | ${sub_if_name}
48 | | When Honeycomb creates sub-interface | ${node} | ${super_if}
49 | | ... | ${sub_if_1_match} | ${sub_if_1_tags} | ${sub_if_1_settings}
50 | | Then Sub-interface Operational Data From Honeycomb Should Be
51 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${sub_if_1_oper}
52 | | And Sub-interface Operational Data From VAT Should Be
53 | | ... | ${node} | ${sub_if_name} | ${sub_if_1_oper}
54 | | And sub-interface indices from Honeycomb and VAT should correspond
55 | | ... | ${node} | ${super_if} | ${sub_if_id}
56
57 | TC02: Honeycomb sets interface and sub-interface up
58 | | [Documentation] | Honeycomb changes the state of interface\
59 | | ... | and of its sub-interface to up.
60 | | ...
61 | | Given interface state from Honeycomb should be
62 | | ... | ${node} | ${super_if} | down
63 | | And interface state from VAT should be
64 | | ... | ${node} | ${super_if} | down
65 | | Sub-interface state from Honeycomb should be
66 | | ... | ${node} | ${super_if} | ${sub_if_id} | down | down
67 | | Sub-interface state from VAT should be
68 | | ... | ${node} | ${sub_if_name} | down | down
69 | | When Honeycomb configures interface state
70 | | ... | ${node} | ${super_if} | up
71 | | Then interface state from Honeycomb should be
72 | | ... | ${node} | ${super_if} | up
73 | | And interface state from VAT should be
74 | | ... | ${node} | ${super_if} | up
75 | | When Honeycomb sets the sub-interface up
76 | | ... | ${node} | ${super_if} | ${sub_if_id}
77 | | Vpp Node Interfaces Ready Wait | ${node}
78 | | Then Sub-interface state from Honeycomb should be
79 | | ... | ${node} | ${super_if} | ${sub_if_id} | up | up
80 | | And sub-interface state from VAT should be
81 | | ... | ${node} | ${sub_if_name} | up | up
82
83 | TC03: Honeycomb sets sub-interface down while its super-interface is up
84 | | [Documentation] | Honeycomb sets the sub-interface down while its \
85 | | ... | super-interface is up. It must be possible.
86 | | ...
87 | | [Teardown] | Set super and sub interfaces up
88 | | ... | ${node} | ${super_if} | ${sub_if_id}
89 | | ...
90 | | Given sub-interface state from Honeycomb should be
91 | | ... | ${node} | ${super_if} | ${sub_if_id} | up | up
92 | | And sub-interface state from VAT should be
93 | | ... | ${node} | ${sub_if_name} | up | up
94 | | And interface state from Honeycomb should be
95 | | ... | ${node} | ${super_if} | up
96 | | And interface state from VAT should be
97 | | ... | ${node} | ${super_if} | up
98 | | When Honeycomb sets the sub-interface down
99 | | ... | ${node} | ${super_if} | ${sub_if_id}
100 | | Then interface state from Honeycomb should be
101 | | ... | ${node} | ${super_if} | up
102 | | And interface state from VAT should be
103 | | ... | ${node} | ${super_if} | up
104 | | And sub-interface state from Honeycomb should be
105 | | ... | ${node} | ${super_if} | ${sub_if_id} | down | up
106 | | And sub-interface state from VAT should be
107 | | ... | ${node} | ${sub_if_name} | down | up
108
109 | TC04: Honeycomb sets interface and sub-interface down
110 | | [Documentation] | Honeycomb changes the state of interface down and then \
111 | | ... | changes the state of its sub-interface down, in this order.
112 | | ...
113 | | [Teardown] | Set super and sub interfaces down
114 | | ... | ${node} | ${super_if} | ${sub_if_id}
115 | | ...
116 | | Given interface state from Honeycomb should be
117 | | ... | ${node} | ${super_if} | up
118 | | And interface state from VAT should be
119 | | ... | ${node} | ${super_if} | up
120 | | When Honeycomb configures interface state
121 | | ... | ${node} | ${super_if} | down
122 | | Then interface state from Honeycomb should be
123 | | ... | ${node} | ${super_if} | down
124 | | And interface state from VAT should be
125 | | ... | ${node} | ${super_if} | down
126 | | Given sub-interface state from Honeycomb should be
127 | | ... | ${node} | ${super_if} | ${sub_if_id} | up | down
128 | | And sub-interface state from VAT should be
129 | | ... | ${node} | ${sub_if_name} | up | down
130 | | When Honeycomb sets the sub-interface down
131 | | ... | ${node} | ${super_if} | ${sub_if_id}
132 | | Then sub-interface state from Honeycomb should be
133 | | ... | ${node} | ${super_if} | ${sub_if_id} | down | down
134 | | And sub-interface state from VAT should be
135 | | ... | ${node} | ${sub_if_name} | down | down
136
137 | TC05: Honeycomb fails to set sub-interface up while its super-interface is down
138 | | [Documentation] | Honeycomb tries to set the sub-interface up while its \
139 | | ... | super-interface is down. It must not be possible.
140 | | ...
141 | | Given interface state from Honeycomb should be
142 | | ... | ${node} | ${super_if} | down
143 | | And interface state from VAT should be
144 | | ... | ${node} | ${super_if} | down
145 | | And sub-interface state from Honeycomb should be
146 | | ... | ${node} | ${super_if} | ${sub_if_id} | down | down
147 | | And sub-interface state from VAT should be
148 | | ... | ${node} | ${sub_if_name} | down | down
149 | | When Honeycomb fails to set sub-interface up
150 | | ... | ${node} | ${super_if} | ${sub_if_id}
151 | | Then interface state from Honeycomb should be
152 | | ... | ${node} | ${super_if} | down
153 | | And interface state from VAT should be
154 | | ... | ${node} | ${super_if} | down
155 | | And sub-interface state from Honeycomb should be
156 | | ... | ${node} | ${super_if} | ${sub_if_id} | down | down
157 | | And sub-interface state from VAT should be
158 | | ... | ${node} | ${sub_if_name} | down | down
159
160 | TC06: Honeycomb fails to delete sub-interface
161 | | [Documentation] | Check if Honeycomb can delete an existing sub-interface.
162 | | ...
163 | | [Setup] | Set super and sub interfaces down
164 | | ... | ${node} | ${super_if} | ${sub_if_id}
165 | | ...
166 | | Given sub-interface Operational Data From Honeycomb Should Be
167 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${sub_if_1_oper}
168 | | And sub-interface Operational Data From VAT Should Be
169 | | ... | ${node} | ${sub_if_name} | ${sub_if_1_oper}
170 | | When Honeycomb fails to remove all sub-interfaces
171 | | ... | ${node} | ${super_if}
172 | | Then sub-interface Operational Data From Honeycomb Should Be
173 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${sub_if_1_oper}
174 | | And sub-interface Operational Data From VAT Should Be
175 | | ... | ${node} | ${sub_if_name} | ${sub_if_1_oper}
176
177 | TC07: Honeycomb adds sub-interface to new bridge domain
178 | | [Documentation] | Check if Honeycomb adds a sub-interface to bridge domain.
179 | | ...
180 | | [Setup] | Set super and sub interfaces down
181 | | ... | ${node} | ${super_if} | ${sub_if_id}
182 | | ...
183 | | Given sub-interface Operational Data From Honeycomb Should Be
184 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${sub_if_1_oper}
185 | | And sub-interface Operational Data From VAT Should Be
186 | | ... | ${node} | ${sub_if_name} | ${sub_if_1_oper}
187 | | When Honeycomb creates first L2 bridge domain
188 | | ... | ${node} | ${bd_name} | ${bd_settings}
189 | | Then bridge domain Operational Data From Honeycomb Should Be
190 | | ... | ${node} | ${bd_name} | ${bd_settings}
191 | | When Honeycomb adds sub-interface to bridge domain
192 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${sub_bd_settings}
193 | | Then sub-interface bridge domain Operational Data From Honeycomb Should Be
194 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${sub_bd_settings}
195 | | And sub-interface bridge domain Operational Data From VAT Should Be
196 | | ... | ${node} | ${sub_if_name} | ${sub_bd_settings}
197 | | And sub-interface Operational Data From VAT Should Be
198 | | ... | ${node} | ${sub_if_name} | ${sub_if_1_oper}
199
200 | TC08: Honeycomb enables tag-rewrite pop 1
201 | | [Documentation] | Check if Honeycomb enables tag-rewrite and sets its \
202 | | ... | parameters correctly. Case: pop 1.
203 | | ...
204 | | [Teardown] | Honeycomb disables tag rewrite
205 | | ... | ${node} | ${super_if} | ${sub_if_id}
206 | | ...
207 | | Given rewrite tag from Honeycomb should be empty
208 | | ... | ${node} | ${super_if} | ${sub_if_id}
209 | | When Honeycomb configures tag rewrite
210 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_pop_1}
211 | | Then rewrite tag from Honeycomb should be
212 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_pop_1_oper}
213 | | And rewrite tag from VAT should be
214 | | ... | ${node} | ${sub_if_name} | ${tag_rewrite_pop_1_VAT}
215
216 | TC09: Honeycomb enables tag-rewrite push
217 | | [Documentation] | Check if Honeycomb enables tag-rewrite and sets its \
218 | | ... | parameters correctly. Case: push.
219 | | ...
220 | | [Teardown] | Honeycomb disables tag rewrite
221 | | ... | ${node} | ${super_if} | ${sub_if_id}
222 | | ...
223 | | Given rewrite tag from Honeycomb should be empty
224 | | ... | ${node} | ${super_if} | ${sub_if_id}
225 | | When Honeycomb configures tag rewrite
226 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_push}
227 | | Then rewrite tag from Honeycomb should be
228 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_push_oper}
229 | | And rewrite tag from VAT should be
230 | | ... | ${node} | ${sub_if_name} | ${tag_rewrite_push_VAT}
231
232 | TC10: Honeycomb enables tag-rewrite translate 1-2
233 | | [Documentation] | Check if Honeycomb enables tag-rewrite and sets its \
234 | | ... | parameters correctly. Case: translate 1-2.
235 | | ...
236 | | [Teardown] | Honeycomb disables tag rewrite
237 | | ... | ${node} | ${super_if} | ${sub_if_id}
238 | | ...
239 | | Given rewrite tag from Honeycomb should be empty
240 | | ... | ${node} | ${super_if} | ${sub_if_id}
241 | | When Honeycomb configures tag rewrite
242 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_translate_1_2}
243 | | Then rewrite tag from Honeycomb should be
244 | | ... | ${node} | ${super_if} | ${sub_if_id}
245 | | ... | ${tag_rewrite_translate_1_2_oper}
246 | | And rewrite tag from VAT should be
247 | | ... | ${node} | ${sub_if_name} | ${tag_rewrite_translate_1_2_VAT}
248
249 | TC11: Honeycomb disables tag-rewrite
250 | | [Documentation] | Check if Honeycomb disables the tag-rewrite.
251 | | ...
252 | | [Teardown] | Honeycomb disables tag rewrite
253 | | ... | ${node} | ${super_if} | ${sub_if_id}
254 | | ...
255 | | When Honeycomb configures tag rewrite
256 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_pop_1}
257 | | Then rewrite tag from Honeycomb should be
258 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_pop_1_oper}
259 | | When Honeycomb configures tag rewrite
260 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_disabled}
261 | | Then rewrite tag from Honeycomb should be empty
262 | | ... | ${node} | ${super_if} | ${sub_if_id}
263 | | And rewrite tag from VAT should be
264 | | ... | ${node} | ${sub_if_name} | ${tag_rewrite_disabled_VAT}
265
266 | TC12: Honeycomb enables tag-rewrite pop 1 again
267 | | [Documentation] | Check if Honeycomb can enable tag-rewrite again, once it \
268 | | ... | was disabled by Honeycomb.
269 | | ...
270 | | [Teardown] | Honeycomb disables tag rewrite
271 | | ... | ${node} | ${super_if} | ${sub_if_id}
272 | | ...
273 | | Given rewrite tag from Honeycomb should be empty
274 | | ... | ${node} | ${super_if} | ${sub_if_id}
275 | | When Honeycomb configures tag rewrite
276 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_pop_1}
277 | | Then rewrite tag from Honeycomb should be
278 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_pop_1_oper}
279 | | And rewrite tag from VAT should be
280 | | ... | ${node} | ${sub_if_name} | ${tag_rewrite_pop_1_VAT}
281
282 | TC13: Honeycomb modifies the tag-rewrite
283 | | [Documentation] | Honeycomb sets the tag-rewrite:
284 | | ... | 1. pop 1, then
285 | | ... | 2. push, then
286 | | ... | 3. translate 1 - 2
287 | | ... | Then Honeycomb disables the tag-rewrite.
288 | | ...
289 | | [Teardown] | Honeycomb disables tag rewrite
290 | | ... | ${node} | ${super_if} | ${sub_if_id}
291 | | ...
292 | | Given rewrite tag from Honeycomb should be empty
293 | | ... | ${node} | ${super_if} | ${sub_if_id}
294 | | When Honeycomb configures tag rewrite
295 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_pop_1}
296 | | Then rewrite tag from Honeycomb should be
297 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_pop_1_oper}
298 | | And rewrite tag from VAT should be
299 | | ... | ${node} | ${sub_if_name} | ${tag_rewrite_pop_1_VAT}
300 | | When Honeycomb configures tag rewrite
301 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_push}
302 | | Then rewrite tag from Honeycomb should be
303 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_push_oper}
304 | | And rewrite tag from VAT should be
305 | | ... | ${node} | ${sub_if_name} | ${tag_rewrite_push_VAT}
306 | | When Honeycomb configures tag rewrite
307 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_translate_1_2}
308 | | Then rewrite tag from Honeycomb should be
309 | | ... | ${node} | ${super_if} | ${sub_if_id}
310 | | ... | ${tag_rewrite_translate_1_2_oper}
311 | | And rewrite tag from VAT should be
312 | | ... | ${node} | ${sub_if_name} | ${tag_rewrite_translate_1_2_VAT}
313 | | When Honeycomb configures tag rewrite
314 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_disabled}
315 | | Then rewrite tag from Honeycomb should be empty
316 | | ... | ${node} | ${super_if} | ${sub_if_id}
317 | | And rewrite tag from VAT should be
318 | | ... | ${node} | ${sub_if_name} | ${tag_rewrite_disabled_VAT}
319
320 | TC14: Honeycomb fails to set wrong vlan-type in tag-rewrite
321 | | [Documentation] | Check that Honeycomb does not accept wrong values of \
322 | | ... | vlan-type in tag-rewrite.
323 | | ...
324 | | Given rewrite tag from Honeycomb should be empty
325 | | ... | ${node} | ${super_if} | ${sub_if_id}
326 | | When Honeycomb fails to set wrong rewrite tag
327 | | ... | ${node} | ${super_if} | ${sub_if_id}
328 | | ... | ${tag_rewrite_translate_1_2_wrong}
329 | | Then rewrite tag from Honeycomb should be empty
330 | | ... | ${node} | ${super_if} | ${sub_if_id}
331 | | And rewrite tag from VAT should be
332 | | ... | ${node} | ${sub_if_name} | ${tag_rewrite_disabled_VAT}
333
334 | TC15: Honeycomb configures sub-interface ipv4 address
335 | | [Documentation] | Check if Honeycomb can configure an ipv4 address on the\
336 | | ... | sub-interface.
337 | | ...
338 | | Given sub-interface ipv4 address from Honeycomb should be empty
339 | | ... | ${node} | ${super_if} | ${sub_if_id}
340 | | And sub-interface ipv4 address from VAT should be empty
341 | | ... | ${node} | ${sub_if_name}
342 | | When Honeycomb sets sub-interface ipv4 address
343 | | ... | ${node} | ${super_if} | ${sub_if_id}
344 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
345 | | Then sub-interface ipv4 address from Honeycomb should be
346 | | ... | ${node} | ${super_if} | ${sub_if_id}
347 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
348 | | And sub-interface ipv4 address from VAT should be
349 | | ... | ${node} | ${sub_if_name}
350 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
351
352 | TC16: Honeycomb removes sub-interface ipv4 address
353 | | [Documentation] | Check if Honeycomb can remove configured ipv4 addresses\
354 | | ... | from the sub-interface.
355 | | ...
356 | | Given sub-interface ipv4 address from Honeycomb should be
357 | | ... | ${node} | ${super_if} | ${sub_if_id}
358 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
359 | | Run Keyword And Continue On Failure
360 | | ... | And sub-interface ipv4 address from VAT should be
361 | | ... | ${node} | ${sub_if_name}
362 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
363 | | When Honeycomb removes all sub-interface ipv4 addresses
364 | | ... | ${node} | ${super_if} | ${sub_if_id}
365 | | Then sub-interface ipv4 address from Honeycomb should be empty
366 | | ... | ${node} | ${super_if} | ${sub_if_id}
367 | | And sub-interface ipv4 address from VAT should be empty
368 | | ... | ${node} | ${sub_if_name}
369
370 | TC17: Honeycomb modifies existing sub-interface ipv4 address
371 | | [Documentation] | Check if Honeycomb can modify an ipv4 address already\
372 | | ... | configured on the sub-interface.
373 | | ...
374 | | [Teardown] | Honeycomb removes all sub-interface ipv4 addresses
375 | | ... | ${node} | ${super_if} | ${sub_if_id}
376 | | ...
377 | | Given sub-interface ipv4 address from Honeycomb should be empty
378 | | ... | ${node} | ${super_if} | ${sub_if_id}
379 | | And sub-interface ipv4 address from VAT should be empty
380 | | ... | ${node} | ${sub_if_name}
381 | | When Honeycomb sets sub-interface ipv4 address
382 | | ... | ${node} | ${super_if} | ${sub_if_id}
383 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
384 | | And Honeycomb sets sub-interface ipv4 address
385 | | ... | ${node} | ${super_if} | ${sub_if_id}
386 | | ... | ${ipv4_2['address']} | ${ipv4_2['prefix-length']}
387 | | Then sub-interface ipv4 address from Honeycomb should be
388 | | ... | ${node} | ${super_if} | ${sub_if_id}
389 | | ... | ${ipv4_2['address']} | ${ipv4_2['prefix-length']}
390 | | And sub-interface ipv4 address from VAT should be
391 | | ... | ${node} | ${sub_if_name}
392 | | ... | ${ipv4_2['address']} | ${ipv4_2['prefix-length']}
393
394 | TC18: Honeycomb modifies sub-interface exact tag match
395 | | [Documentation] | Check if Honeycomb can modify a sub-interface with exact\
396 | | ... | tag match.
397 | | ...
398 | | Given Honeycomb configures interface state | ${node} | ${super_if2} | down
399 | | And sub-interface Operational Data From Honeycomb Should Be empty
400 | | ... | ${node} | ${super_if2} | ${sub_if_id}
401 | | And interface Operational Data From VAT Should Be empty
402 | | ... | ${node} | ${sub_if2_name}
403 | | When Honeycomb creates sub-interface | ${node} | ${super_if2}
404 | | ... | ${sub_if_2_match} | ${sub_if_2_tags} | ${sub_if_2_settings}
405 | | Then Sub-interface Operational Data From Honeycomb Should Be
406 | | ... | ${node} | ${super_if2} | ${sub_if_id} | ${sub_if_2_oper}
407 | | And Sub-interface Operational Data From VAT Should Be
408 | | ... | ${node} | ${sub_if2_name} | ${sub_if_2_oper}
409 | | And sub-interface indices from Honeycomb and VAT should correspond
410 | | ... | ${node} | ${super_if2} | ${sub_if_id}
411
412 | TC19: Honeycomb configures sub-interface ipv6 address
413 | | [Documentation] | Check if Honeycomb can configure an ipv6 address on the\
414 | | ... | sub-interface.
415 | | ...
416 | | Given sub-interface ipv6 address from Honeycomb should be empty
417 | | ... | ${node} | ${super_if} | ${sub_if_id}
418 | | And sub-interface ipv6 address from VAT should be empty
419 | | ... | ${node} | ${sub_if_name}
420 | | When Honeycomb sets sub-interface ipv6 address
421 | | ... | ${node} | ${super_if} | ${sub_if_id}
422 | | ... | ${ipv6['address']} | ${ipv6['prefix-length']}
423 | | Then sub-interface IPv6 address from Honeycomb should contain
424 | | ... | ${node} | ${super_if} | ${sub_if_id}
425 | | ... | ${ipv6['address']} | ${ipv6['prefix-length']}
426 | | And sub-interface IPv6 address from VAT should contain
427 | | ... | ${node} | ${sub_if_name}
428 | | ... | ${ipv6['address']} | ${ipv6['prefix-length']}
429
430 | TC20: Honeycomb removes sub-interface ipv6 address
431 | | [Documentation] | Check if Honeycomb can remove configured ipv6 addresses\
432 | | ... | from the sub-interface.
433 | | ...
434 | | Given sub-interface IPv6 address from Honeycomb should contain
435 | | ... | ${node} | ${super_if} | ${sub_if_id}
436 | | ... | ${ipv6['address']} | ${ipv6['prefix-length']}
437 | | Run Keyword And Continue On Failure
438 | | ... | And sub-interface IPv6 address from VAT should contain
439 | | ... | ${node} | ${sub_if_name}
440 | | ... | ${ipv6['address']} | ${ipv6['prefix-length']}
441 | | When Honeycomb removes all sub-interface ipv6 addresses
442 | | ... | ${node} | ${super_if} | ${sub_if_id}
443 | | Then sub-interface ipv6 address from Honeycomb should be empty
444 | | ... | ${node} | ${super_if} | ${sub_if_id}
445 | | And sub-interface ipv6 address from VAT should be empty
446 | | ... | ${node} | ${sub_if_name}
447
448 | TC21: Honeycomb modifies existing sub-interface ipv6 address
449 | | [Documentation] | Check if Honeycomb can modify an ipv6 address already\
450 | | ... | configured on the sub-interface.
451 | | ...
452 | | [Teardown] | Honeycomb removes all sub-interface ipv6 addresses
453 | | ... | ${node} | ${super_if} | ${sub_if_id}
454 | | ...
455 | | Given sub-interface ipv6 address from Honeycomb should be empty
456 | | ... | ${node} | ${super_if} | ${sub_if_id}
457 | | And sub-interface ipv6 address from VAT should be empty
458 | | ... | ${node} | ${sub_if_name}
459 | | When Honeycomb sets sub-interface ipv6 address
460 | | ... | ${node} | ${super_if} | ${sub_if_id}
461 | | ... | ${ipv6['address']} | ${ipv6['prefix-length']}
462 | | And Honeycomb sets sub-interface ipv6 address
463 | | ... | ${node} | ${super_if} | ${sub_if_id}
464 | | ... | ${ipv6_2['address']} | ${ipv6_2['prefix-length']}
465 | | Then sub-interface IPv6 address from Honeycomb should contain
466 | | ... | ${node} | ${super_if} | ${sub_if_id}
467 | | ... | ${ipv6_2['address']} | ${ipv6_2['prefix-length']}
468 | | And sub-interface IPv6 address from VAT should contain
469 | | ... | ${node} | ${sub_if_name}
470 | | ... | ${ipv6_2['address']} | ${ipv6_2['prefix-length']}
471
472 | TC22: Honeycomb can configure unnumbered sub-interface
473 | | [Documentation] | Check if Honeycomb can configure an unnumbered interface\
474 | | ... | on a sub-interface, borrowing the IP address of a physical interface.
475 | | ...
476 # HC2VPP-330: Honeycomb fails to configure interface as unnumbered
477 | | [Tags] | EXPECTED_FAILING
478 | | ...
479 | | Given sub-interface ipv4 address from Honeycomb should be empty
480 | | ... | ${node} | ${super_if} | ${sub_if_id}
481 | | And sub-interface ipv4 address from VAT should be empty
482 | | ... | ${node} | ${sub_if_name}
483 | | And Honeycomb sets interface IPv4 address | ${node}
484 | | ... | ${super_if2} | ${ipv4['address']} | ${ipv4['prefix-length']}
485 | | When Honeycomb adds unnumbered configuration to interface
486 | | ... | ${node} | ${super_if}.${sub_if_id} | ${super_if2}
487 | | Then IPv4 address from Honeycomb should be
488 | | ... | ${node} | ${super_if2} | ${ipv4['address']} | ${ipv4['prefix-length']}
489 | | And IPv4 address from VAT should be
490 | | ... | ${node} | ${super_if2}
491 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']} | ${ipv4['netmask']}
492 | | And sub-interface ipv4 address from Honeycomb should be
493 | | ... | ${node} | ${super_if} | ${sub_if_id}
494 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
495 | | And sub-interface ipv4 address from VAT should be
496 | | ... | ${node} | ${sub_if_name}
497 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
498
499 | TC23: Honeycomb removes sub-interface unnumbered configuration
500 | | [Documentation] | Check if Honeycomb can remove unnumbered configuration\
501 | | ... | from a sub-interface.
502 | | ...
503 | | [Teardown] | Honeycomb removes interface IPv4 addresses | ${node}
504 | | ... | ${super_if2}
505 | | ...
506 # HC2VPP-330: Honeycomb fails to configure interface as unnumbered
507 | | [Tags] | EXPECTED_FAILING
508 | | ...
509 | | Given IPv4 address from Honeycomb should be
510 | | ... | ${node} | ${super_if2} | ${ipv4['address']} | ${ipv4['prefix-length']}
511 | | And IPv4 address from VAT should be
512 | | ... | ${node} | ${super_if2}
513 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']} | ${ipv4['netmask']}
514 | | And sub-interface ipv4 address from Honeycomb should be
515 | | ... | ${node} | ${super_if} | ${sub_if_id}
516 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
517 | | And sub-interface ipv4 address from VAT should be
518 | | ... | ${node} | ${sub_if_name}
519 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
520 | | When Honeycomb removes unnumbered configuration from interface
521 | | ... | ${node} | ${super_if}.${sub_if_id}
522 | | Then IPv4 address from Honeycomb should be
523 | | ... | ${node} | ${super_if2} | ${ipv4['address']} | ${ipv4['prefix-length']}
524 | | And IPv4 address from VAT should be
525 | | ... | ${node} | ${super_if2}
526 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']} | ${ipv4['netmask']}
527 | | And sub-interface ipv4 address from Honeycomb should be empty
528 | | ... | ${node} | ${super_if} | ${sub_if_id}
529 | | And sub-interface ipv4 address from VAT should be empty
530 | | ... | ${node} | ${sub_if_name}
531
532 | TC24: Honeycomb can configure unnumbered interface using a sub-interface
533 | | [Documentation] | Check if Honeycomb can configure an unnumbered interface\
534 | | ... | on an interface, borrowing the IP address of a sub-interface.
535 | | ...
536 # HC2VPP-330: Honeycomb fails to configure interface as unnumbered
537 | | [Tags] | EXPECTED_FAILING
538 | | ...
539 | | Given IPv4 address from Honeycomb should be empty | ${node} | ${super_if2}
540 | | And ipv4 address from VAT should be empty | ${node} | ${super_if2}
541 | | And sub-interface ipv4 address from Honeycomb should be empty
542 | | ... | ${node} | ${super_if} | ${sub_if_id}
543 | | And sub-interface ipv4 address from VAT should be empty
544 | | ... | ${node} | ${sub_if_name}
545 | | And Honeycomb sets sub-interface ipv4 address
546 | | ... | ${node} | ${super_if} | ${sub_if_id}
547 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
548 | | When Honeycomb adds unnumbered configuration to interface
549 | | ... | ${node} | ${super_if2} | ${super_if}.${sub_if_id}
550 | | Then IPv4 address from Honeycomb should be
551 | | ... | ${node} | ${super_if2} | ${ipv4['address']} | ${ipv4['prefix-length']}
552 | | And IPv4 address from VAT should be
553 | | ... | ${node} | ${super_if2}
554 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']} | ${ipv4['netmask']}
555 | | And sub-interface ipv4 address from Honeycomb should be
556 | | ... | ${node} | ${super_if} | ${sub_if_id}
557 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
558 | | And sub-interface ipv4 address from VAT should be
559 | | ... | ${node} | ${sub_if_name}
560 | | ... | ${ipv4['address']} | ${ipv4['prefix-length']}
561
562 *** Keywords ***
563 | Set super and sub interfaces up
564 | | [Documentation] | Honeycomb sets super-interface and sub-interface up, in \
565 | | ... | this order.
566 | | ...
567 | | ... | *Arguments:*
568 | | ... | - node - Information about a DUT node. Type: dictionary
569 | | ... | - super_interface - Super interface. Type: string
570 | | ... | - identifier - Sub-interface identifier. Type: integer or string
571 | | ...
572 | | ... | *Example:*
573 | | ... | \| Set super and sub interfaces up\
574 | | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| 1 \|
575 | | ...
576 | | [Arguments] | ${node} | ${super_interface} | ${identifier}
577 | | ...
578 | | Honeycomb configures interface state
579 | | ... | ${node} | ${super_interface} | up
580 | | Honeycomb sets the sub-interface up
581 | | ... | ${node} | ${super_interface} | ${identifier}
582
583 | Set super and sub interfaces down
584 | | [Documentation] | Honeycomb sets super-interface and sub-interface down, in\
585 | | ... | this order.
586 | | ...
587 | | ... | *Arguments:*
588 | | ... | - node - Information about a DUT node. Type: dictionary
589 | | ... | - super_interface - Super interface. Type: string
590 | | ... | - identifier - Sub-interface identifier. Type: integer or string
591 | | ...
592 | | ... | *Example:*
593 | | ... | \| Set super and sub interfaces down\
594 | | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| 1 \|
595 | | ...
596 | | [Arguments] | ${node} | ${super_interface} | ${identifier}
597 | | ...
598 | | Honeycomb configures interface state
599 | | ... | ${node} | ${super_interface} | down
600 | | Honeycomb sets the sub-interface down
601 | | ... | ${node} | ${super_interface} | ${identifier}
602
603 | Honeycomb disables tag rewrite
604 | | [Documentation] |
605 | | ...
606 | | ... | *Arguments:*
607 | | ... | - node - Information about a DUT node. Type: dictionary
608 | | ... | - super_if - Super-interface. Type: string
609 | | ... | - identifier - Sub-interface ID. Type: integer or string
610 | | ...
611 | | ... | *Example:*
612 | | ... | \| Honeycomb disables tag rewrite \
613 | | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| 1 \|
614 | | ...
615 | | [Arguments] | ${node} | ${super_if} | ${sub_if_id}
616 | | ...
617 | | Honeycomb configures tag rewrite
618 | | ... | ${node} | ${super_if} | ${sub_if_id} | ${tag_rewrite_disabled}

©2016 FD.io a Linux Foundation Collaborative Project. All Rights Reserved.
Linux Foundation is a registered trademark of The Linux Foundation. Linux is a registered trademark of Linus Torvalds.
Please see our privacy policy and terms of use.