tests/vpp/device/container_memif/eth2p-ethipv6-ip6base-eth-2memif-1dcr-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | IP6FWD | BASE | MEMIF | DOCKER | DRV_VFIO_PCI
  19 | ... | ethipv6-ip6base-eth-2memif-1dcr
  20 |
  21 | Suite Setup | Setup suite single link | scapy
  22 | Test Setup | Setup test
  23 | Test Teardown | Tear down test | packet_trace | container
  24 |
  25 | Test Template | Local Template
  26 |
  27 | Documentation | *IPv4 routing test cases with memif interface*
  28 |
  29 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  30 | ... | single links between nodes.
  31 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6 for IPv6 routing on \
  32 | ... | both links.
  33 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv6 routing and \
  34 | ... | two static IPv6 /64 route entries. Container is connected to VPP via \
  35 | ... | Memif interface. Container is running same VPP version as running on \
  36 | ... | DUT.
  37 | ... | *[Ver] TG verification:* Test IPv6 packets are sent in one direction \
  38 | ... | by TG on links to DUT1 and via container; on receive TG verifies \
  39 | ... | packets for correctness and their IPv6 src-addr, dst-addr and \
  40 | ... | MAC addresses.
  41 | ... | *[Ref] Applicable standard specifications:* RFC791, RFC826, RFC792
  42
  43 *** Variables ***
  44 | @{plugins_to_enable}= | dpdk_plugin.so | memif_plugin.so
  45 | ${crypto_type}= | ${None}
  46 | ${nic_name}= | virtual
  47 | ${nic_driver}= | vfio-pci
  48 | ${overhead}= | ${0}
  49 # Container
  50 | ${container_engine}= | Docker
  51 | ${container_chain_topology}= | chain_functional
  52
  53 *** Keywords ***
  54 | Local Template
  55 | | [Documentation]
  56 | | ... | [Ver] Make TG send IPv6 packets in both directions between two\
  57 | | ... | of its interfaces to be routed by DUT to and from docker; verify\
  58 | | ... | all packets are received.
  59 | |
  60 | | ... | *Arguments:*
  61 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  62 | | ... | - phy_cores - Number of physical cores. Type: integer
  63 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  64 | |
  65 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  66 | |
  67 | | Set Test Variable | \${frame_size}
  68 | |
  69 | | Given Set Max Rate And Jumbo
  70 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  71 | | And Pre-initialize layer driver | ${nic_driver}
  72 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  73 | | When Initialize layer driver | ${nic_driver}
  74 | | And Initialize layer interface
  75 | | And Start containers for test | auto_scale=${False} | pinning=${False}
  76 | | And Set interfaces in path up
  77 | | And Set up memif interfaces on DUT node
  78 | | ... | ${dut1} | memif-DUT1_CNF | memif-DUT1_CNF
  79 | | ... | memif_if1=memif_if1 | memif_if2=memif_if2
  80 | | ... | rxq=${rxq_count_int} | txq=${rxq_count_int}
  81 | | And Add Fib Table | ${dut1} | 20 | ipv6=${True}
  82 | | And Assign Interface To Fib Table
  83 | | ... | ${dut1} | ${memif_if2} | 20 | ipv6=${True}
  84 | | And Assign Interface To Fib Table
  85 | | ... | ${dut1} | ${dut1_if2} | 20 | ipv6=${True}
  86 | | And VPP Interface Set IP Address
  87 | | ... | ${dut1} | ${dut1_if1} | 2001:1::1 | 64
  88 | | And VPP Interface Set IP Address
  89 | | ... | ${dut1} | ${memif_if1} | 2001:2::1 | 64
  90 | | And VPP Interface Set IP Address
  91 | | ... | ${dut1} | ${memif_if2} | 2001:2::2 | 64
  92 | | And VPP Interface Set IP Address
  93 | | ... | ${dut1} | ${dut1_if2} | 2001:3::1 | 64
  94 | | ${memif_if2_key}= | Get interface by sw index | ${nodes['DUT1']}
  95 | | ... | ${memif_if2}
  96 | | ${memif_if2_mac}= | Get interface MAC | ${nodes['DUT1']} | ${memif_if2_key}
  97 | | And Vpp Route Add
  98 | | ... | ${dut1} | 2001:3::0 | 64 | gateway=2001:2::2 | interface=${memif_if1}
  99 | | And Vpp Route Add
 100 | | ... | ${dut1} | 2001:1::0 | 64 | gateway=2001:2::2 | interface=${memif_if2}
 101 | | ... | vrf=20
 102 | | VPP Add IP Neighbor
 103 | | ... | ${dut1} | ${memif_if1} | 2001:2::2 | ${memif_if2_mac}
 104 | | VPP Add IP Neighbor
 105 | | ... | ${dut1} | ${dut1_if2} | 2001:3::2 | ${tg_if2_mac}
 106 | | Then Send packet and verify headers
 107 | | ... | ${tg} | 2001:1::1 | 2001:3::2
 108 | | ... | ${tg_if1} | ${tg_if1_mac} | ${dut1_if1_mac}
 109 | | ... | ${tg_if2} | ${dut1_if2_mac} | ${tg_if2_mac}
 110
 111 *** Test Cases ***
 112 | tc01-78B-ethipv6-ip6base-eth-2memif-1dcr-dev
 113 | | [Tags] | 78B
 114 | | frame_size=${78} | phy_cores=${0}