tests/suites/bridge_domain/test.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/default.robot
  16 | Resource | resources/libraries/robot/interfaces.robot
  17 | Resource | resources/libraries/robot/bridge_domain.robot
  18 | Resource | resources/libraries/robot/l2_traffic.robot
  19 | Library | resources.libraries.python.NodePath
  20 | Force Tags | HW_ENV | VM_ENV
  21 | Suite Setup | Setup all TGs before traffic script
  22 | Test Setup | Setup all DUTs before test
  23
  24 *** Test Cases ***
  25 | VPP reports interfaces
  26 | | [Tags] | 3_NODE_DOUBLE_LINK_TOPO | 3_NODE_SINGLE_LINK_TOPO
  27 | | VPP reports interfaces on | ${nodes['DUT1']}
  28
  29 | Vpp forwards packets via L2 bridge domain 2 ports
  30 | | [Tags] | 3_NODE_DOUBLE_LINK_TOPO
  31 | | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
  32 | | Compute Path | always_same_link=${FALSE}
  33 | | ${tg_if1} | ${tmp}= | First Interface
  34 | | ${tg_if2} | ${tmp}= | Last Interface
  35 | | ${bd_if1} | ${tmp}= | First Ingress Interface
  36 | | ${bd_if2} | ${tmp}= | Last Egress Interface
  37 | | Vpp l2bd forwarding setup | ${nodes['DUT1']} | ${bd_if1} | ${bd_if2}
  38 | | Send and receive ICMPv4 bidirectionally | ${nodes['TG']} | ${tg_if1} | ${tg_if2}
  39
  40 | Vpp forwards packets via L2 bridge domain in circular topology
  41 | | [Tags] | 3_NODE_SINGLE_LINK_TOPO
  42 | | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']}
  43 | | ...          | ${nodes['TG']}
  44 | | Compute Path
  45 | | ${tg_if1} | ${tg}= | Next Interface
  46 | | ${dut1_if1} | ${dut1}= | Next Interface
  47 | | ${dut1_if2} | ${dut1}= | Next Interface
  48 | | ${dut2_if1} | ${dut2}= | Next Interface
  49 | | ${dut2_if2} | ${dut2}= | Next Interface
  50 | | ${tg_if2} | ${tg}= | Next Interface
  51 | | Vpp l2bd forwarding setup | ${dut1} | ${dut1_if1} | ${dut1_if2}
  52 | | Vpp l2bd forwarding setup | ${dut2} | ${dut2_if1} | ${dut2_if2}
  53 | | Send and receive ICMPv4 bidirectionally | ${tg} | ${tg_if1} | ${tg_if2}
  54
  55 | Vpp forwards packets via L2 bridge domain in circular topology with static L2FIB entries
  56 | | [Tags] | 3_NODE_SINGLE_LINK_TOPO
  57 | | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']}
  58 | | ...          | ${nodes['TG']}
  59 | | Compute Path
  60 | | ${tg_if1} | ${tg}= | Next Interface
  61 | | ${dut1_if1} | ${dut1}= | Next Interface
  62 | | ${dut1_if2} | ${dut1}= | Next Interface
  63 | | ${dut2_if1} | ${dut2}= | Next Interface
  64 | | ${dut2_if2} | ${dut2}= | Next Interface
  65 | | ${tg_if2} | ${tg}= | Next Interface
  66 | | ${mac}= | Get Interface Mac | ${tg} | ${tg_if2}
  67 | | Vpp l2bd forwarding setup | ${dut1} | ${dut1_if1} | ${dut1_if2} | ${FALSE}
  68 | | ...                       | ${mac}
  69 | | Vpp l2bd forwarding setup | ${dut2} | ${dut2_if1} | ${dut2_if2} | ${FALSE}
  70 | | ...                       | ${mac}
  71 | | Send and receive ICMPv4 bidirectionally | ${tg} | ${tg_if1} | ${tg_if2}