tests/vpp/device/container_memif/eth2p-ethip4-ip4base-eth-2memif-1dcr-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.InterfaceUtil
  16 | Library | resources.libraries.python.IPv6Util
  17 | Library | resources.libraries.python.Routing
  18 | ...
  19 | Resource | resources/libraries/robot/ip/ip4.robot
  20 | Resource | resources/libraries/robot/shared/default.robot
  21 | Resource | resources/libraries/robot/shared/memif.robot
  22 | Resource | resources/libraries/robot/shared/testing_path.robot
  23 | Resource | resources/libraries/robot/shared/traffic.robot
  24 | ...
  25 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV
  26 | ... | FUNCTEST | IP4FWD | BASE | ETH | MEMIF | DOCKER
  27 | ...
  28 | Test Setup | Set up VPP device test
  29 | ...
  30 | Test Teardown | Run Keywords
  31 | ... | Tear down functional test with container
  32 | ... | AND | Tear down VPP device test
  33 | ... | AND | Show Memif on all DUTs | ${nodes}
  34 | ...
  35 | Documentation | *IPv4 routing test cases with memif interface*
  36 | ...
  37 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  38 | ... | single links between nodes.
  39 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for IPv4 routing on \
  40 | ... | both links.
  41 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and \
  42 | ... | two static IPv4 /24 route entries. Container is connected to VPP via \
  43 | ... | Memif interface. Container is running same VPP version as running on \
  44 | ... | DUT.
  45 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent in \
  46 | ... | one direction by TG on links to DUT1 and via container; on receive TG \
  47 | ... | verifies packets for correctness and their IPv4 src-addr, dst-addr and \
  48 | ... | MAC addresses.
  49 | ... | *[Ref] Applicable standard specifications:* RFC791, RFC826, RFC792
  50
  51 *** Variables ***
  52 # IP
  53 | ${net1}= | 10.0.1.0
  54 | ${net3}= | 10.0.3.0
  55 | ${net1_ip1}= | 10.0.1.1
  56 | ${net1_ip2}= | 10.0.1.2
  57 | ${net2_ip1}= | 10.0.2.1
  58 | ${net2_ip2}= | 10.0.2.2
  59 | ${net3_ip1}= | 10.0.3.1
  60 | ${net3_ip2}= | 10.0.3.2
  61 | ${prefix_length}= | 24
  62 | ${fib_table_2}= | 20
  63 # Memif
  64 | ${sock_base}= | memif-DUT1_CNF
  65 # Container
  66 | ${container_engine}= | Docker
  67 | ${container_chain_topology}= | chain_functional
  68
  69 # TODO: Add update of VPP PIDs after container creation
  70 *** Test Cases ***
  71 | tc01-eth2p-ethip4-ip4base-eth-2memif-1dcr-device
  72 | | [Documentation]
  73 | | ... | [Top] TG=DUT=DCR. [Enc] Eth-IPv4-ICMPv4. [Cfg] Configure two VRFs to \
  74 | | ... | route IPv4 traffic through two memif interfaces. Both interfaces are \
  75 | | ... | configured with IP addresses from the same network. [Ver] Make TG to \
  76 | | ... | send ICMPv4 Echo Reqest form one TG interface to another one to be \
  77 | | ... | switched by DUT1; verify header of received packet.
  78 | | ...
  79 | | Given Configure path in 2-node circular topology
  80 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
  81 | | And Set up functional test with containers
  82 | | And Configure interfaces in path up
  83 | | When Set up memif interfaces on DUT node | ${dut_node} | ${sock_base}
  84 | | ... | ${sock_base} | dcr_uuid=${dcr_uuid}
  85 | | ... | memif_if1=memif_if1 | memif_if2=memif_if2 | rxq=${0} | txq=${0}
  86 | | And Add Fib Table | ${dut_node} | ${fib_table_2}
  87 | | And Assign Interface To Fib Table | ${dut_node}
  88 | | ... | ${memif_if2} | ${fib_table_2}
  89 | | And Assign Interface To Fib Table | ${dut_node}
  90 | | ... | ${dut_to_tg_if2} | ${fib_table_2}
  91 | | And Configure IP addresses on interfaces
  92 | | ... | ${dut_node} | ${dut_to_tg_if1} | ${net1_ip1} | ${prefix_length}
  93 | | ... | ${dut_node} | ${memif_if1} | ${net2_ip1} | ${prefix_length}
  94 | | ... | ${dut_node} | ${memif_if2} | ${net2_ip2} | ${prefix_length}
  95 | | ... | ${dut_node} | ${dut_to_tg_if2} | ${net3_ip1} | ${prefix_length}
  96 | | ${memif_if2_key}= | Get interface by sw index | ${nodes['DUT1']}
  97 | | ... | ${memif_if2}
  98 | | ${memif_if2_mac}= | Get interface MAC | ${nodes['DUT1']} | ${memif_if2_key}
  99 | | And Vpp Route Add | ${dut_node} | ${net3} | ${prefix_length}
 100 | | ... | gateway=${net2_ip2} | interface=${memif_if1}
 101 | | ... | resolve_attempts=${NONE} | count=${NONE}
 102 | | And Vpp Route Add | ${dut_node} | ${net1} | ${prefix_length}
 103 | | ... | gateway=${net2_ip1} | interface=${memif_if2}
 104 | | ... | resolve_attempts=${NONE} | count=${NONE} | vrf=${fib_table_2}
 105 | | Add IP Neighbor | ${dut_node} | ${memif_if1} | ${net2_ip2}
 106 | | ... | ${memif_if2_mac}
 107 | | Add IP Neighbor | ${dut_node} | ${dut_to_tg_if2} | ${net3_ip2}
 108 | | ... | ${tg_to_dut_if2_mac}
 109 | | Then Send packet and verify headers
 110 | | ... | ${tg_node} | ${net1_ip2} | ${net3_ip2}
 111 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac} | ${dut_to_tg_if1_mac}
 112 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if2_mac} | ${tg_to_dut_if2_mac}