tests/suites/honeycomb/3 - bridge_domain.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 # Node and interfaces to run tests on.
  16 | ${node}= | ${nodes['DUT1']}
  17 | @{interfaces}= | ${node['interfaces'].values()[0]['name']}
  18 | ... | ${node['interfaces'].values()[1]['name']}
  19 # Configuration which will be set and verified during tests.
  20 | ${bd1_name}= | bd-01
  21 | ${bd2_name}= | bd-02
  22 | &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
  23 | ... | unknown-unicast-flood=${True} | arp-termination=${True}
  24 | &{if_settings}= | split_horizon_group=${1} | bvi=${True}
  25
  26 *** Settings ***
  27 | Resource | resources/libraries/robot/default.robot
  28 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  29 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  30 | Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
  31 | Suite Teardown | Stop Honeycomb service on DUTs | ${node}
  32 | Documentation | *Honeycomb bridge domain management test suite.*
  33 | ...
  34 | ... | Test suite uses the first two interfaces on the first DUT node.
  35
  36 *** Test Cases ***
  37 | Honeycomb sets up l2 bridge domain
  38 | | [Documentation] | Check if Honeycomb can create bridge domains on VPP node.
  39 | | [Tags] | honeycomb_sanity
  40 | | When Honeycomb creates first l2 bridge domain
  41 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  42 | | Then Bridge domain configuration from Honeycomb should be
  43 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  44 | | And Bridge domain configuration from VAT should be
  45 | | ... | ${node} | ${0} | ${bd_settings}
  46
  47 | Honeycomb assigns interfaces to bridge domain
  48 | | [Documentation] | Check if Honeycomb can assign VPP interfaces to an\
  49 | | ... | existing bridge domain.
  50 | | [Tags] | honeycomb_sanity
  51 | | Given Bridge domain configuration from Honeycomb should be
  52 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  53 | | When Honeycomb adds interfaces to bridge domain
  54 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  55 | | Then Honeycomb should show interfaces assigned to bridge domain
  56 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  57 | | And VAT should show interfaces assigned to bridge domain
  58 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings}
  59
  60 | Honeycomb manages multiple bridge domains on node
  61 | | [Documentation] | Check if Honeycomb can manage multiple bridge domains on\
  62 | | ... | a single node.
  63 | | [Tags] | honeycomb_sanity
  64 | | Given Bridge domain configuration from Honeycomb should be
  65 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  66 | | When Honeycomb creates l2 bridge domain
  67 | | ... | ${node} | ${bd2_name} | ${bd_settings}
  68 | | Then Bridge domain configuration from Honeycomb should be
  69 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  70 | | And Bridge domain configuration from Honeycomb should be
  71 | | ... | ${node} | ${bd2_name} | ${bd_settings}
  72 | | And Bridge domain configuration from VAT should be
  73 | | ... | ${node} | ${0} | ${bd_settings}
  74 | | And Bridge domain configuration from VAT should be
  75 | | ... | ${node} | ${1} | ${bd_settings}
  76
  77 | Honeycomb removes bridge domains
  78 | | [Documentation] | Check if Honeycomb can remove bridge domains from a VPP\
  79 | | ... | node.
  80 | | [Tags] | honeycomb_sanity
  81 | | Given Bridge domain configuration from Honeycomb should be
  82 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  83 | | When Honeycomb removes all bridge domains | ${node}
  84 | | Then Honeycomb should show no bridge domains | ${node}
  85 | | And VAT should show no bridge domains | ${node}