tests/suites/vxlan/vxlan_xconnect_untagged.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/default.robot
  16 | Resource | resources/libraries/robot/testing_path.robot
  17 | Resource | resources/libraries/robot/vxlan.robot
  18 | Resource | resources/libraries/robot/l2_traffic.robot
  19 | Library  | resources.libraries.python.Trace
  20 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | HW_ENV
  21 | Test Setup | Run Keywords | Setup all DUTs before test
  22 | ...        | AND          | Setup all TGs before traffic script
  23 | Test Teardown | Show Packet Trace on All DUTs | ${nodes}
  24 | Documentation | *RFC7348 VXLAN: L2 cross-connect with VXLAN test cases*
  25 | ...
  26 | ... | *[Top] Network topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  27 | ... | with single links between nodes.
  28 | ... | *[Enc] Packet encapsulations:* Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on
  29 | ... | DUT1-DUT2, Eth-IPv4-ICMPv4 on TG-DUTn for L2 switching of IPv4.
  30 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  31 | ... | cross-connect (L2XC) switching; VXLAN tunnels are configured between
  32 | ... | L2XCs on DUT1 and DUT2.
  33 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets
  34 | ... | are sent in both directions by TG on links to DUT1 and DUT2; on receive
  35 | ... | TG verifies packets for correctness and their IPv4 src-addr, dst-addr
  36 | ... | and MAC addresses.
  37 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  38
  39 *** Variables ***
  40 | ${VNI}= | 24
  41
  42 *** Test Cases ***
  43 | TC01: DUT1 and DUT2 with L2XC and VXLANoIPv4 tunnels switch ICMPv4 between TG links
  44 | | [Documentation]
  45 | | ... | [Top] TG-DUT1-DUT2-TG. [Enc] Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on \
  46 | | ... | [Ref] RFC7348.DUT1-DUT2, Eth-IPv4-ICMPv4 on TG-DUTn. [Cfg] On
  47 | | ... | DUT1 and DUT2 configure L2 cross-connect (L2XC), each with one
  48 | | ... | interface to TG and one VXLAN tunnel interface towards the other
  49 | | ... | DUT. [Ver] Make TG send ICMPv4 Echo Req between two of its
  50 | | ... | interfaces; verify all packets are received. [Ref] RFC7348.
  51 | | Given Path for 3-node testing is set
  52 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  53 | | And   Interfaces in 3-node path are up
  54 | | ${dut1_to_dut2_name}= | Get interface name | ${dut1_node} | ${dut1_to_dut2}
  55 | | ${dut2_to_dut1_name}= | Get interface name | ${dut2_node} | ${dut2_to_dut1}
  56 | | And   IP addresses are set on interfaces | ${dut1_node} | ${dut1_to_dut2_name} | ${NONE}
  57 | |       ...                                | ${dut2_node} | ${dut2_to_dut1_name} | ${NONE}
  58 | | ${dut1s_vxlan}= | When Create VXLAN interface     | ${dut1_node} | ${VNI}
  59 | |                 | ...  | ${dut1s_ip_address} | ${dut2s_ip_address}
  60 | |                   And  Interfaces are added to xconnect | ${dut1_node}
  61 | |                   ...  | ${dut1_to_tg} | ${dut1s_vxlan}
  62 | | ${dut2s_vxlan}= | And  Create VXLAN interface     | ${dut2_node} | ${VNI}
  63 | |                 | ...  | ${dut2s_ip_address} | ${dut1s_ip_address}
  64 | |                   And  Interfaces are added to xconnect | ${dut2_node}
  65 | |                   ...  | ${dut2_to_tg} | ${dut2s_vxlan}
  66 | | Then Send and receive ICMPv4 bidirectionally
  67 | | ... | ${tg_node} | ${tg_to_dut1} | ${tg_to_dut2}