tests/vpp/device/interfaces/eth2p-eth-l2bdbasemaclrn-eth-2tap-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | L2BD | BASE | TAP
  19 | ...
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test | namespace
  22 | Test Teardown | Tear down test | packet_trace | namespace | linux_bridge
  23 | ...
  24 | Documentation | *Tap Interface Traffic Tests*
  25 | ...
  26 | ... | *[Top] Network Topologies:* TG=DUT1 2-node topology with two links
  27 | ... | between nodes.
  28 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for L2 switching of
  29 | ... | IPv4.
  30 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  31 | ... | bridge-domain (L2BD) MAC learning enabled; Split Horizon Groups (SHG)
  32 | ... | are set depending on test case; Namespaces (NM)
  33 | ... | are set on DUT1 with attached linux-TAP.
  34 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets
  35 | ... | are sent by TG on link to DUT1; On receipt TG verifies packets
  36 | ... | for correctness and their IPv4 src-addr, dst-addr, and MAC addresses.
  37 | ... | *[Ref] Applicable standard specifications:*
  38
  39 *** Variables ***
  40 | @{plugins_to_enable}= | dpdk_plugin.so
  41 | ${nic_name}= | virtual
  42 | ${overhead}= | ${0}
  43 | ${bid_TAP}= | tapBr
  44
  45 *** Test Cases ***
  46 | tc01-eth2p-ethicmpv4-l2bdbasemaclrn-eth-2tap-dev_tap-simple-bd
  47 | | [Documentation]
  48 | | ... | [Ver] Packet sent from TG is passed through all L2BD and received\
  49 | | ... | back on TG. Then src_ip, dst_ip and MAC are checked.
  50 | | ...
  51 | | Set Test Variable | ${frame_size} | ${42}
  52 | | Set Test Variable | ${rxq_count_int} | ${1}
  53 | | ...
  54 | | Given Add PCI devices to all DUTs
  55 | | And Set Max Rate And Jumbo And Handle Multi Seg
  56 | | And Apply startup configuration on all VPP DUTs
  57 | | And VPP Enable Traces On All Duts | ${nodes}
  58 | | When Set interfaces in path up
  59 | | ${int1}= | And Add Tap Interface | ${dut1} | tap0
  60 | | ${int2}= | And Add Tap Interface | ${dut1} | tap1
  61 | | And Set Interface State | ${dut1} | ${int1} | up
  62 | | And Set Interface State | ${dut1} | ${int2} | up
  63 | | And Create bridge domain | ${dut1} | 19 | learn=${TRUE}
  64 | | And Create bridge domain | ${dut1} | 20 | learn=${TRUE}
  65 | | And Linux Add Bridge | ${dut1} | ${bid_TAP} | tap0 | tap1
  66 | | And Add interface to bridge domain | ${dut1} | ${int1} | 20 | 0
  67 | | And Add interface to bridge domain | ${dut1} | ${dut1_if1} | 20 | 0
  68 | | And Add interface to bridge domain | ${dut1} | ${int2} | 19 | 0
  69 | | And Add interface to bridge domain | ${dut1} | ${dut1_if2} | 19 | 0
  70 | | Then Send ICMP packet and verify received packet
  71 | | ... | ${tg} | ${tg_if1} | ${tg_if2}