tests/suites/honeycomb/2 - vxlan.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 # Node and interfaces to run tests on.
  16 | ${node}= | ${nodes['DUT1']}
  17 | ${interface}= | ${node['interfaces'].values()[0]['name']}
  18 | ${vx_interface}= | vx_tunnel_test
  19 # Configuration which will be set and verified during tests.
  20 | &{vxlan_settings}= | src=192.168.0.2 | dst=192.168.0.3 | vni=${88}
  21 | ... | encap-vrf-id=${0}
  22 | &{vxlan_settings2}= | src=192.168.0.4 | dst=192.168.0.5 | vni=${47}
  23 | ... | encap-vrf-id=${0}
  24 | &{vxlan_settings_ipv6}= | src=10::10 | dst=10::11 | vni=${88}
  25 | ... | encap-vrf-id=${0}
  26
  27 *** Settings ***
  28 | Resource | resources/libraries/robot/default.robot
  29 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  30 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  31 | Resource | resources/libraries/robot/honeycomb/vxlan.robot
  32 # import additional VxLAN settings from resource file
  33 | Variables | tests/suites/honeycomb/resources/vxlan.py
  34 | Documentation | *Honeycomb VxLAN management test suite.*
  35 | ...
  36 | ... | Test suite uses the first interface of the first DUT node.
  37
  38 *** Test Cases ***
  39 | Honeycomb configures VxLAN tunnel
  40 | | [Documentation] | Check if Honeycomb API can configure VxLAN settings.
  41 | | [Tags] | honeycomb_sanity
  42 | | Given VxLAN configuration from Honeycomb should be empty
  43 | | ... | ${node} | ${vx_interface}
  44 | | When Honeycomb sets interface VxLAN configuration
  45 | | ... | ${node} | ${vx_interface} | ${vxlan_settings}
  46 | | Then VxLAN configuration from Honeycomb should be
  47 | | ... | ${node} | ${vx_interface} | ${vxlan_settings}
  48 | | And VxLAN configuration from VAT should be
  49 | | ... | ${node} | ${vxlan_settings}
  50
  51 | Honeycomb disables VxLAN tunnel
  52 | | [Documentation] | Check if Honeycomb API can reset VxLAN configuration.
  53 | | [Tags] | honeycomb_sanity
  54 | | Given VxLAN configuration from Honeycomb should be
  55 | | ... | ${node} | ${vx_interface} | ${vxlan_settings}
  56 | | When Honeycomb removes VxLAN tunnel settings | ${node} | ${vx_interface}
  57 | | Then VxLAN configuration from Honeycomb should be empty
  58 | | ... | ${node} | ${vx_interface}
  59 | | And VxLAN configuration from VAT should be empty | ${node}
  60
  61 | Honeycomb does not set VxLAN configuration on another interface type
  62 | | [Documentation] | Check if Honeycomb API prevents setting VxLAN\
  63 | | ... | on incorrect interface.
  64 | | [Tags] | honeycomb_sanity
  65 | | Given VxLAN configuration from Honeycomb should be empty
  66 | | ... | ${node} | ${interface}
  67 | | And VxLAN configuration from VAT should be empty | ${node}
  68 | | When Honeycomb fails setting VxLan on different interface type
  69 | | ... | ${node} | ${interface} | ${vxlan_settings2}
  70 | | Then VxLAN configuration from Honeycomb should be empty
  71 | | ... | ${node} | ${interface}
  72 | | And VxLAN configuration from VAT should be empty
  73 | | ... | ${node}
  74
  75 | Honeycomb does not set invalid VxLAN configuration
  76 | | [Documentation] | Check if Honeycomb API prevents setting incorrect VxLAN\
  77 | | ... | settings.
  78 | | [Tags] | honeycomb_sanity
  79 | | Given VxLAN configuration from Honeycomb should be empty
  80 | | ... | ${node} | ${vx_interface}
  81 | | And VxLAN configuration from VAT should be empty | ${node}
  82 | | When Honeycomb fails setting invalid VxLAN configuration
  83 | | ... | ${node} | ${vx_interface} | ${vxlan_invalid}
  84 | | Then VxLAN configuration from Honeycomb should be empty
  85 | | ... | ${node} | ${vx_interface}
  86
  87 | Honeycomb configures VxLAN tunnel with ipv6
  88 | | [Documentation] | Check if Honeycomb API can configure VxLAN with\
  89 | | ... | ipv6 settings.
  90 | | [Tags] | honeycomb_sanity
  91 | | Given VxLAN configuration from Honeycomb should be empty
  92 | | ... | ${node} | ${vx_interface}
  93 | | And VxLAN configuration from VAT should be empty | ${node}
  94 | | When Honeycomb sets interface VxLAN configuration
  95 | | ... | ${node} | ${vx_interface} | ${vxlan_settings_ipv6}
  96 | | Then VxLAN configuration from Honeycomb should be
  97 | | ... | ${node} | ${vx_interface} | ${vxlan_settings_ipv6}
  98 | | And VxLAN configuration from VAT should be
  99 | | ... | ${node} | ${vxlan_settings_ipv6}
 100