tests/vpp/device/container_memif/eth2p-ethip6-ip6base-eth-2memif-1dcr-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | IP6FWD | BASE | MEMIF | DOCKER
  19 | ...
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test
  22 | Test Teardown | Tear down test | packet_trace | container
  23 | ...
  24 | Documentation | *IPv4 routing test cases with memif interface*
  25 | ...
  26 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  27 | ... | single links between nodes.
  28 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-ICMPv6 for IPv6 routing on \
  29 | ... | both links.
  30 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv6 routing and \
  31 | ... | two static IPv6 /64 route entries. Container is connected to VPP via \
  32 | ... | Memif interface. Container is running same VPP version as running on \
  33 | ... | DUT.
  34 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets are sent in \
  35 | ... | one direction by TG on links to DUT1 and via container; on receive TG \
  36 | ... | verifies packets for correctness and their IPv6 src-addr, dst-addr and \
  37 | ... | MAC addresses.
  38 | ... | *[Ref] Applicable standard specifications:* RFC791, RFC826, RFC792
  39
  40 *** Variables ***
  41 | @{plugins_to_enable}= | dpdk_plugin.so | memif_plugin.so
  42 | ${nic_name}= | virtual
  43 | ${overhead}= | ${0}
  44 # Container
  45 | ${container_engine}= | Docker
  46 | ${container_chain_topology}= | chain_functional
  47
  48 *** Test Cases ***
  49 | tc01-eth2p-ethip6-ip6base-eth-2memif-1dcr-dev
  50 | | [Documentation]
  51 | | ... | [Ver] Make TG send ICMPv6 Echo Reqs in both directions between two\
  52 | | ... | of its interfaces to be routed by DUT to and from docker; verify\
  53 | | ... | all packets are received.
  54 | | ...
  55 | | Set Test Variable | ${frame_size} | ${62}
  56 | | Set Test Variable | ${rxq_count_int} | ${1}
  57 | | ...
  58 | | Given Add PCI devices to all DUTs
  59 | | And Set Max Rate And Jumbo And Handle Multi Seg
  60 | | And Apply startup configuration on all VPP DUTs
  61 | | And VPP Enable Traces On All Duts | ${nodes}
  62 | | When Start containers for test | auto_scale=${False} | pinning=${False}
  63 | | And Set interfaces in path up
  64 | | And Set up memif interfaces on DUT node
  65 | | ... | ${dut1} | memif-DUT1_CNF | memif-DUT1_CNF
  66 | | ... | memif_if1=memif_if1 | memif_if2=memif_if2
  67 | | ... | rxq=${rxq_count_int} | txq=${rxq_count_int}
  68 | | And Add Fib Table | ${dut1} | 20 | ipv6=${True}
  69 | | And Assign Interface To Fib Table
  70 | | ... | ${dut1} | ${memif_if2} | 20 | ipv6=${True}
  71 | | And Assign Interface To Fib Table
  72 | | ... | ${dut1} | ${dut1_if2} | 20 | ipv6=${True}
  73 | | And VPP Interface Set IP Address
  74 | | ... | ${dut1} | ${dut1_if1} | 2001:1::1 | 64
  75 | | And VPP Interface Set IP Address
  76 | | ... | ${dut1} | ${memif_if1} | 2001:2::1 | 64
  77 | | And VPP Interface Set IP Address
  78 | | ... | ${dut1} | ${memif_if2} | 2001:2::2 | 64
  79 | | And VPP Interface Set IP Address
  80 | | ... | ${dut1} | ${dut1_if2} | 2001:3::1 | 64
  81 | | ${memif_if2_key}= | Get interface by sw index | ${nodes['DUT1']}
  82 | | ... | ${memif_if2}
  83 | | ${memif_if2_mac}= | Get interface MAC | ${nodes['DUT1']} | ${memif_if2_key}
  84 | | And Vpp Route Add
  85 | | ... | ${dut1} | 2001:3::0 | 64 | gateway=2001:2::2 | interface=${memif_if1}
  86 | | And Vpp Route Add
  87 | | ... | ${dut1} | 2001:1::0 | 64 | gateway=2001:2::2 | interface=${memif_if2}
  88 | | ... | vrf=20
  89 | | VPP Add IP Neighbor
  90 | | ... | ${dut1} | ${memif_if1} | 2001:2::2 | ${memif_if2_mac}
  91 | | VPP Add IP Neighbor
  92 | | ... | ${dut1} | ${dut1_if2} | 2001:3::2 | ${tg_if2_mac}
  93 | | Then Send packet and verify headers
  94 | | ... | ${tg} | 2001:1::1 | 2001:3::2
  95 | | ... | ${tg_if1} | ${tg_if1_mac} | ${dut1_if1_mac}
  96 | | ... | ${tg_if2} | ${dut1_if2_mac} | ${tg_if2_mac}