tests/perf/Long_Bridge_Domain_Intel-X710-DA2.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance.robot
  16 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | PERFTEST_LONG
  17 | ... | NIC_Intel-X710
  18 | Suite Setup | 3-node Performance Suite Setup with DUT's NIC model
  19 | ... | L2 | Intel-X710
  20 | Suite Teardown | 3-node Performance Suite Teardown
  21 | Test Setup | Setup all DUTs before test
  22 | Test Teardown | Run Keywords
  23 | ...           | Run Keyword If Test Failed
  24 | ...           | Traffic should pass with no loss | 10
  25 | ...           | ${min_rate}pps | ${framesize} | 3-node-bridge
  26 | ...           | fail_on_loss=${False}
  27 | ...           | AND | Remove startup configuration of VPP from all DUTs
  28 | ...           | AND | Show vpp trace dump on all DUTs
  29 | Documentation | *RFC2544: Pkt throughput L2BD test cases*
  30 | ...
  31 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  32 | ... | with single links between nodes.
  33 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  34 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-\
  35 | ... | domain and MAC learning enabled. DUT1 and DUT2 tested with 2p10GE NIC
  36 | ... | X710 by Intel.
  37 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  38 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  39 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  40 | ... | of packets transmitted. NDR and PDR are discovered for different\
  41 | ... | Ethernet L2 frame sizes using either binary search or linear search\
  42 | ... | algorithms with configured starting rate and final step that determines\
  43 | ... | throughput measurement resolution. Test packets are generated by TG on\
  44 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  45 | ... | (flow-group per direction, 253 flows per flow-group) with all packets\
  46 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static\
  47 | ... | payload. MAC addresses are matching MAC addresses of the TG node\
  48 | ... | interfaces.
  49 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  50
  51 *** Variables ***
  52 #X710 bandwidth limit
  53 | ${s_limit} | ${10000000000}
  54
  55 *** Keywords ***
  56 | L2 Bridge Domain NDR Binary Search
  57 | | [Arguments] | ${framesize} | ${min_rate} | ${wt} | ${rxq}
  58 | | # Test Variables required for test teardown
  59 | | Set Test Variable | ${framesize}
  60 | | Set Test Variable | ${min_rate}
  61 | | ${max_rate}= | Calculate pps | ${s_limit} | ${framesize}
  62 | | ${binary_min}= | Set Variable | ${min_rate}
  63 | | ${binary_max}= | Set Variable | ${max_rate}
  64 | | ${threshold}= | Set Variable | ${min_rate}
  65 | | Set Test Documentation | [Cfg] DUT runs L2BD switching config with ${wt}\
  66 | | Set Test Documentation | thread, ${wt} phy core, ${rxq}\ | append=True
  67 | | Set Test Documentation | receive queue per NIC port. | append=True
  68 | | Set Test Documentation | [Ver] Find NDR for ${framesize} Byte\ | append=True
  69 | | Set Test Documentation | frames using binary search start at\ | append=True
  70 | | Set Test Documentation | 10GE linerate, step ${threshold}pps. | append=True
  71 | | Add '${wt}' worker threads and rxqueues '${rxq}' in 3-node single-link topo
  72 | | Add PCI devices to DUTs from 3-node single link topology
  73 | | Run Keyword If | ${framesize} < ${1522} | Add No Multi Seg to all DUTs
  74 | | Apply startup configuration on all VPP DUTs
  75 | | L2 bridge domain initialized in a 3-node circular topology
  76 | | Find NDR using binary search and pps
  77 | | ... | ${framesize} | ${binary_min} | ${binary_max} | 3-node-bridge
  78 | | ... | ${min_rate} | ${max_rate} | ${threshold}
  79
  80 | L2 Bridge Domain PDR Binary Search
  81 | | [Arguments] | ${framesize} | ${min_rate} | ${wt} | ${rxq}
  82 | | # Test Variables required for test teardown
  83 | | Set Test Variable | ${framesize}
  84 | | Set Test Variable | ${min_rate}
  85 | | ${max_rate}= | Calculate pps | ${s_limit} | ${framesize}
  86 | | ${binary_min}= | Set Variable | ${min_rate}
  87 | | ${binary_max}= | Set Variable | ${max_rate}
  88 | | ${threshold}= | Set Variable | ${min_rate}
  89 | | Set Test Documentation | [Cfg] DUT runs L2BD switching config with ${wt}\
  90 | | Set Test Documentation | thread, ${wt} phy core, ${rxq}\ | append=True
  91 | | Set Test Documentation | receive queue per NIC port. | append=True
  92 | | Set Test Documentation | [Ver] Find PDR for ${framesize} Byte\ | append=True
  93 | | Set Test Documentation | frames using binary search start at\ | append=True
  94 | | Set Test Documentation | 10GE linerate, step ${threshold}pps, | append=True
  95 | | Set Test Documentation | LT=${glob_loss_acceptance} | append=True
  96 | | Set Test Documentation | ${glob_loss_acceptance_type}. | append=True
  97 | | Add '${wt}' worker threads and rxqueues '${rxq}' in 3-node single-link topo
  98 | | Add PCI devices to DUTs from 3-node single link topology
  99 | | Run Keyword If | ${framesize} < ${1522} | Add No Multi Seg to all DUTs
 100 | | Apply startup configuration on all VPP DUTs
 101 | | L2 bridge domain initialized in a 3-node circular topology
 102 | | Find PDR using binary search and pps
 103 | | ... | ${framesize} | ${binary_min} | ${binary_max} | 3-node-bridge
 104 | | ... | ${min_rate} | ${max_rate} | ${threshold}
 105 | | ... | ${glob_loss_acceptance} | ${glob_loss_acceptance_type}
 106
 107 *** Test Cases ***
 108 | TC01: 64B NDR binary search - DUT L2BD - 1thread 1core 1rxq
 109 | | ... | ${64} | ${100000} | 1 | 1
 110 | | [Tags] | 1_THREAD_NOHTT_RXQUEUES_1 | SINGLE_THREAD | NDR
 111 | | [Template] | L2 Bridge Domain NDR Binary Search
 112
 113 | TC02: 64B PDR binary search - DUT L2BD - 1thread 1core 1rxq
 114 | | ... | ${64} | ${100000} | 1 | 1
 115 | | [Tags] | 1_THREAD_NOHTT_RXQUEUES_1 | SINGLE_THREAD | PDR | SKIP_PATCH
 116 | | [Template] | L2 Bridge Domain PDR Binary Search
 117
 118 | TC03: 1518B NDR binary search - DUT L2BD - 1thread 1core 1rxq
 119 | | ... | ${1518} | ${10000} | 1 | 1
 120 | | [Tags] | 1_THREAD_NOHTT_RXQUEUES_1 | SINGLE_THREAD | NDR
 121 | | [Template] | L2 Bridge Domain NDR Binary Search
 122
 123 | TC04: 1518B PDR binary search - DUT L2BD - 1thread 1core 1rxq
 124 | | ... | ${1518} | ${10000} | 1 | 1
 125 | | [Tags] | 1_THREAD_NOHTT_RXQUEUES_1 | SINGLE_THREAD | PDR | SKIP_PATCH
 126 | | [Template] | L2 Bridge Domain PDR Binary Search
 127
 128 | TC05: 9000B NDR binary search - DUT L2BD - 1thread 1core 1rxq
 129 | | ... | ${9000} | ${10000} | 1 | 1
 130 | | [Tags] | 1_THREAD_NOHTT_RXQUEUES_1 | SINGLE_THREAD | NDR
 131 | | [Template] | L2 Bridge Domain NDR Binary Search
 132
 133 | TC06: 9000B PDR binary search - DUT L2BD - 1thread 1core 1rxq
 134 | | ... | ${9000} | ${10000} | 1 | 1
 135 | | [Tags] | 1_THREAD_NOHTT_RXQUEUES_1 | SINGLE_THREAD | PDR | SKIP_PATCH
 136 | | [Template] | L2 Bridge Domain PDR Binary Search
 137
 138 | TC07: 64B NDR binary search - DUT L2BD - 2thread 2core 1rxq
 139 | | ... | ${64} | ${100000} | 2 | 1
 140 | | [Tags] | 2_THREAD_NOHTT_RXQUEUES_1 | MULTI_THREAD | NDR
 141 | | [Template] | L2 Bridge Domain NDR Binary Search
 142
 143 | TC08: 64B PDR binary search - DUT L2BD - 2thread 2core 1rxq
 144 | | ... | ${64} | ${100000} | 2 | 1
 145 | | [Tags] | 2_THREAD_NOHTT_RXQUEUES_1 | MULTI_THREAD | PDR | SKIP_PATCH
 146 | | [Template] | L2 Bridge Domain PDR Binary Search
 147
 148 | TC09: 1518B NDR binary search - DUT L2BD - 2thread 2core 1rxq
 149 | | ... | ${1518} | ${10000} | 2 | 1
 150 | | [Tags] | 2_THREAD_NOHTT_RXQUEUES_1 | MULTI_THREAD | NDR | SKIP_PATCH
 151 | | [Template] | L2 Bridge Domain NDR Binary Search
 152
 153 | TC10: 1518B PDR binary search - DUT L2BD - 2thread 2core 1rxq
 154 | | ... | ${1518} | ${10000} | 2 | 1
 155 | | [Tags] | 2_THREAD_NOHTT_RXQUEUES_1 | MULTI_THREAD | PDR | SKIP_PATCH
 156 | | [Template] | L2 Bridge Domain PDR Binary Search
 157
 158 | TC11: 9000B NDR binary search - DUT L2BD - 2thread 2core 1rxq
 159 | | ... | ${9000} | ${10000} | 2 | 1
 160 | | [Tags] | 2_THREAD_NOHTT_RXQUEUES_1 | MULTI_THREAD | NDR | SKIP_PATCH
 161 | | [Template] | L2 Bridge Domain NDR Binary Search
 162
 163 | TC12: 9000B PDR binary search - DUT L2BD - 2thread 2core 1rxq
 164 | | ... | ${9000} | ${10000} | 2 | 1
 165 | | [Tags] | 2_THREAD_NOHTT_RXQUEUES_1 | MULTI_THREAD | PDR | SKIP_PATCH
 166 | | [Template] | L2 Bridge Domain PDR Binary Search
 167
 168 | TC13: 64B NDR binary search - DUT L2BD - 4thread 4core 2rxq
 169 | | ... | ${64} | ${100000} | 4 | 2
 170 | | [Tags] | 4_THREAD_NOHTT_RXQUEUES_2 | MULTI_THREAD | NDR
 171 | | [Template] | L2 Bridge Domain NDR Binary Search
 172
 173 | TC14: 64B PDR binary search - DUT L2BD - 4thread 4core 2rxq
 174 | | ... | ${64} | ${100000} | 4 | 2
 175 | | [Tags] | 4_THREAD_NOHTT_RXQUEUES_2 | MULTI_THREAD | PDR | SKIP_PATCH
 176 | | [Template] | L2 Bridge Domain PDR Binary Search
 177
 178 | TC15: 1518B NDR binary search - DUT L2BD - 4thread 4core 2rxq
 179 | | ... | ${1518} | ${10000} | 4 | 2
 180 | | [Tags] | 4_THREAD_NOHTT_RXQUEUES_2 | MULTI_THREAD | NDR | SKIP_PATCH
 181 | | [Template] | L2 Bridge Domain NDR Binary Search
 182
 183 | TC16: 1518B PDR binary search - DUT L2BD - 4thread 4core 2rxq
 184 | | ... | ${1518} | ${10000} | 4 | 2
 185 | | [Tags] | 4_THREAD_NOHTT_RXQUEUES_2 | MULTI_THREAD | PDR | SKIP_PATCH
 186 | | [Template] | L2 Bridge Domain PDR Binary Search
 187
 188 | TC17: 9000B NDR binary search - DUT L2BD - 4thread 4core 2rxq
 189 | | ... | ${9000} | ${10000} | 4 | 2
 190 | | [Tags] | 4_THREAD_NOHTT_RXQUEUES_2 | MULTI_THREAD | NDR | SKIP_PATCH
 191 | | [Template] | L2 Bridge Domain NDR Binary Search
 192
 193 | TC18: 9000B PDR binary search - DUT L2BD - 4thread 4core 2rxq
 194 | | ... | ${9000} | ${10000} | 4 | 2
 195 | | [Tags] | 4_THREAD_NOHTT_RXQUEUES_2 | MULTI_THREAD | PDR | SKIP_PATCH
 196 | | [Template] | L2 Bridge Domain PDR Binary Search