tests/vpp/device/container_memif/eth2p-ethip4-ip4base-eth-2memif-1dcr-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.InterfaceUtil
  16 | Library | resources.libraries.python.IPUtil
  17 | ...
  18 | Resource | resources/libraries/robot/ip/ip4.robot
  19 | Resource | resources/libraries/robot/shared/default.robot
  20 | Resource | resources/libraries/robot/shared/memif.robot
  21 | Resource | resources/libraries/robot/shared/testing_path.robot
  22 | Resource | resources/libraries/robot/shared/traffic.robot
  23 | ...
  24 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV
  25 | ... | FUNCTEST | IP4FWD | BASE | ETH | MEMIF | DOCKER
  26 | ...
  27 | Test Setup | Set up VPP device test
  28 | ...
  29 | Test Teardown | Run Keywords
  30 | ... | Tear down functional test with container
  31 | ... | AND | Tear down VPP device test
  32 | ... | AND | Show Memif on all DUTs | ${nodes}
  33 | ...
  34 | Documentation | *IPv4 routing test cases with memif interface*
  35 | ...
  36 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  37 | ... | single links between nodes.
  38 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for IPv4 routing on \
  39 | ... | both links.
  40 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and \
  41 | ... | two static IPv4 /24 route entries. Container is connected to VPP via \
  42 | ... | Memif interface. Container is running same VPP version as running on \
  43 | ... | DUT.
  44 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent in \
  45 | ... | one direction by TG on links to DUT1 and via container; on receive TG \
  46 | ... | verifies packets for correctness and their IPv4 src-addr, dst-addr and \
  47 | ... | MAC addresses.
  48 | ... | *[Ref] Applicable standard specifications:* RFC791, RFC826, RFC792
  49
  50 *** Variables ***
  51 # IP
  52 | ${net1}= | 10.0.1.0
  53 | ${net3}= | 10.0.3.0
  54 | ${net1_ip1}= | 10.0.1.1
  55 | ${net1_ip2}= | 10.0.1.2
  56 | ${net2_ip1}= | 10.0.2.1
  57 | ${net2_ip2}= | 10.0.2.2
  58 | ${net3_ip1}= | 10.0.3.1
  59 | ${net3_ip2}= | 10.0.3.2
  60 | ${prefix_length}= | 24
  61 | ${fib_table_2}= | 20
  62 # Memif
  63 | ${sock_base}= | memif-DUT1_CNF
  64 # Container
  65 | ${container_engine}= | Docker
  66 | ${container_chain_topology}= | chain_functional
  67
  68 # TODO: Add update of VPP PIDs after container creation
  69 *** Test Cases ***
  70 | tc01-eth2p-ethip4-ip4base-eth-2memif-1dcr-device
  71 | | [Documentation]
  72 | | ... | [Top] TG=DUT=DCR. [Enc] Eth-IPv4-ICMPv4. [Cfg] Configure two VRFs to \
  73 | | ... | route IPv4 traffic through two memif interfaces. Both interfaces are \
  74 | | ... | configured with IP addresses from the same network. [Ver] Make TG to \
  75 | | ... | send ICMPv4 Echo Reqest form one TG interface to another one to be \
  76 | | ... | switched by DUT1; verify header of received packet.
  77 | | ...
  78 | | Given Configure path in 2-node circular topology
  79 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
  80 | | And Set up functional test with containers
  81 | | And Configure interfaces in path up
  82 | | When Set up memif interfaces on DUT node
  83 | | ... | ${dut_node} | ${sock_base} | ${sock_base} | dcr_uuid=${dcr_uuid}
  84 | | ... | memif_if1=memif_if1 | memif_if2=memif_if2 | rxq=${0} | txq=${0}
  85 | | And Add Fib Table | ${dut_node} | ${fib_table_2}
  86 | | And Assign Interface To Fib Table
  87 | | ... | ${dut_node} | ${memif_if2} | ${fib_table_2}
  88 | | And Assign Interface To Fib Table
  89 | | ... | ${dut_node} | ${dut_to_tg_if2} | ${fib_table_2}
  90 | | And Configure IP addresses on interfaces
  91 | | ... | ${dut_node} | ${dut_to_tg_if1} | ${net1_ip1} | ${prefix_length}
  92 | | ... | ${dut_node} | ${memif_if1} | ${net2_ip1} | ${prefix_length}
  93 | | ... | ${dut_node} | ${memif_if2} | ${net2_ip2} | ${prefix_length}
  94 | | ... | ${dut_node} | ${dut_to_tg_if2} | ${net3_ip1} | ${prefix_length}
  95 | | ${memif_if2_key}= | Get interface by sw index | ${nodes['DUT1']}
  96 | | ... | ${memif_if2}
  97 | | ${memif_if2_mac}= | Get interface MAC | ${nodes['DUT1']} | ${memif_if2_key}
  98 | | And Vpp Route Add
  99 | | ... | ${dut_node} | ${net3} | ${prefix_length}
 100 | | ... | gateway=${net2_ip2} | interface=${memif_if1}
 101 | | And Vpp Route Add
 102 | | ... | ${dut_node} | ${net1} | ${prefix_length}
 103 | | ... | gateway=${net2_ip1} | interface=${memif_if2} | vrf=${fib_table_2}
 104 | | VPP Add IP Neighbor
 105 | | ... | ${dut_node} | ${memif_if1} | ${net2_ip2} | ${memif_if2_mac}
 106 | | VPP Add IP Neighbor
 107 | | ... | ${dut_node} | ${dut_to_tg_if2} | ${net3_ip2} | ${tg_to_dut_if2_mac}
 108 | | Then Send packet and verify headers
 109 | | ... | ${tg_node} | ${net1_ip2} | ${net3_ip2}
 110 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac} | ${dut_to_tg_if1_mac}
 111 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if2_mac} | ${tg_to_dut_if2_mac}