tests/honeycomb/func/mgmt-cfg-intvhost-apihc-apivat-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 | ${interface}= | ${node['interfaces']['port1']['name']}
  16 | ${vhost_interface}= | test_vhost
  17 | &{vhost_user_server}= | socket=/tmp/soc1 | role=server
  18 | &{vhost_user_server_edit_1}= | socket=/tmp/soc12 | role=server
  19 | &{vhost_user_server_edit_2}= | socket=/tmp/soc12 | role=client
  20 | &{vhost_user_client}= | socket=/tmp/soc2 | role=client
  21 | &{vhost_user_client_edit_1}= | socket=/tmp/soc22 | role=client
  22 | &{vhost_user_client_edit_2}= | socket=/tmp/soc22 | role=server
  23 | &{vhost_user_wrong}= | socket=/tmp/soc2 | role=wrong
  24
  25 *** Settings ***
  26 | Resource | resources/libraries/robot/shared/default.robot
  27 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  28 | Resource | resources/libraries/robot/honeycomb/vhost_user.robot
  29 | ...
  30 | Force Tags | HC_FUNC
  31 | ...
  32 | Suite Setup | Set Up Honeycomb Functional Test Suite | ${node}
  33 | ...
  34 | Suite Teardown | Tear Down Honeycomb Functional Test Suite | ${node}
  35 | ...
  36 | Documentation | *Honeycomb vhost-user interface management test suite.*
  37
  38 *** Test Cases ***
  39 | TC01: Honeycomb creates vhost-user interface - server
  40 | | [Documentation] | Check if Honeycomb creates a vhost-user interface, role:\
  41 | | ... | server.
  42 | | ...
  43 | | Given vhost-user Operational Data From Honeycomb Should Be empty
  44 | | ... | ${node} | ${vhost_interface}
  45 | | When Honeycomb creates vhost-user interface
  46 | | ... | ${node} | ${vhost_interface} | ${vhost_user_server}
  47 | | Then vhost-user Operational Data From Honeycomb Should Be
  48 | | ... | ${node} | ${vhost_interface} | ${vhost_user_server}
  49 | | And vhost-user Operational Data From VAT Should Be
  50 | | ... | ${node} | ${vhost_user_server}
  51
  52 | TC02: Honeycomb modifies vhost-user interface - server
  53 | | [Documentation] | Check if Honeycomb can modify properties of existing\
  54 | | ... | vhost-user interface, role: server.
  55 | | ...
  56 | | Given vhost-user Operational Data From Honeycomb Should Be
  57 | | ... | ${node} | ${vhost_interface} | ${vhost_user_server}
  58 | | When Honeycomb configures vhost-user interface
  59 | | ... | ${node} | ${vhost_interface} | ${vhost_user_server_edit_1}
  60 | | Then vhost-user Operational Data From Honeycomb Should Be
  61 | | ... | ${node} | ${vhost_interface} | ${vhost_user_server_edit_1}
  62 | | And vhost-user Operational Data From VAT Should Be
  63 | | ... | ${node} | ${vhost_user_server_edit_1}
  64 | | When Honeycomb configures vhost-user interface
  65 | | ... | ${node} | ${vhost_interface} | ${vhost_user_server_edit_2}
  66 | | Then vhost-user Operational Data From Honeycomb Should Be
  67 | | ... | ${node} | ${vhost_interface} | ${vhost_user_server_edit_2}
  68 | | And vhost-user Operational Data From VAT Should Be
  69 | | ... | ${node} | ${vhost_user_server_edit_2}
  70 | | When Honeycomb configures vhost-user interface
  71 | | ... | ${node} | ${vhost_interface} | ${vhost_user_server}
  72 | | Then vhost-user Operational Data From Honeycomb Should Be
  73 | | ... | ${node} | ${vhost_interface} | ${vhost_user_server}
  74 | | And vhost-user Operational Data From VAT Should Be
  75 | | ... | ${node} | ${vhost_user_server}
  76
  77 | TC03: Honeycomb deletes vhost-user interface - server
  78 | | [Documentation] | Check if Honeycomb can delete an existing vhost-user\
  79 | | ... | interface, role: server.
  80 | | ...
  81 | | Given vhost-user Operational Data From Honeycomb Should Be
  82 | | ... | ${node} | ${vhost_interface} | ${vhost_user_server}
  83 | | When Honeycomb removes vhost-user interface
  84 | | ... | ${node} | ${vhost_interface}
  85 | | Then vhost-user Operational Data From Honeycomb Should Be empty
  86 | | ... | ${node} | ${vhost_interface}
  87 | | And vhost-user Operational Data From VAT Should Be empty
  88 | | ... | ${node}
  89
  90 | TC04: Honeycomb creates vhost-user interface - client
  91 | | [Documentation] | Check if Honeycomb creates a vhost-user interface, role:\
  92 | | ... | client.
  93 | | ...
  94 | | Given vhost-user Operational Data From Honeycomb Should Be empty
  95 | | ... | ${node} | ${vhost_interface}
  96 | | When Honeycomb creates vhost-user interface
  97 | | ... | ${node} | ${vhost_interface} | ${vhost_user_client}
  98 | | Then vhost-user Operational Data From Honeycomb Should Be
  99 | | ... | ${node} | ${vhost_interface} | ${vhost_user_client}
 100 | | And vhost-user Operational Data From VAT Should Be
 101 | | ... | ${node} | ${vhost_user_client}
 102
 103 | TC05: Honeycomb modifies vhost-user interface - client
 104 | | [Documentation] | Check if Honeycomb can modify properties of existing\
 105 | | ... | vhost-user interface, role: client.
 106 | | ...
 107 | | Given vhost-user Operational Data From Honeycomb Should Be
 108 | | ... | ${node} | ${vhost_interface} | ${vhost_user_client}
 109 | | When Honeycomb configures vhost-user interface
 110 | | ... | ${node} | ${vhost_interface} | ${vhost_user_client_edit_1}
 111 | | Then vhost-user Operational Data From Honeycomb Should Be
 112 | | ... | ${node} | ${vhost_interface} | ${vhost_user_client_edit_1}
 113 | | And vhost-user Operational Data From VAT Should Be
 114 | | ... | ${node} | ${vhost_user_client_edit_1}
 115 | | When Honeycomb configures vhost-user interface
 116 | | ... | ${node} | ${vhost_interface} | ${vhost_user_client_edit_2}
 117 | | Then vhost-user Operational Data From Honeycomb Should Be
 118 | | ... | ${node} | ${vhost_interface} | ${vhost_user_client_edit_2}
 119 | | And vhost-user Operational Data From VAT Should Be
 120 | | ... | ${node} | ${vhost_user_client_edit_2}
 121 | | When Honeycomb configures vhost-user interface
 122 | | ... | ${node} | ${vhost_interface} | ${vhost_user_client}
 123 | | Then vhost-user Operational Data From Honeycomb Should Be
 124 | | ... | ${node} | ${vhost_interface} | ${vhost_user_client}
 125 | | And vhost-user Operational Data From VAT Should Be
 126 | | ... | ${node} | ${vhost_user_client}
 127
 128 | TC06: Honeycomb deletes vhost-user interface - client
 129 | | [Documentation] | Check if Honeycomb can delete an existing vhost-user\
 130 | | ... | interface, role: client.
 131 | | ...
 132 | | Given vhost-user Operational Data From Honeycomb Should Be
 133 | | ... | ${node} | ${vhost_interface} | ${vhost_user_client}
 134 | | When Honeycomb removes vhost-user interface
 135 | | ... | ${node} | ${vhost_interface}
 136 | | Then vhost-user Operational Data From Honeycomb Should Be empty
 137 | | ... | ${node} | ${vhost_interface}
 138 | | And vhost-user Operational Data From VAT Should Be empty
 139 | | ... | ${node}
 140
 141 | TC07: Honeycomb does not set vhost-user configuration on another interface type
 142 | | [Documentation] | Check if Honeycomb refuses to set vhost-user\
 143 | | ... | configuration for interface which is not v3po:vhost-user type.
 144 | | ...
 145 | | When Honeycomb fails setting vhost-user on different interface type
 146 | | ... | ${node} | ${interface} | ${vhost_user_server}
 147 | | Then vhost-user Operational Data From Honeycomb Should Be empty
 148 | | ... | ${node} | ${interface}
 149 | | And vhost-user Operational Data From VAT Should Be empty
 150 | | ... | ${node}
 151
 152 | TC08: Honeycomb does not set invalid vhost-user configuration
 153 | | [Documentation] | Check if Honeycomb refuses to set invalid parameters to\
 154 | | ... | vhost-user interface.
 155 | | ...
 156 | | Given vhost-user Operational Data From Honeycomb Should Be empty
 157 | | ... | ${node} | ${vhost_interface}
 158 | | When Honeycomb fails setting invalid vhost-user configuration
 159 | | ... | ${node} | ${vhost_interface} | ${vhost_user_wrong}
 160 | | Then vhost-user Operational Data From Honeycomb Should Be empty
 161 | | ... | ${node} | ${vhost_interface}
 162 | | And vhost-user Operational Data From VAT Should Be empty
 163 | | ... | ${node}