tests/vpp/device/crypto/ethip6/2n1l-10ge2p1x710-ethip6ipsec1tptsw-ip6base-policy-aes128cbc-hmac512sha-scapy.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Intel-X710 | IP6FWD | IPSEC | IPSECSW | IPSECTPT | IP6BASE
  19 | ... | AES_128_CBC | HMAC_SHA_512 | HMAC | AES | DRV_VFIO_PCI
  20 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  21 | ... | ethip6ipsec1tptsw-ip6base-policy-aes128cbc-hmac512sha
  22 |
  23 | Suite Setup | Setup suite topology interfaces | scapy
  24 | Test Setup | Setup test
  25 | Test Teardown | Tear down test | packet_trace | telemetry | ipsec_sa
  26 |
  27 | Test Template | Local Template
  28 |
  29 | Documentation | *IPv6 IPsec transport mode test suite.*
  30 |
  31 | ... | *[Top] Network topologies:* TG-DUT1 2-node topology with one link\
  32 | ... | between nodes.
  33 | ... | *[Cfg] DUT configuration:* On DUT1 create loopback interface, configure
  34 | ... | loopback an physical interface IPv6 addresses, static ARP record, route
  35 | ... | and IPsec manual keyed connection in transport mode.
  36 | ... | *[Ver] TG verification:* ESP packet is sent from TG to DUT1. ESP packet
  37 | ... | is received on TG from DUT1.
  38 | ... | *[Ref] Applicable standard specifications:* RFC4303.
  39
  40 *** Variables ***
  41 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  42 | ... | crypto_native_plugin.so | crypto_ipsecmb_plugin.so
  43 | ... | crypto_openssl_plugin.so
  44 | ${crypto_type}= | ${None}
  45 | ${nic_name}= | Intel-X710
  46 | ${nic_driver}= | vfio-pci
  47 | ${nic_rxq_size}= | 0
  48 | ${nic_txq_size}= | 0
  49 | ${nic_pfs}= | 2
  50 | ${nic_vfs}= | 0
  51 | ${overhead}= | ${58}
  52 | ${tg_spi}= | ${1000}
  53 | ${dut_spi}= | ${1001}
  54 | ${ESP_PROTO}= | ${50}
  55 | ${tg_if1_ip6}= | 3ffe:5f::1
  56 | ${tg_if2_ip6}= | 3ffe:60::4
  57 | ${dut_if1_ip6}= | 3ffe:5f::2
  58 | ${dut_if2_ip6}= | 3ffe:60::3
  59 | ${tg_host_ip6}= | 3ffe:61::3
  60 | ${ip6_plen}= | ${64}
  61 | ${ip6_plen_rt}= | ${128}
  62 # Telemetry
  63 | ${telemetry_profile}= | vpp_test_teardown
  64
  65 *** Keywords ***
  66 | Local Template
  67 | | [Documentation]
  68 | | ... | [Cfg] On DUT1 configure IPsec manual keyed connection with encryption\
  69 | | ... | algorithm AES_128_CBC and integrity algorithm HMAC_SHA_512 in\
  70 | | ... | transport mode.
  71 | |
  72 | | ... | *Arguments:*
  73 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  74 | | ... | - phy_cores - Number of physical cores. Type: integer
  75 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  76 | |
  77 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  78 | |
  79 | | Set Test Variable | \${frame_size}
  80 | |
  81 | | # These are enums (not strings) so they cannot be in Variables table.
  82 | | ${encr_alg}= | Crypto Alg AES CBC 128
  83 | | ${auth_alg}= | Integ Alg SHA 512 256
  84 | |
  85 | | Given Set Max Rate And Jumbo
  86 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  87 | | And Pre-initialize layer driver | ${nic_driver}
  88 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  89 | | When Initialize layer driver | ${nic_driver}
  90 | | And Initialize layer interface
  91 | | And Configure topology for IPv6 IPsec testing
  92 | | And Generate keys for IPSec | ${encr_alg} | ${auth_alg}
  93 | | And Configure manual keyed connection for IPSec
  94 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${encr_alg} | ${encr_key} | ${auth_alg}
  95 | | ... | ${auth_key} | ${dut_spi} | ${tg_spi} | ${tg_dst_ip} | ${tg_src_ip}
  96 | | ... | is_ipv6=${TRUE}
  97 | | Then Send IPsec Packet and verify ESP encapsulation in received packet
  98 | | ... | ${tg} | ${TG_pf1}[0] | ${TG_pf2}[0]
  99 | | ... | ${DUT1_vf1_mac}[0] | ${DUT1_vf2_mac}[0]
 100 | | ... | ${encr_alg} | ${encr_key} | ${auth_alg} | ${auth_key} | ${tg_spi}
 101 | | ... | ${dut_spi} | ${tg_src_ip} | ${tg_dst_ip}
 102
 103 *** Test Cases ***
 104 | 78B-0c-ethip6ipsec1tptsw-ip6base-policy-aes128cbc-hmac512sha-scapy
 105 | | [Tags] | 78B | 0C
 106 | | frame_size=${78} | phy_cores=${0}