tests/suites/honeycomb/2 - vxlan.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 # Node and interfaces to run tests on.
  16 | ${node}= | ${nodes['DUT1']}
  17 | ${interface}= | ${node['interfaces']['port1']['name']}
  18 | ${vx_interface}= | vx_tunnel_test
  19 # Configuration which will be set and verified during tests.
  20 | &{vxlan_settings}= | src=192.168.0.2 | dst=192.168.0.3 | vni=${88}
  21 | ... | encap-vrf-id=${0}
  22 | &{vxlan_settings2}= | src=192.168.0.4 | dst=192.168.0.5 | vni=${47}
  23 | ... | encap-vrf-id=${0}
  24 | &{vxlan_settings_ipv6}= | src=10::10 | dst=10::11 | vni=${88}
  25 | ... | encap-vrf-id=${0}
  26 | &{vxlan_settings_ipv6_long}= | src=10:0:0:0:0:0:0:10 | dst=10:0:0:0:0:0:0:11
  27 | ... | vni=${88} | encap-vrf-id=${0}
  28
  29 *** Settings ***
  30 | Resource | resources/libraries/robot/default.robot
  31 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  32 | Resource | resources/libraries/robot/honeycomb/vxlan.robot
  33 # import additional VxLAN settings from resource file
  34 | Variables | tests/suites/honeycomb/resources/vxlan.py
  35 | Documentation | *Honeycomb VxLAN management test suite.*
  36 | ...
  37 | ... | Test suite uses the first interface of the first DUT node.
  38
  39 *** Test Cases ***
  40 | Honeycomb configures VxLAN tunnel
  41 | | [Documentation] | Check if Honeycomb API can configure VxLAN settings.
  42 | | [Tags] | honeycomb_sanity
  43 | | Given VxLAN configuration from Honeycomb should be empty
  44 | | ... | ${node} | ${vx_interface}
  45 | | And VxLAN configuration from VAT should be empty | ${node}
  46 | | When Honeycomb sets interface VxLAN configuration
  47 | | ... | ${node} | ${vx_interface} | ${vxlan_settings}
  48 | | Then VxLAN configuration from Honeycomb should be
  49 | | ... | ${node} | ${vx_interface} | ${vxlan_settings}
  50 | | And VxLAN configuration from VAT should be
  51 | | ... | ${node} | ${vxlan_settings}
  52
  53 | Honeycomb disables VxLAN tunnel
  54 | | [Documentation] | Check if Honeycomb API can reset VxLAN configuration.
  55 | | [Tags] | honeycomb_sanity
  56 | | Given VxLAN configuration from Honeycomb should be
  57 | | ... | ${node} | ${vx_interface} | ${vxlan_settings}
  58 | | And VxLAN configuration from VAT should be
  59 | | ... | ${node} | ${vxlan_settings}
  60 | | When Honeycomb removes VxLAN tunnel settings | ${node} | ${vx_interface}
  61 | | Then VxLAN configuration from Honeycomb should be empty
  62 | | ... | ${node} | ${vx_interface}
  63 | | And VxLAN configuration from VAT should be empty | ${node}
  64
  65 Honeycomb can configure VXLAN tunnel after one has been disabled
  66 | | [Documentation] | Check if Honeycomb API can configure VxLAN settings again\
  67 | | ... | after previous settings have been removed.
  68 | | [Tags] | honeycomb_sanity
  69 | | [Teardown] | Honeycomb removes VxLAN tunnel settings
  70 | | ... | ${node} | ${vx_interface}
  71 | | Given VxLAN configuration from Honeycomb should be empty
  72 | | ... | ${node} | ${vx_interface}
  73 | | And VxLAN configuration from VAT should be empty | ${node}
  74 | | When Honeycomb sets interface VxLAN configuration
  75 | | ... | ${node} | ${vx_interface} | ${vxlan_settings2}
  76 | | Then VxLAN configuration from Honeycomb should be
  77 | | ... | ${node} | ${vx_interface} | ${vxlan_settings2}
  78 | | And VxLAN configuration from VAT should be
  79 | | ... | ${node} | ${vxlan_settings2}
  80
  81 | Honeycomb does not set VxLAN configuration on another interface type
  82 | | [Documentation] | Check if Honeycomb API prevents setting VxLAN\
  83 | | ... | on incorrect interface.
  84 | | [Tags] | honeycomb_sanity
  85 | | Given VxLAN configuration from Honeycomb should be empty
  86 | | ... | ${node} | ${interface}
  87 | | And VxLAN configuration from VAT should be empty | ${node}
  88 | | When Honeycomb fails setting VxLan on different interface type
  89 | | ... | ${node} | ${interface} | ${vxlan_settings2}
  90 | | Then VxLAN configuration from Honeycomb should be empty
  91 | | ... | ${node} | ${interface}
  92 | | And VxLAN configuration from VAT should be empty
  93 | | ... | ${node}
  94
  95 | Honeycomb does not set invalid VxLAN configuration
  96 | | [Documentation] | Check if Honeycomb API prevents setting incorrect VxLAN\
  97 | | ... | settings.
  98 | | [Tags] | honeycomb_sanity
  99 | | Given VxLAN configuration from Honeycomb should be empty
 100 | | ... | ${node} | ${vx_interface}
 101 | | And VxLAN configuration from VAT should be empty | ${node}
 102 | | When Honeycomb fails setting invalid VxLAN configuration
 103 | | ... | ${node} | ${vx_interface} | ${vxlan_invalid}
 104 | | Then VxLAN configuration from Honeycomb should be empty
 105 | | ... | ${node} | ${vx_interface}
 106
 107 | Honeycomb configures VxLAN tunnel with ipv6
 108 | | [Documentation] | Check if Honeycomb API can configure VxLAN with\
 109 | | ... | ipv6 settings.
 110 | | [Tags] | honeycomb_sanity
 111 | | [Teardown] | Honeycomb removes VxLAN tunnel settings
 112 | | ... | ${node} | ${vx_interface}
 113 | | Given VxLAN configuration from Honeycomb should be empty
 114 | | ... | ${node} | ${vx_interface}
 115 | | And VxLAN configuration from VAT should be empty | ${node}
 116 | | When Honeycomb sets interface VxLAN configuration
 117 | | ... | ${node} | ${vx_interface} | ${vxlan_settings_ipv6}
 118 | | Then VxLAN configuration from Honeycomb should be
 119 | | ... | ${node} | ${vx_interface} | ${vxlan_settings_ipv6_long}
 120 | | And VxLAN configuration from VAT should be
 121 | | ... | ${node} | ${vxlan_settings_ipv6}