tests/kubernetes/perf/container_memif/10ge2p1x710-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | L2BDMACLRN | L2BDBASE | SCALE | MEMIF
  19 | ... | K8S | 1VSWITCH | 2VNF | VPP_AGENT | SFC_CONTROLLER | HORIZONTAL
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L2 | ${nic_name}
  23 | Suite Teardown | Tear down suite | performance
  24 | ...
  25 | Test Setup | Set up performance test with Ligato Kubernetes
  26 | Test Teardown | Tear down test | ligato
  27 | ...
  28 | Test Template | Local Template
  29 | ...
  30 | Documentation | *RFC2544: Pkt throughput L2BD test cases*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 bridge domain.
  35 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with two L2
  36 | ... | bridge domains and MAC learning enabled. DUT1 and DUT2 tested with
  37 | ... | ${nic_name}.\
  38 | ... | VNF Containers are connected to VSWITCH container via Memif interface.
  39 | ... | All containers are running same VPP version. Containers are deployed
  40 | ... | with Kubernetes. Configuration is applied by vnf-agent.
  41 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  42 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  43 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  44 | ... | of packets transmitted. NDR and PDR are discovered for different\
  45 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  46 | ... | TG traffic profile contains two L3 flow-groups
  47 | ... | (flow-group per direction, 254 flows per flow-group) with all packets
  48 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
  49 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  50 | ... | interfaces.
  51 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  52
  53 *** Variables ***
  54 | ${nic_name}= | Intel-X710
  55 | ${overhead}= | ${0}
  56 # SFC profile
  57 | ${sfc_profile}= | configmaps/eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz
  58 # Traffic profile:
  59 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  60 # CPU settings
  61 | ${system_cpus}= | ${1}
  62 | ${vswitch_cpus}= | ${5}
  63 | ${vnf_cpus}= | ${2}
  64
  65 *** Keywords ***
  66 | Local Template
  67 | | [Documentation]
  68 | | ... | [Cfg] DUT runs Container orchestrated config.
  69 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  70 | | ...
  71 | | ... | *Arguments:*
  72 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  73 | | ... | Type: integer, string
  74 | | ... | - phy_cores - Number of physical cores. Type: integer
  75 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  76 | | ...
  77 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  78 | | ...
  79 | | Set Test Variable | \${frame_size}
  80 | | ...
  81 | | Set Max Rate And Jumbo
  82 | | ${dut1_if1_name}= | Get interface name | ${dut1} | ${dut1_if1}
  83 | | ${dut1_if2_name}= | Get interface name | ${dut1} | ${dut1_if2}
  84 | | ${dut2_if1_name}= | Get interface name | ${dut2} | ${dut2_if1}
  85 | | ${dut2_if2_name}= | Get interface name | ${dut2} | ${dut2_if2}
  86 | | ${tg_if1_mac}= | Get Interface MAC | ${tg} | ${tg_if1}
  87 | | ${tg_if2_mac}= | Get Interface MAC | ${tg} | ${tg_if2}
  88 | | Create Kubernetes VSWITCH startup config on all DUTs
  89 | | ... | ${phy_cores} | ${rxq} | ${jumbo}
  90 | | Create Kubernetes VNF'1' startup config on all DUTs
  91 | | Create Kubernetes VNF'2' startup config on all DUTs
  92 | | Create Kubernetes CM from file on all DUTs | ${nodes} | csit
  93 | | ... | name=vswitch-vpp-cfg | vpp.conf=/tmp/vswitch.conf
  94 | | Create Kubernetes CM from file on all DUTs | ${nodes} | csit
  95 | | ... | name=vnf1-vpp-cfg | vpp.conf=/tmp/vnf1.conf
  96 | | Create Kubernetes CM from file on all DUTs | ${nodes} | csit
  97 | | ... | name=vnf2-vpp-cfg | vpp.conf=/tmp/vnf2.conf
  98 | | Apply Kubernetes resource on node | ${dut1}
  99 | | ... | pods/contiv-vnf.yaml | $$VNF$$=vnf1
 100 | | Apply Kubernetes resource on node | ${dut2}
 101 | | ... | pods/contiv-vnf.yaml | $$VNF$$=vnf1
 102 | | Apply Kubernetes resource on node | ${dut1}
 103 | | ... | pods/contiv-vnf.yaml | $$VNF$$=vnf2
 104 | | Apply Kubernetes resource on node | ${dut2}
 105 | | ... | pods/contiv-vnf.yaml | $$VNF$$=vnf2
 106 | | Apply Kubernetes resource on node | ${dut1}
 107 | | ... | ${sfc_profile}.yaml | $$TEST_NAME$$=${TEST NAME}
 108 | | ... | $$VSWITCH_IF1$$=${dut1_if1_name}
 109 | | ... | $$VSWITCH_IF2$$=${dut1_if2_name}
 110 | | Apply Kubernetes resource on node | ${dut2}
 111 | | ... | ${sfc_profile}.yaml | $$TEST_NAME$$=${TEST NAME}
 112 | | ... | $$VSWITCH_IF1$$=${dut2_if1_name}
 113 | | ... | $$VSWITCH_IF2$$=${dut2_if2_name}
 114 | | Wait for Kubernetes PODs on all DUTs | ${nodes} | csit
 115 | | Set Kubernetes PODs affinity on all DUTs | ${nodes}
 116 | | Find NDR and PDR intervals using optimized search
 117
 118 *** Test Cases ***
 119 | tc01-64B-1c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 120 | | [Tags] | 64B | 1C
 121 | | frame_size=${64} | phy_cores=${1}
 122
 123 | tc02-64B-2c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 124 | | [Tags] | 64B | 2C
 125 | | frame_size=${64} | phy_cores=${2}
 126
 127 | tc03-64B-4c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 128 | | [Tags] | 64B | 4C
 129 | | frame_size=${64} | phy_cores=${4}
 130
 131 | tc04-1518B-1c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 132 | | [Tags] | 1518B | 1C
 133 | | frame_size=${1518} | phy_cores=${1}
 134
 135 | tc05-1518B-2c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 136 | | [Tags] | 1518B | 2C
 137 | | frame_size=${1518} | phy_cores=${2}
 138
 139 | tc06-1518B-4c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 140 | | [Tags] | 1518B | 4C
 141 | | frame_size=${1518} | phy_cores=${4}
 142
 143 | tc07-9000B-1c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 144 | | [Tags] | 9000B | 1C
 145 | | frame_size=${9000} | phy_cores=${1}
 146
 147 | tc08-9000B-2c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 148 | | [Tags] | 9000B | 2C
 149 | | frame_size=${9000} | phy_cores=${2}
 150
 151 | tc09-9000B-4c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 152 | | [Tags] | 9000B | 4C
 153 | | frame_size=${9000} | phy_cores=${4}
 154
 155 | tc10-IMIX-1c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 156 | | [Tags] | IMIX | 1C
 157 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 158
 159 | tc11-IMIX-2c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 160 | | [Tags] | IMIX | 2C
 161 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 162
 163 | tc12-IMIX-4c-eth-1drcl2bdbasemaclrn-eth-2memif-2drcl2xc-1horiz-k8s-ndrpdr
 164 | | [Tags] | IMIX | 4C
 165 | | frame_size=IMIX_v4_1 | phy_cores=${4}