Add Honeycomb persistence tests
[csit.git] / tests / suites / honeycomb / 7 - persistence.robot
1 # Copyright (c) 2016 Cisco and/or its affiliates.
2 # Licensed under the Apache License, Version 2.0 (the "License");
3 # you may not use this file except in compliance with the License.
4 # You may obtain a copy of the License at:
5 #
6 #     http://www.apache.org/licenses/LICENSE-2.0
7 #
8 # Unless required by applicable law or agreed to in writing, software
9 # distributed under the License is distributed on an "AS IS" BASIS,
10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11 # See the License for the specific language governing permissions and
12 # limitations under the License.
13
14 *** Variables***
15 # Node and interface to run tests on.
16 | ${node}= | ${nodes['DUT1']}
17 | ${interface}= | ${node['interfaces']['port1']['name']}
18
19 *** Settings ***
20 | Resource | resources/libraries/robot/default.robot
21 | Resource | resources/libraries/robot/honeycomb/persistence.robot
22 # Restart Honeycomb and VPP to clear configuration before tests.
23 | Suite Setup | Run keywords
24 | ... | Stop Honeycomb service on DUTs | ${node} | AND
25 | ... | Clear persisted Honeycomb configuration | ${node} | AND
26 | ... | Setup DUT | ${node} | AND
27 | ... | Setup Honeycomb service on DUTs | ${node}
28 | Documentation | *Honeycomb configuration persistence test suite.*
29
30 *** Test Cases ***
31 | Honeycomb persists configuration through restart of both systems
32 | | [Documentation] | Checks if Honeycomb maintains configuration after both\
33 | | ... | Honeycomb and VPP are restarted.
34 | | [Tags] | honeycomb_sanity
35 | | When Honeycomb configures every setting | ${node} | ${interface}
36 | | And Honeycomb and VPP are restarted | ${node}
37 | | Then Honeycomb and VPP should verify every setting | ${node} | ${interface}
38 | | And Honeycomb should show no rogue interfaces | ${node}
39
40 | Honeycomb persists configuration through restart of Honeycomb
41 | | [Documentation] | Checks if Honeycomb maintains configuration after it\
42 | | ... | is restarted.
43 | | [Tags] | honeycomb_sanity
44 | | Given Honeycomb and VPP should verify every setting | ${node} | ${interface}
45 | | When Honeycomb is restarted | ${node}
46 | | Then Honeycomb and VPP should verify every setting | ${node} | ${interface}
47 | | And Honeycomb should show no rogue interfaces | ${node}
48
49 | Honeycomb persists configuration through restart of VPP
50 | | [Documentation] | Checks if Honeycomb updates VPP settings after VPP is\
51 | | ... | restarted.
52 | | [Tags] | honeycomb_sanity
53 | | Given Honeycomb and VPP should verify every setting | ${node} | ${interface}
54 | | When VPP is restarted | ${node}
55 | | Then Honeycomb and VPP should verify every setting | ${node} | ${interface}
56 | | And Honeycomb should show no rogue interfaces | ${node}
57
58 | Honeycomb reverts to defaults if persistence files are invalid
59 | | [Documentation] | Checks if Honeycomb reverts to default configuration when\
60 | | ... | persistence files are damaged or invalid.
61 | | [Tags] | honeycomb_sanity
62 | | Given Honeycomb and VPP should verify every setting | ${node} | ${interface}
63 | | When Persistence file is damaged during restart | ${node}
64 | | Then Honeycomb and VPP should have default configuration | ${node}

©2016 FD.io a Linux Foundation Collaborative Project. All Rights Reserved.
Linux Foundation is a registered trademark of The Linux Foundation. Linux is a registered trademark of Linus Torvalds.
Please see our privacy policy and terms of use.