tests/vpp/device/crypto/eth2p-ethip4ipsec1tnlsw-ip4base-policy-aes-128-cbc-sha-512-256-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | IP4FWD | IPSEC | IPSECSW | IPSECTUN | IP4BASE
  19 | ... | AES_128_CBC | HMAC_SHA_512 | HMAC | AES
  20 | ...
  21 | Suite Setup | Setup suite single link | scapy
  22 | Test Setup | Setup test
  23 | Test Teardown | Tear down test | packet_trace
  24 | ...
  25 | Test Template | Local Template
  26 | ...
  27 | Documentation | *IPv4 IPsec tunnel mode test suite.*
  28 | ...
  29 | ... | *[Top] Network topologies:* TG-DUT1 2-node topology with one link\
  30 | ... | between nodes.
  31 | ... | *[Cfg] DUT configuration:* On DUT1 create loopback interface, configure\
  32 | ... | loopback an physical interface IPv4 addresses, static ARP record, route\
  33 | ... | and IPsec manual keyed connection in tunnel mode.
  34 | ... | *[Ver] TG verification:* ESP packet is sent from TG to DUT1. ESP packet\
  35 | ... | is received on TG from DUT1.
  36 | ... | *[Ref] Applicable standard specifications:* RFC4303.
  37
  38 *** Variables ***
  39 | @{plugins_to_enable}= | dpdk_plugin.so | crypto_ia32_plugin.so
  40 | ... | crypto_ipsecmb_plugin.so | crypto_openssl_plugin.so
  41 | ${nic_name}= | virtual
  42 | ${overhead}= | ${54}
  43 | ${tg_spi}= | ${1000}
  44 | ${dut_spi}= | ${1001}
  45 | ${ESP_PROTO}= | ${50}
  46 | ${tg_if_ip4}= | 192.168.100.2
  47 | ${dut_if_ip4}= | 192.168.100.3
  48 | ${tg_lo_ip4}= | 192.168.3.3
  49 | ${dut_lo_ip4}= | 192.168.4.4
  50 | ${ip4_plen}= | ${24}
  51
  52 *** Keywords ***
  53 | Local Template
  54 | | [Documentation]
  55 | | ... | [Cfg] On DUT1 configure IPsec manual keyed connection with encryption\
  56 | | ... | algorithm AES_128_CBC and integrity algorithm HMAC_SHA_512 in tunnel\
  57 | | ... | mode.
  58 | | ...
  59 | | ... | *Arguments:*
  60 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  61 | | ... | - phy_cores - Number of physical cores. Type: integer
  62 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  63 | | ...
  64 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  65 | | ...
  66 | | Set Test Variable | \${frame_size}
  67 | | ...
  68 | | # These are enums (not strings) so they cannot be in Variables table.
  69 | | ${encr_alg}= | Crypto Alg AES CBC 128
  70 | | ${auth_alg}= | Integ Alg SHA 512 256
  71 | | ...
  72 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  73 | | And Add PCI devices to all DUTs
  74 | | And Set Max Rate And Jumbo And Handle Multi Seg
  75 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  76 | | When Configure topology for IPv4 IPsec testing
  77 | | And Generate keys for IPSec | ${encr_alg} | ${auth_alg}
  78 | | And Configure manual keyed connection for IPSec
  79 | | ... | ${dut1} | ${dut1_if1} | ${encr_alg} | ${encr_key} | ${auth_alg}
  80 | | ... | ${auth_key} | ${dut_spi} | ${tg_spi} | ${dut_src_ip} | ${tg_src_ip}
  81 | | ... | ${dut_tun_ip} | ${tg_tun_ip}
  82 | | Then Send IPsec Packet and verify ESP encapsulation in received packet
  83 | | ... | ${tg} | ${tg_if1} | ${dut1_if1_mac}
  84 | | ... | ${encr_alg} | ${encr_key} | ${auth_alg} | ${auth_key} | ${tg_spi}
  85 | | ... | ${dut_spi} | ${tg_src_ip} | ${dut_src_ip} | ${tg_tun_ip}
  86 | | ... | ${dut_tun_ip}
  87
  88 *** Test Cases ***
  89 | tc01-110B-eth2p-ethip4ipsec1tnlsw-ip4base-policy-aes-128-cbc-sha-512-256-dev
  90 | | [Tags] | 110B
  91 | | frame_size=${110} | phy_cores=${0}