tests/suites/honeycomb/4 - tap.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 # Node and interfaces to run tests on.
  16 | ${node}= | ${nodes['DUT1']}
  17 | ${interface}= | ${node['interfaces']['port1']['name']}
  18 | ${tap_interface}= | tap_test
  19 # Configuration which will be set and verified during tests.
  20 | &{tap_settings}= | tap-name=tap_test | mac=08:00:27:c0:5d:37
  21 | ... | device-instance=${1}
  22 | &{tap_settings2}= | tap-name=tap_test | mac=08:00:27:60:26:ab
  23 | ... | device-instance=${2}
  24
  25 *** Settings ***
  26 | Resource | resources/libraries/robot/default.robot
  27 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  28 | Resource | resources/libraries/robot/honeycomb/tap.robot
  29 | Force Tags | honeycomb_sanity
  30 | Documentation | *Honeycomb TAP management test suite.*
  31 | ...
  32 | ... | Test suite uses the first interface of the first DUT node.
  33
  34 *** Test Cases ***
  35 | Honeycomb configures TAP interface
  36 | | [Documentation] | Check if Honeycomb API can configure a TAP interface.
  37 | | Given TAP configuration from Honeycomb should be empty
  38 | | ... | ${node} | ${tap_interface}
  39 | | And TAP configuration from VAT should be empty
  40 | | ... | ${node} | ${tap_interface}
  41 | | When Honeycomb creates TAP interface
  42 | | ... | ${node} | ${tap_interface} | ${tap_settings}
  43 | | Then TAP configuration from Honeycomb should be
  44 | | ... | ${node} | ${tap_interface} | ${tap_settings}
  45 | | And TAP configuration from VAT should be
  46 | | ... | ${node} | ${tap_interface} | ${tap_settings}
  47
  48 | Honeycomb modifies existing TAP interface configuration
  49 | | [Documentation] | Check if Honeycomb API can re-configure and existing TAP\
  50 | | ... | interface with new settings.
  51 | | Given TAP configuration from Honeycomb should be
  52 | | ... | ${node} | ${tap_interface} | ${tap_settings}
  53 | | And TAP configuration from VAT should be
  54 | | ... | ${node} | ${tap_interface} | ${tap_settings}
  55 | | When Honeycomb configures TAP interface
  56 | | ... | ${node} | ${tap_interface} | ${tap_settings2}
  57 | | Then TAP configuration from Honeycomb should be
  58 | | ... | ${node} | ${tap_interface} | ${tap_settings2}
  59 | | And TAP configuration from VAT should be
  60 | | ... | ${node} | ${tap_interface} | ${tap_settings2}
  61
  62 | Honeycomb removes TAP interface
  63 | | [Documentation] | Check if Honeycomb API can remove TAP interface.
  64 | | Given TAP configuration from Honeycomb should be
  65 | | ... | ${node} | ${tap_interface} | ${tap_settings2}
  66 | | And TAP configuration from VAT should be
  67 | | ... | ${node} | ${tap_interface} | ${tap_settings2}
  68 | | When Honeycomb removes TAP interface | ${node} | ${tap_interface}
  69 | | Then TAP configuration from Honeycomb should be empty
  70 | | ... | ${node} | ${tap_interface}
  71 | | And TAP configuration from VAT should be empty
  72 | | ... | ${node} | ${tap_interface}