tests/vpp/device/container_memif/eth2p-ethipv4-ip4base-eth-2memif-1dcr-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | IP4FWD | BASE | MEMIF | DOCKER | DRV_VFIO_PCI
  19 |
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test
  22 | Test Teardown | Tear down test | packet_trace | container
  23 |
  24 | Test Template | Local Template
  25 |
  26 | Documentation | *IPv4 routing test cases with memif interface*
  27 |
  28 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  29 | ... | single links between nodes.
  30 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing on both links.
  31 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and \
  32 | ... | two static IPv4 /24 route entries. Container is connected to VPP via \
  33 | ... | Memif interface. Container is running same VPP version as running on \
  34 | ... | DUT.
  35 | ... | *[Ver] TG verification:* Test IPv4 packets with IP protocol=61 are \
  36 | ... | sent in one direction by TG on links to DUT1 and via container; on \
  37 | ... | receive TG verifies packets for correctness and their IPv4 src-addr, \
  38 | ... | dst-addr and MAC addresses.
  39 | ... | *[Ref] Applicable standard specifications:* RFC791, RFC826, RFC792
  40
  41 *** Variables ***
  42 | @{plugins_to_enable}= | dpdk_plugin.so | memif_plugin.so
  43 | ${crypto_type}= | ${None}
  44 | ${nic_name}= | virtual
  45 | ${nic_driver}= | vfio-pci
  46 | ${overhead}= | ${0}
  47 # Container
  48 | ${container_engine}= | Docker
  49 | ${container_chain_topology}= | chain_functional
  50
  51 *** Keywords ***
  52 | Local Template
  53 | | [Documentation]
  54 | | ... | [Ver] Make TG send IPv4 packet in both directions between two\
  55 | | ... | of its interfaces to be routed by DUT to and from docker; verify\
  56 | | ... | all packets are received.
  57 | |
  58 | | ... | *Arguments:*
  59 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  60 | | ... | - phy_cores - Number of physical cores. Type: integer
  61 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  62 | |
  63 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  64 | |
  65 | | Set Test Variable | \${frame_size}
  66 | |
  67 | | Given Set Max Rate And Jumbo
  68 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  69 | | And Pre-initialize layer driver | ${nic_driver}
  70 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  71 | | When Initialize layer driver | ${nic_driver}
  72 | | And Initialize layer interface
  73 | | And Start containers for test | auto_scale=${False} | pinning=${False}
  74 | | And Initialize IPv4 routing with memif pairs
  75 | | Then Send packet and verify headers
  76 | | ... | ${tg} | 10.10.10.1 | 20.20.20.1
  77 | | ... | ${tg_if1} | ${tg_if1_mac} | ${dut1_if1_mac}
  78 | | ... | ${tg_if2} | ${dut1_if2_mac} | ${tg_if2_mac}
  79
  80 *** Test Cases ***
  81 | tc01-64B-ethipv4-ip4base-eth-2memif-1dcr-dev
  82 | | [Tags] | 64B
  83 | | frame_size=${64} | phy_cores=${0}