tests/vpp/device/container_memif/eth2p-eth-l2xcbase-eth-2memif-1dcr-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | L2XCFWD | BASE | MEMIF | DOCKER
  19 | ...
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test
  22 | Test Teardown | Tear down test | packet_trace | container
  23 | ...
  24 | Documentation | *L2 cross-connect test cases with memif interface*
  25 | ...
  26 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  27 | ... | single links between nodes.
  28 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for L2 switching of \
  29 | ... | IPv4; Eth-IPv6-ICMPv6 for L2 switching of IPv6.
  30 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 cross-connect \
  31 | ... | (L2XC) switching. Container is connected to VPP via Memif interface. \
  32 | ... | Container is running same VPP version as running on DUT.
  33 | ... | *[Ver] TG verification:* Test ICMPv4 (or ICMPv6) Echo Request packets \
  34 | ... | are sent in both directions by TG on links to DUT1 and via container; \
  35 | ... | on receive TG verifies packets for correctness and their IPv4 (IPv6) \
  36 | ... | src-addr, dst-addr and MAC addresses.
  37 | ... | *[Ref] Applicable standard specifications:* RFC792
  38
  39 *** Variables ***
  40 | @{plugins_to_enable}= | dpdk_plugin.so | memif_plugin.so
  41 | ${nic_name}= | virtual
  42 | ${overhead}= | ${0}
  43 # Container
  44 | ${container_engine}= | Docker
  45 | ${container_chain_topology}= | chain_functional
  46
  47 *** Test Cases ***
  48 | tc01-eth2p-ethip4-l2xcbase-eth-2memif-1dcr-dev
  49 | | [Documentation]
  50 | | ... | [Ver] Make TG send ICMPv4 Echo Reqs in both directions between two\
  51 | | ... | of its interfaces to be switched by DUT to and from docker; verify\
  52 | | ... | all packets are received.
  53 | | ...
  54 | | Set Test Variable | ${frame_size} | ${42}
  55 | | Set Test Variable | ${rxq_count_int} | ${1}
  56 | | ...
  57 | | Given Add PCI devices to all DUTs
  58 | | And Set Max Rate And Jumbo And Handle Multi Seg
  59 | | And Apply startup configuration on all VPP DUTs
  60 | | And VPP Enable Traces On All Duts | ${nodes}
  61 | | When Start containers for test | auto_scale=${False} | pinning=${False}
  62 | | And Initialize L2 xconnect with memif pairs
  63 | | Then Send ICMPv4 bidirectionally and verify received packets
  64 | | ... | ${tg} | ${tg_if1} | ${tg_if2}
  65
  66 | tc02-eth2p-ethip6-l2xcbase-eth-2memif-1dcr-dev
  67 | | [Documentation]
  68 | | ... | [Ver] Make TG send ICMPv6 Echo Reqs in both directions between two\
  69 | | ... | of its interfaces to be switched by DUT to and from docker; verify\
  70 | | ... | all packets are received.
  71 | | ...
  72 | | Set Test Variable | ${frame_size} | ${62}
  73 | | Set Test Variable | ${rxq_count_int} | ${1}
  74 | | ...
  75 | | Given Add PCI devices to all DUTs
  76 | | And Set Max Rate And Jumbo And Handle Multi Seg
  77 | | And Apply startup configuration on all VPP DUTs
  78 | | And VPP Enable Traces On All Duts | ${nodes}
  79 | | When Start containers for test | auto_scale=${False} | pinning=${False}
  80 | | And Initialize L2 xconnect with memif pairs
  81 | | Then Send ICMPv6 bidirectionally and verify received packets
  82 | | ... | ${tg} | ${tg_if1} | ${tg_if2}