tests/vpp/device/container_memif/eth2p-ethicmpv4-ip4base-eth-2memif-1dcr-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | IP4FWD | BASE | MEMIF | DOCKER
  19 | ...
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test
  22 | Test Teardown | Tear down test | packet_trace | container
  23 | ...
  24 | Test Template | Local Template
  25 | ...
  26 | Documentation | *IPv4 routing test cases with memif interface*
  27 | ...
  28 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  29 | ... | single links between nodes.
  30 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for IPv4 routing on \
  31 | ... | both links.
  32 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and \
  33 | ... | two static IPv4 /24 route entries. Container is connected to VPP via \
  34 | ... | Memif interface. Container is running same VPP version as running on \
  35 | ... | DUT.
  36 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent in \
  37 | ... | one direction by TG on links to DUT1 and via container; on receive TG \
  38 | ... | verifies packets for correctness and their IPv4 src-addr, dst-addr and \
  39 | ... | MAC addresses.
  40 | ... | *[Ref] Applicable standard specifications:* RFC791, RFC826, RFC792
  41
  42 *** Variables ***
  43 | @{plugins_to_enable}= | dpdk_plugin.so | memif_plugin.so
  44 | ${nic_name}= | virtual
  45 | ${overhead}= | ${0}
  46 # Container
  47 | ${container_engine}= | Docker
  48 | ${container_chain_topology}= | chain_functional
  49
  50 *** Keywords ***
  51 | Local Template
  52 | | [Documentation]
  53 | | ... | [Ver] Make TG send ICMPv4 Echo Reqs in both directions between two\
  54 | | ... | of its interfaces to be routed by DUT to and from docker; verify\
  55 | | ... | all packets are received.
  56 | | ...
  57 | | ... | *Arguments:*
  58 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  59 | | ... | - phy_cores - Number of physical cores. Type: integer
  60 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  61 | | ...
  62 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  63 | | ...
  64 | | Set Test Variable | \${frame_size}
  65 | | ...
  66 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  67 | | And Add PCI devices to all DUTs
  68 | | And Set Max Rate And Jumbo And Handle Multi Seg
  69 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  70 | | When Start containers for test | auto_scale=${False} | pinning=${False}
  71 | | And Initialize IPv4 routing with memif pairs
  72 | | Then Send packet and verify headers
  73 | | ... | ${tg} | 10.10.10.1 | 20.20.20.1
  74 | | ... | ${tg_if1} | ${tg_if1_mac} | ${dut1_if1_mac}
  75 | | ... | ${tg_if2} | ${dut1_if2_mac} | ${tg_if2_mac}
  76
  77 *** Test Cases ***
  78 | tc01-64B-eth2p-ethicmpv4-ip4base-eth-2memif-1dcr-dev
  79 | | [Tags] | 64B
  80 | | frame_size=${64} | phy_cores=${0}