tests/suites/honeycomb/3 - bridge_domain.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 # Node and interfaces to run tests on.
  16 | ${node}= | ${nodes['DUT1']}
  17 | @{interfaces}= | ${node['interfaces']['port1']['name']}
  18 | ... | ${node['interfaces']['port3']['name']}
  19 # Configuration which will be set and verified during tests.
  20 | ${bd1_name}= | bd-01
  21 | ${bd2_name}= | bd-02
  22 | &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
  23 | ... | unknown-unicast-flood=${True} | arp-termination=${True}
  24 | &{if_settings}= | split_horizon_group=${1} | bvi=${False}
  25 | &{if_settings2}= | split_horizon_group=${2} | bvi=${True}
  26
  27 *** Settings ***
  28 | Resource | resources/libraries/robot/default.robot
  29 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  30 | Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
  31 | Suite Teardown | Honeycomb removes all bridge domains | ${node}
  32 | Force Tags | honeycomb_sanity
  33 | Documentation | *Honeycomb bridge domain management test suite.*
  34 | ...
  35 | ... | Test suite uses the first two interfaces on the first DUT node.
  36
  37 *** Test Cases ***
  38 | Honeycomb sets up l2 bridge domain
  39 | | [Documentation] | Check if Honeycomb can create bridge domains on VPP node.
  40 | | When Honeycomb creates first l2 bridge domain
  41 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  42 | | Then Bridge domain configuration from Honeycomb should be
  43 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  44 | | And Bridge domain configuration from VAT should be
  45 | | ... | ${node} | ${0} | ${bd_settings}
  46
  47 | Honeycomb manages multiple bridge domains on node
  48 | | [Documentation] | Check if Honeycomb can manage multiple bridge domains on\
  49 | | ... | a single node.
  50 | | Given Bridge domain configuration from Honeycomb should be
  51 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  52 | | When Honeycomb creates l2 bridge domain
  53 | | ... | ${node} | ${bd2_name} | ${bd_settings}
  54 | | Then Bridge domain configuration from Honeycomb should be
  55 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  56 | | And Bridge domain configuration from Honeycomb should be
  57 | | ... | ${node} | ${bd2_name} | ${bd_settings}
  58 | | And Bridge domain configuration from VAT should be
  59 | | ... | ${node} | ${0} | ${bd_settings}
  60 | | And Bridge domain configuration from VAT should be
  61 | | ... | ${node} | ${1} | ${bd_settings}
  62
  63 | Honeycomb removes bridge domains
  64 | | [Documentation] | Check if Honeycomb can remove bridge domains from a VPP\
  65 | | ... | node.
  66 | | Given Bridge domain configuration from Honeycomb should be
  67 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  68 | | When Honeycomb removes all bridge domains | ${node}
  69 | | Then Honeycomb should show no bridge domains | ${node}
  70 | | And VAT should show no bridge domains | ${node}
  71
  72 | Honeycomb assigns interfaces to bridge domain
  73 | | [Documentation] | Check if Honeycomb can assign VPP interfaces to an\
  74 | | ... | existing bridge domain.
  75 | | Given Honeycomb creates first l2 bridge domain
  76 | | ... | ${node} | ${bd1_name} | ${bd_settings}
  77 | | When Honeycomb adds interfaces to bridge domain
  78 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  79 | | Then Honeycomb should show interfaces assigned to bridge domain
  80 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  81 | | And VAT should show interfaces assigned to bridge domain
  82 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings}
  83
  84 | Honeycomb removes bridge domain with an interface assigned
  85 | | [Documentation] | Check if Honeycomb can remove a bridge domain that has an\
  86 | | ... | interface assigned to it.
  87 | | Given Honeycomb should show interfaces assigned to bridge domain
  88 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings}
  89 | | And VAT should show interfaces assigned to bridge domain
  90 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings}
  91 | | When Honeycomb removes all bridge domains | ${node}
  92 | | Then Honeycomb should show no bridge domains | ${node}
  93 | | And VAT should show no bridge domains | ${node}
  94
  95 | Honeycomb does not assign two bridged virtual interfaces to one bridge domain.
  96 | | [Documentation] | Check if Honeycomb can assign two bridged virtual\
  97 | | ... | interfaces to a single bridge domain, and expect to fail.
  98 | | [Teardown] | Honeycomb removes all bridge domains | ${node}
  99 | | Given Honeycomb creates first l2 bridge domain
 100 | | ... | ${node} | ${bd1_name} | ${bd_settings}
 101 | | When Honeycomb fails to add interfaces to bridge domain
 102 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings2}
 103 | | Then Honeycomb should not show interfaces assigned to bridge domain
 104 | | ... | ${node} | @{interfaces} | ${bd1_name} | ${if_settings2}
 105 | | And VAT should not show interfaces assigned to bridge domain
 106 | | ... | ${node} | ${0} | @{interfaces} | ${if_settings2}